Tweet
Ciao a tutti.
Devo macrare fishing sul mio pg, ho trovato questo script carino con il quale basta mettersi sulla barca, girarla verso Nord e premere play: fa tutto da se.
Unica pecca: quando pesca (lo script dice chiaramente di stare vicino al tillerman, in fondo alla barca) a causa del movimento della barca, il pezzo di mare in cui hai gettato l'amo si sposta ed appare il messaggio: you need to be closer to the water to fish! (cioè che devo stare più vicino a dove ho gettato l'amo).
Credo che il problema stia nel dove far gettare l'amo al pg (che momentaneamente lo getta proprio avanti a se). Qualcuno che ci sa fare può gentilmente vedere se sa come risolvere? Questo è lo script:
Grazie mille.
Devo macrare fishing sul mio pg, ho trovato questo script carino con il quale basta mettersi sulla barca, girarla verso Nord e premere play: fa tutto da se.
Unica pecca: quando pesca (lo script dice chiaramente di stare vicino al tillerman, in fondo alla barca) a causa del movimento della barca, il pezzo di mare in cui hai gettato l'amo si sposta ed appare il messaggio: you need to be closer to the water to fish! (cioè che devo stare più vicino a dove ho gettato l'amo).
Credo che il problema stia nel dove far gettare l'amo al pg (che momentaneamente lo getta proprio avanti a se). Qualcuno che ci sa fare può gentilmente vedere se sa come risolvere? Questo è lo script:
codice:
;==================================
; Script Name: Simple fisherman / trainer.
; Author: Locke
; Version: 1.0
; Client Tested with:
; EUO version tested with: 1.5.75
; Shard OSI / FS: FS
; Revision Date: 5 minutes from now
; Public Release: June 14 2006
; Purpose: To train fishing and assist with fishing up serpents.
;==================================
; just load the script up and press play with your boat facing north.
;///-------------------------------------------------------------------------\\\
; User Config Section:
set %default_aiming #true
; this will use the scripts default casting spots. if it's working screwy for you
; set to #false and set your own.
set %fishwait 8
; this is how long to wait in seconds before trying to cast again. please note
; there is a seperate 3 second wait for the antiblock so there's a
; 11 second wait by default.
set %pole KDF
; ID for your fishin pole
set %equip_pole #false
set %creatures KI_OD_
; sea serpent and water elemental
; /User config section.
set %useweapon #false
; set to #true to auto disarm the pole and equip a weapon when a serp spawns
set %usehotkey #true
set %key F2
; this is the hotkey for resuming the script after a serpent spawns
set %auto_attack #false
; if your an archer like myself, set this to #true
;\\\------------------------------------------------------------------------///
set %dir N
gosub setup
goto mainloop
;-~+ Main loop: +~-:
mainloop:
set %test #charposy
wait 3s
gosub checklocation
gosub scan %creatures
gosub use
gosub target
goto mainloop
;-~+/Main loop: +~-;
;======================================================================
sub setup
;=================================================================
; This sub is for setting up the script
; the below code opens the status bar is if it closed
if #charname = N/A
{
event macro 8 2
while #contsize <> 432_184
wait 1
wait 10
set %openedstatus #true
}
; this opens up the backpack
event macro 8 7
while #contsize <> 230_204
wait 1
wait 10
; this opens up the paperdoll and checks for the fishing pole in it
event macro 8 1
while #contsize <> 262_324
wait 1
set %doll #contid
wait 10
if %equip_pole = #true
gosub equip %pole
; this lets you move the containers where you want them in the event they had to be opened.
if %openedstatus = #true || %openedpack = #true
{
display ok Please drag your containers where you want them. You got 5 seconds
wait 5s
}
if %useweapon = #true
{
display ok Please target the weapon you'll be using.
set #targcurs 1
while #targcurs = 1
wait 1
set %weapon #ltargetid
}
; this sets where to cast - the format is % , click , X OR Y, "F"oward or "B"ack.
if %default_aiming = #true
{
set %clickxF 558
set %clickyF 260
set %clickxB 415
set %clickyB 361
}
else
{
display ok Please hover your cursor where you want to cast,$
+while the boat is going forward and press enter to close the display box.
set %clickxF #cursorx
set %clickyF #cursory
display ok Please hover your cursror where you want to cast,$
+while the boat is stationary or going back and press enter to close the display box.
set %clickxB #cursorx
set %clickyB #cursory
}
event macro 1 0 Slow forward
return
;======================================================================
sub equip
;=================================================================
; this sub finds and equips the fishing pole.
retry_equip:
finditem %1 C
if #findkind <> -1
{
set %pole #findid
if #findbagid = %doll
return
if #findbagid = #backpackid
{
exevent drag %pole
exevent droppd
}
}
else
{
if %notfound = #true
{
display Ok I was unable to find a fishing pole in any open containers.$
+you will need to see if the object types match. If they do then please report back
halt
}
set %notfound #true
set %openedpack #true
event macro 8 7
while #contsize <> 230_204
wait 1
wait 13
goto retry_equip
}
set %notfound #false
return
;======================================================================
sub move
;=================================================================
; this is an artifact from an earlier version, and for some reason
; hasn't been removed. *scratches head*
if #charposy = 3561 2
event macro 1 0 slow forward
wait 2s
if #charposy = 3462 2
event macro 1 0 slow back
wait 2s
return
;======================================================================
sub use
;=================================================================
; this sub dbl clicks the pole.
finditem %pole C
if #findkind <> -1
{
set #lobjectid #findid
event macro 17 0
target
}
else
{
display ok I was unable to find a fishing pole in your backpack. Script is halting
halt
}
return
;======================================================================
sub target
;=================================================================
; this sub casts the pole based on the direction you are going.
set %time #scnt + 2
while #targcurs <> 1 && %time > #scnt
wait 1
set %time #scnt + 5
while #targcurs = 1 && %time > #scnt
{
if %test > #charposy ; forward
click %clickxF %clickyF D
if %test =< #charposy
click %clickxB %clickyB D
wait 5
}
gosub fishwait %fishwait
return
;======================================================================
sub checklocation
;=================================================================
; this sub checks your position to see if you could be stuck.
if %test = #charposy
{
gosub moveme %dir
return
}
if %test <> #charposy
return
else
{
event macro 3 0 Apparently I don't know where I am due to high lag. It should fix itself in time.
return
}
return
; really isn't nessecary. *shrugs*
;======================================================================
sub moveme
;=================================================================
; this sub is what causes you to yo-yo inbetween two points. It starts at N meaning
; north and changes to going south on the first pass, then to north, etc etc.
set %test #charposy
if %1 = N
{
event macro 1 0 Slow Back
set %dir S
wait 5s
}
if %1 = S 3
event macro 1 0 Slow Forward
set %dir N
wait 5s
return
;======================================================================
sub scan
;=================================================================
; this sub scans for %creatures (%1) and if one is found the script will beep 5
; times and pause so you can kill it.
finditem %1 G_15
if #findkind <> -1
{
set %serp #findid
event macro 1 0 stop
for %1 1 5
{
sound
wait 2
}
if %useweapon = #true
{
exevent drag %pole
exevent dropc #backpackid
wait 15
finditem %weapon C_ , #backpackid
if #findkind <> -1
{
exevent drag #findid
exevent droppd
}
}
if %auto_attack = #true
gosub attack %serp
display ok Captain we're under attack! Hurry or we'll surly sink!$Awaiting orders Captain!
if %usehotkey = #true
{
hotkeyloop:
onhotkey %key
goto breakloop
goto hotkeyloop
}
else
pause
breakloop:
finditem YFM G_2
if #findkind <> -1
gosub dragitems #findid
if %dir = N
event macro 1 0 slow forward
else
event macro 1 0 slow back
}
return
;======================================================================
sub fishwait
;=================================================================
set #lpc 20
set %gumptimeout %1
set %gumpwait #scnt
set %count 0
gumpwaitloop:
gosub scan %creatures
if %gumptimeout + %gumpwait < #scnt
return
set %count %count + 1
goto gumpwaitloop
;======================================================================
sub dragitems
;=================================================================
set %items PVI_ZVI_TVI_NVI_YDF_
set %dropspot %1
loop:
finditem %items C_ , #backpackid
if #findkind <> -1
{
exevent drag #findid #findstack
exevent dropc %dropspot
wait 15
}
else
return
goto loop
;======================================================================
sub attack
;=================================================================
finditem %1 G_15
if #findkind <> -1
{
set #ltargetid #findid
event macro 27 0
}
return
Commenta