[MODIFICA] Script bendata

[riccardino]

Buongiorno, avrei bisogno di una piccola modifica a questa script, se qualcuno ne è capace mi contatti in icq o lasci contatto e lo richiamerò io.

La semplice modifica di cui ho bisogno è la seguente:

-Nel caso usi hidding la script non mi benda più
-Appena finisce hidding la script mi ribenda

Questa è la script:


; .Ultimate Healer.
; TheGod

set #lpc 100
set %d #false
set %aids ZLF

menu window size 10 90
menu window title
menu window color black
menu font bgcolor black
menu font color green
menu font size 18
menu text time 15 15 0
menu font size 22
menu font color yellow
menu text use_cure 15 40 .
menu show

main:
if yes in #charghost || #targcurs = 1
goto main
if #hits < #maxhits || c in #charstatus
gosub aids
goto main

sub aids
again:
event macro 8 7
finditem %aids c_ , #backpackid
if #findstack = 0
return
set %time ( ( 11 - ( #dex / 20 ) ) * 10 )
if d in #charstatus
{
set %end_d #scnt2 + 62
d_loop_1:
if ( ( #scnt2 + %time ) > %end_d ) || d notin #charstatus
goto apply
goto d_loop_1
}
apply:
event macro 58 0
wait 1
set %start #scnt2
set %end %start + %time
gosub check_msg
if #result = 0
return
gosub check_time
if #result = 1
goto again
return

sub check_msg
set %out #scnt2 + 5
set %index 1
msg_loop:
scanjournal %index
if applying in #journal
return 1
if being in #journal || #scnt2 > %out
return 0
set %index %index + 1
goto msg_loop

sub check_time
set %left %end - #scnt2
set %no_print #scnt2 + 5
menu set time %left
aids_loop:
if #scnt2 >= %no_print
{
if %left <= 20 && c in #charstatus
menu set use_cure NOW!
menu set time %left
set %no_print #scnt2 + 5
}
if d in #charstatus && %d = #false
{
set %d #true
set %end_d #scnt2 + 62
d_loop_2:
if ( ( #scnt2 + %time ) > %end_d ) || d notin #charstatus
{
menu set use_cure .
menu set time 0
return 1
}
if #scnt2 >= %no_print
{
if %left <= 20 && c in #charstatus
menu set use_cure NOW!
menu set time %left
set %no_print #scnt2 + 5
}
goto d_loop_2
}
if #scnt2 > %end
{
if %d
set %d #false
menu set use_cure .
menu set time 0
return
}
set %left %end - #scnt2
goto aids_loop

[morhua]

Basta aggiungere quello che vedi evidenziato in rosso nel pezzo di codice a inizio script:

main:
if yes in #charghost || #targcurs = 1 || H in #charstatus
goto main
if #hits < #maxhits || c in #charstatus
gosub aids
goto main

[riccardino]

Basta aggiungere quello che vedi evidenziato in rosso nel pezzo di codice a inizio script:

main:
if yes in #charghost || #targcurs = 1 || H in #charstatus
goto main
if #hits < #maxhits || c in #charstatus
gosub aids
goto main

Grazie mille