annuncio

**Marino** · 30-03-2012, 19:58

Originariamente inviato da MrMalaparte Visualizza il messaggio

Ciao a tutti, allora il mio pensiero � questo: secondo me con boscag no filla perfettamente tutti i large o meglio alcuni li trasha, non ho verificato fino in fondo ma questo dubbio mi rimane. La mia domanda � questa, c'� uno script BUONO che filla e basta i bod, secondo le mie preferenze e un altro script solo per la consegna? Se si me li potete indicare? Grazie mille

con quali bod hai notato sta cosa con quell da sarto o con quelli da fabbro?

posso indicarti questo che li fila soltanto e se li aggiungi nella lista ti riempi i large usa bod filler http://forum.gamesnet.it/f667/easyuo...ml#post6700707

per quanto riguarda la consegna puoi utilizzare questo http://forum.gamesnet.it/f667/richie...8/#post7105230 che consegna e ritira i bod e mette i premi nel packanimal del tuo pet funziona sia per i bod da fabbro che da sarto per� per quelli da fabbro da qualche problema nel trashare a terra i premi che non vuoi, bisognerebbe sistemarlo, poi c'� anche il power bod swamper modificato da felix per tailor e per black che se ricordo bene consegna suddivide i bod in book diversi e deposita i premi nella bank di luna per� non so se funziona ancora dato che � un p� datato

se qualcuno � cos� gentile da postare una versione quasi funzionante posso anche darci un occhiata perch� interessava anche a me

**Marino** · 30-03-2012, 19:59

part 1/2

codice:

; =====================================================================
; Script Name: Traston's Simple Bod Swapper
; Author: Traston ShadowFire
; Version: 1.01
; Client Tested With: 5.0.1h
; Euo Version Tested With: 1.5 Test Ver 67
; Shard Osi / Fs: FS
; Shard Name: Alexandria (the only one that counts)
; Debug Mode Started: 22 Nov 2005
; Last Revised : 27 Dec 2005
; Official Release: 25 Dec 2005
; Global Variables Used: none
; Purpose:exchanges filled bods for new from a BOD book,
; moves rewards to pack animal, and places new bods in book.
; user can identify what they want to keep, and what they want
; to drop (so that someone else might benefeit from the
; shovels and axes that you do not want)
;--------------------------------------------------
;Customize
;--------------------------------------------------
; ID of Items that you want to keep
set %keepers KEG_BUI_POF_ZZF_QPF_tvh_ewh_nvi_dui_aui_fui_gui_gbg_TLH
; ID of Items that you want to drop on ground
set %tossit kkh_twf
; Put the number of the option for Bulk Order Deed
; on your shard here
set %voption 4 ;<---
; Put the option number for packy backpack here
set %poption 11 ;<---
;--------------------------------------------------
;edit below at your own risk
;--------------------------------------------------
;display ok Once you start this, follow the prompts then
          ; + let it run do not try to click anything for the script.
           ;+ If by chance it does mess up, stop it then try again.
           ;+ If the problem persists please stop and drop me a PM
           ;+ So I can try to fix it for you.
wait 1
event macro 31 0
wait 10

event macro 8 1
while #contName <> paperdoll_gump && #contSize <> 262_324
      {
       wait 10
       contpos 800 280
      }
  wait 10

event macro 8 7
while #contName <> container_gump && #contSize <> 230_204
      {
       wait 10
       contpos 610 570
      }
wait 10

setup:
gosub vendorselect
wait 1
gosub secureselect
wait 1
gosub filledbookselect
wait 1
gosub emptybookselect
wait 5

;--------------------------------------------------
;Main Loop
;--------------------------------------------------
loop:
gosub getbod
wait 1
gosub clickok
wait 1
gosub movenewbod
wait 1
gosub turnina
wait 1
gosub turninb
wait 1
gosub tossit
wait 1
gosub cutfat
wait 10
goto loop
;--------------------------------------------------
;Vendor Selector
;--------------------------------------------------
sub vendorselect
set #sysmsgcol 68
event sysmessage Selezionare il vendor $
selectionv:
set #targcurs 1
while #targcurs = 1
wait 2
set %trader #ltargetid
vmove:
finditem %trader
if #finddist > 1
   {
  move #findx #findy a
  }
event property %trader
      if ( guildmaster in #property ) || ( guildmistress in #property )
         {
          event sysmessage Sorry guild masters do not give bods try again $
          wait 2
          goto selectionv
         }
      if ( blacksmith in #property ) || ( tailor in #property ) || ( weaver in #property ) || ( weaponsmith in #property )
         {
          msg #property
          wait 5
          return
         }
      else
           {
             event sysmessage Wrong vendor type, please try again $
             wait 2
             goto selectionv
           }
goto vmove
;--------------------------------------------------
;secure Selector
;--------------------------------------------------
sub secureselect
display yesno Click yes for Packy, click no for bank
if #dispres = yes
{
   set #lobjectid #charid
   event macro 17
   msg all follow me $
   wait 5
   event sysmessage Target the Packy to dump to $
   set #targcurs 1
   while #targcurs = 1
   wait 2
   set %storage #ltargetid
   exevent popup %storage %poption
   wait 5
   while #contName <> container_gump && #contSize <> 230_204
   wait 10
   contpos 440 570
   wait 10
   return
}
if #dispres = no
{
   msg bank $
   wait 5
   while #contName <> container_gump && #contSize <> 180_240
   wait 10
   contpos 440 570
   wait 5
   Display yesno This was devised to be used in Luna $
        +You must be able to access both the bank and the $
        +Vendor From the same location. $
        +Is the bankbox open? $
   if #dispres = yes
   {
       set %storage #contid
       wait 5
       return
   }
   if #dispres = no
   {
       display ok You need to either get to a spot where $
          +you can access the vendor and the bank $
          +without moving, or get a packy.$
          +(a lama is cheap)$$
          +Stopping the script now. $
          wait 2
          halt
   }
}
return
;--------------------------------------------------
;filled book Selector selezionare book con i bod da consegnare
;--------------------------------------------------
sub filledbookselect
  wait 5
  set #sysmsgcol 68
  event sysmessage Target the book that has the bods to be traded
 filledselect:
  set #targcurs 1
  while #targcurs = 1
     wait 2
  set %bodbag #ltargetid
  event property %bodbag
  if deeds_in_book:_0 in #property
     {
      wait 2
      event sysmessage That book is empty, please select a new one.
      goto filledselect
     }
 	set #lobjectid %bodbag
	event macro 17
    wait 2
    while #contName <> generic_gump && #contSize <> 615_454
        wait 10
         event property %trader
         wait 5
         if ( tailor in #property ) || ( weaver in #property )
            {
             set %f1clickx #contposx + 50
             set %f1clicky #contposy + 40
             wait 5
             click %f1clickx %f1clicky
             wait 10
             set %f2clickx #contposx + 40
             set %f2clicky #contposy + 285
             wait 5
             click %f2clickx %f2clicky
             wait 5
            }
         if ( blacksmith in #property ) || ( weaponsmith in #property )
            {
             set %f3clickx #contposx + 50
             set %f3clicky #contposy + 40
             wait 5
             click %f3clickx %f3clicky
             wait 10
             set %f4clickx #contposx + 40
             set %f4clicky #contposy + 205
             wait 5
             click %f4clickx %f4clicky
             wait 5
            }

         wait 5
         set %cclickx #contposx + 25
         set %cclicky #contposy + 25
         wait 5
         click %cclickx %cclicky r
         wait 5
         set %cclickx #contposx + 25
         set %cclicky #contposy + 25
         wait 5
         click %cclickx %cclicky r

  wait 10
return

;--------------------------------------------------
;empty book Selector     selezionare il libro vuoto
;--------------------------------------------------
sub emptybookselect
event sysmessage Target the BOD book to store new BOD's in You can target a bag if you really want, $
wait 2

set #targcurs 1
while #targcurs = 1
wait 5
set %bodbook #ltargetid
wait 5
return

;-------------------------------------------------
;gets a new bod
;-------------------------------------------------
sub getbod
    getbod:
   exevent popup %trader %voption
   wait 14
   return
;-------------------------------------------------
; clicks yes in the bod menu
; Thx to Redsatin and Tecmo for this part.
;-------------------------------------------------
sub clickok

     set %timeout #scnt2 + 40
    bodgump:
    wait 4
    if #ContName = generic_gump
    {
     wait 5
     set %size #ContSize
     str right %size 3
     wait 5
     set %clicky #strres + #ContPosY - 30
     set %ClickX 115 + #ContPosX
     wait 6
     click %clickx %clicky
     wait 3
     return
    }
    if %timeout > #scnt2
      {
      wait 2
      goto bodgump
      }
    wait 3
    return

**Marino** · 30-03-2012, 20:00

part2/2

codice:

;--------------------------------------------------
;transfers new empty bods to book
;--------------------------------------------------
Sub movenewbod
    movenewbod:
finditem EYM c_ , #backpackid
wait 5
if #findkind <> -1
   {
    wait 4
    exevent drag #findid
    wait 5
    exevent dropc %bodbook
    wait 5
    goto movenewbod
   }
wait 5
if #contkind = IOIB
  {
   set %newx #contposx + 20
   set %newy #contposy + 20
   wait 5
   click %newx %newy r
   wait 5
   return
  }
  wait 4
 return
;--------------------------------------------------------------------------------------------
;drop bod out of book
;--------------------------------------------------------------------------------------------
sub turnina
set %journal #jindex
 	set #lobjectid %bodbag
	event macro 17
	wait 11
	for %i %journal #jindex
		{
			scanjournal %i
			if the_book_is_empty. in #journal
     {
     wait 2
     gosub finaldump
     }
  }
    wait 4
  while #contName <> generic_gump && #contSize <> 615_454
         wait 5
         {
          set %dclickx #contposx + 40
          set %dclicky #contposy + 105
          wait 5
          click %dclickx %dclicky
          wait 5
         }
  wait 5
  if #contName = generic_gump && #contSize = 615_454
        {
         set %newx #contposx + 20
         set %newy #contposy + 20
         wait 5
         click %newx %newy r
         wait 5
        }
  wait 5
  return
;--------------------------------------------------------------------------------------------
;give the bod to vendor
;--------------------------------------------------------------------------------------------
sub turninb
finditem EYM c_ , #backpackid
if #findkind <> -1
{
   wait 6
   exevent drag #findid
   wait 6
   exevent dropc %trader
   wait 6
   return
}
if #findkind = -1
{
 gosub tossit
 gosub finaldump
}
;--------------------------------------------------------------------------------------------
;drops unwanted stuff to the ground
;--------------------------------------------------------------------------------------------
sub tossit

    finditem %1
    if #findkind <> -1
    {
        finditem %tossem G_ , 0
        if #findcnt < 20
        {
            finditem %tossem c_ , %storage
            if #findkind <> -1
            {
                for %i 1 #findcnt
                {
                      set #findindex %i
                      exevent drag #findid #findstack
                      gosub takerandom
                      set %gdropx #charposx + #result
                      gosub takerandom
                      set %gdropy #charposy + #result
                      wait 2
                      exevent dropg %gdropx %gdropy
                      wait 6
                }
            }
        }
    }
wait 10
return
;-------------------------------------------------
; drops stuff to storage
;-------------------------------------------------
sub cutfat
wait 2
  storagedrop:
   finditem %keepers c_ , #backpackid
   wait 2
   if #findkind <> -1
   {
      wait 1
      exevent drag #findid #findstack
      wait 5
      exevent dropc %storage
      wait 5
      goto storagedrop
   }
  }
wait 2
return
;-------------------------------------------------
;Final Dump to storage
;-------------------------------------------------
sub finaldump
 lastdrop:

  wait 5
   finditem %keepers c_ , #backpackid
   if #findkind <> -1
   {
      wait 1
      exevent drag #findid #findstack
      wait 5
      exevent dropc %storage
      wait 5
      goto lastdrop
   }
Display ok Looks like you are out of bods to turn in.
           + Thank you for using Traston's Simple Bod Swapper
           + Please let me know what you think.
Halt

**fengyr** · 31-03-2012, 03:02

X marino:

codice:

;==================================
; Script Name: Power Bod Swapper
; Author: Felix
; Version: 1.31
; Client Tested with: 6.0.10
; EUO version tested with: 1.5.143
; Shard FS: UODreams
; Public Release: 31/01/2009
; Purpose: swapping tailoring bods in luna
;==================================
set %storage YDCQNMD ; set here id of backpack in bank
set %trader WDPD ; id of npc u give bod to
set %banker1 PYFD ; id of first banker npc in luna
set %banker2 QYFD ; id of second banker npc in luna
; ID of Items that you want to keep
set %keepers KEG_BUI_POF_ZZF_TWF_QPF_tvh_ewh_dui_aui_fui_gui_gbg_TLH
set %tossem NVI ; ID of rewards that you want to drop on ground
; Put the number of the option for Bulk Order Deed
; on your shard here
set %voption 4 ;<---


set %filledbookchangestr Deeds , #spc , in , #spc , Book: , #spc , 0
set #lpc 1000

set %clothbod1 bandana
set %clothbod2 body , #spc , sash
set %clothbod3 bonnet
set %clothbod4 surcoat
set %clothbod5 cap
set %clothbod6 cloak
set %clothbod7 doublet
set %clothbod8 dress
set %clothbod9 shirt
set %clothbod10 hat
set %clothbod11 tunic
set %clothbod12 apron
set %clothbod13 jester
set %clothbod14 kilt
set %clothbod15 pants
set %clothbod16 skirt
set %clothbod17 skullcap
set %clothbod18 robe
set %clothbodq 18

set %leatherbod1 shoes
set %leatherbod2 bots
set %leatherbod3 sandals
set %leatherbod4 boots
set %leatherbodq 4


gosub findbooks
gosub checkfilledbook
gosub checkunsortedbook
;gosub checkclothbook
;gosub filledbookselect
;wait 1
;gosub emptybookselect
;wait 5

;--------------------------------------------------
;Main Loop
;--------------------------------------------------
gosub openbank
set %bodgiventovendor #true
loop:
if %bodgiventovendor
{
 gosub getbod
 gosub clickok
;wait 1
}
else
{
    gosub checkunsortedbook
    gosub movenewbod
    wait 5
    gosub checkfilledbook
    gosub takebodfrombook 20
}
;wait 1
gosub turninb
set %bodgiventovendor #result
if #weight > #maxweight - 20
{
   gosub PutRewardsToStorage
   gosub DropRewardsOnGround
}
sleep 10
goto loop

sub checkfilledbook
    event property %filled
    if %filledbookchangestr in #property
    {
       set %filledi %filledi + 1
       if %filledi <= %filledq
       {
          set %filled %filled . %filledi
       }
       else
           {
              gosub DropRewardsOnGround
              gosub PutRewardsToStorage
              gosub movenewbod
              while 1 = 1
              {
                    sound
                    sleep 10
              }
           }

    }
return

sub checkunsortedbook
    event property %unsorted
    if 500 in #PROPERTY
    {
       set %unsortedi %unsortedi + 1
       if %unsortedi > %unsortedq
       {
          pause
       }
       set %unsorted %unsorted . %unsortedi
    }
    if %cloth <> %unsorted
    {
         event property %cloth
         if 500 in #PROPERTY
         {
                set %clothi %clothi + 1
                set %cloth %cloth . %clothi
                if %clothi > %clothq
                {
                   set %cloth %unsorted
                }
          }
    }
    if %leather <> %unsorted
    {
         event property %leather
         if 500 in #PROPERTY
         {
                set %leatheri %leatheri + 1
                set %leather %leather . %leatheri
                if %leatheri > %leatherq
                {
                   set %leather %unsorted
                }
          }
    }
    if %bone <> %unsorted
    {
         event property %bone
         if 500 in #PROPERTY
         {
                set %bonei %bonei + 1
                set %bone %bone . %bonei
                if %bonei > %boneq
                {
                   set %bone %unsorted
                }
          }
    }
    if %barbed <> %unsorted
    {
         event property %barbed
         if 500 in #PROPERTY
         {
                set %barbedi %barbedi + 1
                set %barbed %barbed . %barbedi
                if %barbedi > %barbedq
                {
                   set %barbed %unsorted
                }
          }
    }
    if %large <> %unsorted
    {
         event property %large
         if 500 in #PROPERTY
         {
                set %largei %largei + 1
                set %large %large . %largei
                if %largei > %largeq
                {
                   set %large %unsorted
                }
          }
    }
return

sub findbooks
    set %filledi 0
    set %unsortedi 0
    set %filledq 0
    set %unsortedq 0
    set %clothi 0
    set %clothq 0
    set %leatheri 0
    set %leatherq 0
    set %bonei 0
    set %boneq 0
    set %barbedi 0
    set %barbedq 0
    set %largei 0
    set %largeq 0

    finditem DYM
    for %i 1 #findcnt
    {
        set #findindex %i
        event property #findid
        if filled in #property
        {
           set %filledi %filledi + 1
           set %filled . %filledi #findid
        }
        if unsorted in #property
        {
           set %unsortedi %unsortedi + 1
           set %unsorted . %unsortedi #findid
        }
        if cloth in #property
        {
           set %clothi %clothi + 1
           set %cloth . %clothi #findid
        }
        if leather in #property
        {
           set %leatheri %leatheri + 1
           set %leather . %leatheri #findid
        }
        if bone in #property
        {
           set %bonei %bonei + 1
           set %bone . %bonei #findid
        }
        if barbed in #property
        {
           set %barbedi %barbedi + 1
           set %barbed . %barbedi #findid
        }
        if large in #property
        {
           set %largei %largei + 1
           set %large . %largei #findid
        }
    }
set %filledq %filledi
set %filledi 1
set %unsortedq %unsortedi
set %unsortedi 1
set %clothq %clothi
set %clothi 1
set %leatherq %leatheri
set %leatheri 1
set %boneq %bonei
set %bonei 1
set %barbedq %barbedi
set %barbedi 1
set %largeq %largei
set %largei 1
if %unsortedq = 0 || %filledq = 0
{
   halt
}

set %filled %filled . %filledi
set %unsorted %unsorted . %unsortedi

if %clothq = 0
   set %cloth %unsorted
else
   set %cloth %cloth . %clothi

if %leatherq = 0
   set %leather %unsorted
else
   set %leather %leather . %leatheri

if %boneq = 0
   set %bone %unsorted
else
   set %bone %bone . %clothi

if %barbedq = 0
   set %barbed %unsorted
else
   set %barbed %barbed . %barbedi

if %largeq = 0
   set %large %unsorted
else
   set %large %large . %clothi


return

**fengyr** · 31-03-2012, 03:03

codice:

;-------------------------------------------------
;gets a new bod
;-------------------------------------------------
sub getbod
    getbod:
   exevent popup %trader %voption
   ;wait 2
   return
;-------------------------------------------------
; clicks yes in the bod menu
; Thx to Redsatin and Tecmo for this part.
;-------------------------------------------------
sub clickok

     set %timeout #scnt2 + 10
    bodgump:
    wait 1
    if #ContName = generic_gump && #CONTSIZE <> 615_454
    {
     ;wait 2
     set %size #ContSize
     str right %size 3
     ;wait 0
     set %clicky #strres + #ContPosY - 30
     set %ClickX 115 + #ContPosX
     ;wait 5
     click %clickx %clicky
     ;wait 2
     return
    }
    if %timeout > #scnt2
      {
      wait 1
      goto bodgump
      }
    wait 2
    return
;--------------------------------------------------
;transfers new empty bods to book
;--------------------------------------------------
Sub movenewbod
    finditem EYM c_ , #backpackid
    if #findkind <> -1
    {
      for %i 1 #findcnt
      {
          set #findindex %i
          repeat
              event property #findid
              str count #property $
              sleep 10
          until #strres > 1
          set %moved #false
          set %smallfilled #false
          if small in #property
          {
             gosub bodfilled #property
             set %smallfilled #result
          }
          if ( ! %moved ) && ( ! %smallfilled ) && ( spined in #property || horned in #property || barbed in #property )
          {
             gosub movetobook #findid %barbed
             set %moved #true
          }
          if ( ! %moved ) && ( ! %smallfilled ) && bone in #property
          {
             gosub movetobook #findid %bone
             set %moved #true
          }
          if ( ! %moved ) && ( large in #property )
          {
             gosub movetobook #findid %large
             set %moved #true
          }
          if ( ! %moved ) && ( ! %smallfilled ) && ( leather in #property || studded in #property )
          {
             gosub movetobook #findid %leather
             set %moved #true
          }
          if ( ! %moved ) && ( ! %smallfilled )
          {
                 set %isclothbod #false
                 for %j 1 %clothbodq
                 {
                     if %clothbod . %j in #property
                        set %isclothbod #true

                 }
                 if %isclothbod
                 {
                    gosub movetobook #findid %cloth
                    set %moved #true
                 }
                 else
                 {
                     set %isleatherbod #false
                     for %j 1 %leatherbodq
                     {
                         if %leatherbod . %j in #property
                            set %isleatherbod #true
                     }
                     if %isleatherbod
                     {
                        gosub movetobook #findid %leather
                        set %moved #true
                     }
                 }

         }
      }
    }
   if #contkind = IOIB
   {
   pause
     set %newx #contposx + 20
     set %newy #contposy + 20
     wait 5
     click %newx %newy r
     wait 5
     return
   }
 return

 sub bodfilled
 ;%1 #property
             str count %1 10
             set %cnt10 #strres
             str count %1 15
             set %cnt15 #strres
             str count %1 20
             set %cnt20 #strres
 if %cnt10 = 2 || %cnt15 = 2 || %cnt20 = 2
    return #true
 else
    return #false
 ;end bodfilled

 sub movetobook
 ;%1 bod
 ;%2 book
          exevent drag %1
          wait 2
          exevent dropc %2
          wait 6
 return
;--------------------------------------------------------------------------------------------
;drop bod out of book
;--------------------------------------------------------------------------------------------
sub takebodfrombook
;%1 numberofbods
  set #lobjectid %filled
  event macro 17
  for %i 1 %1
  {
      set %timeout #scnt2 + 20
      while #contName <> generic_gump && #contSize <> 615_454 && %timeout > #scnt2
        wait 1
      if #scnt2 > %timeout
         break
      set %dclickx #contposx + 40
      set %dclicky #contposy + 105
      wait 1
      click %dclickx %dclicky
  }
  set %timeout #scnt2 + 20
  while #contName <> generic_gump && #contSize <> 615_454 && %timeout > #scnt2
        wait 1

  set %newx #contposx + 20
  set %newy #contposy + 20
  wait 1
  click %newx %newy r

  return
;--------------------------------------------------------------------------------------------
;give the bod to vendor
;--------------------------------------------------------------------------------------------
sub turninb
finditem EYM c_ , #backpackid
if #findkind <> -1
{
   set %filledbodfound #false
   for %i 1 #findcnt
   {
       set #findindex %i
       repeat
             event property #findid
             str count #property $
             sleep 10
       until #strres > 1
       gosub bodfilled #property
       if #result
       {
          set %bod #findid
          set %filledbodfound #true
          goto turninb_bodfound
       }
   }
   turninb_bodfound:
   if %filledbodfound
   {
      finditem %trader
      while #finddist > 2
      {
            wait 1
            finditem %trader
      }
      gosub movetobook %bod %trader
      return #true
   }
   else
       return #false
}
else
  return #false

sub takerandom
    set %result #random / 200
    set %result %result - 2
    return %result
return


;--------------------------------------------------------------------------------------------
;drops unwanted stuff to the ground
;--------------------------------------------------------------------------------------------
sub DropRewardsOnGround
            finditem %tossem c_ , #backpackid
            repeat
                  if #findkind <> -1
                  {
                     for %i 1 #findcnt
                     {
                      set #findindex %i
                      exevent drag #findid #findstack
                      gosub takerandom
                      set %gdropx #charposx + #result
                      gosub takerandom
                      set %gdropy #charposy + #result
                      wait 2
                      exevent dropg %gdropx %gdropy
                      wait 6
                     }
                  }
                  finditem %tossem c_ , #backpackid
            until #findkind = -1
return
;-------------------------------------------------
; drops stuff to storage
;-------------------------------------------------
sub PutRewardsToStorage
  finditem %storage
  if #findkind = -1
  {
     gosub openbank
  }
  ;event macro 1 0 #result
  if #result = ok || #findkind <> -1
  {
     finditem %keepers c_ , #backpackid
     repeat
           if #findkind <> -1
           {
              for %i 1 #findcnt
              {
               set #findindex %i
               exevent drag #findid #findstack
               wait 2
               exevent dropc %storage
               wait 6
              }
           }
           finditem %keepers c_ , #backpackid
     until #findkind = -1
  }
return

sub openbank
    while #CHARPOSX <> 976 || #CHARPOSY <> 526 || #CHARPOSZ <> -50
    {
        event pathfind 976 526 -50
        wait 3
    }
    set %timeforbank #systime + 30000
    repeat
          exevent popup %banker1 2
          exevent popup %banker2 2
          finditem %storage
          sleep 10
    until #findkind = 0 || #systime > %timeforbank
    finditem %storage
    if #findcnt = 1
    {
       wait 60
       set #lobjectid %storage
       event macro 17 0
       return ok
    }
return

non l'ho mai usato ne controllato, non chiedermi niente.
PS: ovviamente non mi faccio mai gli affari miei quando vedo gli script degli altri.... a prima vista c'� da scrivere una funzione decente per il trash nelle apposite chest, il drop a terra non � affidabile e pure sgradevole

quindi non usatelo cos� com'�

**MrMalaparte** · 17-04-2012, 15:49

Boscag non completa bene i bod black, dopo qualche giorno me ne sono accorto ma soprattutto finito gli occhi, a volte trasha bod buoni per runici

annuncio

Richiesta aiuto fillaggio bod

Richiesta aiuto fillaggio bod

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta