[EASYUO HELP] script arm\disarm

[Dav87E]

cdt cerco uno script per easy uo che mi armi e disarmi un arma (della quale si possa settare l'id) in modo tale da mettere piu armi su piu tasti....perche con razor nn funge^^

[adrytug]

prova questo:
;===================================
; Script Name: Tecmo's ReArm It
; Author: Tecmo
; Version: 1.10
; Client Tested with: 5.0.1a
; EUO version tested with: 1.50
; Shard OSI / FS: OSI / FS
; Revision Date: 2005Nov08
; Public Release: 2004Oct13
; Global Variables Used: no
; Purpose: Auto ReArm Weapon of Choice
;===================================

;Reason: To help Alcedes in his scripting and EUO language learning needs.
;Plug in and Hit Play... Not modifications needed.
;May not work with all weapons (did not work with two handed items, need more coding for that.

SET %ReArmDelay 5s
GOTO InterActiveSetup ;Remark this line out and set the below ID's to skip setup each time.

;SKIP Setup / Keep Config ; Set Item to #FALSE if not using
SET %Weapon #TRUE
SET %WeaponID [put id here]

SET %Shield #TRUE
SET %ShieldID [put id here]
GOTO Loop

;=======================
InterActiveSetup:
SET %Weapon #FALSE
SET %Shield #FALSE
GOSUB TecmoSplashIntro
GOSUB Setup


;=======================
Loop:
IF %Weapon = #TRUE && %Shield = #TRUE
{
WAIT %ReArmDelay
FINDITEM %WeaponID C_ , #CHARID
IF #FINDKIND = -1
GOSUB ReArm %WeaponID
WAIT 20
FINDITEM %ShieldID C_ , #CHARID
IF #FINDKIND = -1
GOSUB ReArm %ShieldID
}
ELSE
{
IF %Weapon = #TRUE
{
WAIT %ReArmDelay
FINDITEM %WeaponID C_ , #CHARID
IF #FINDKIND = -1
GOSUB ReArm %WeaponID
}
ELSE
{
WAIT %ReArmDelay
FINDITEM %ShieldID C_ , #CHARID
IF #FINDKIND = -1
GOSUB ReArm %ShieldID
}
}
WAIT 10
GOTO Loop

;=======================
SUB Setup
DISPLAY YESNO Using a Weapon? $
+If so, Press Yes and target the Weapon!
IF #DISPRES = YES
{
SET %Weapon #TRUE
GOSUB TargetCursor
SET %WeaponID #LTARGETID
}
DISPLAY YESNO Using a Shield? $
+If so, Press Yes and target the Shield!
IF #DISPRES = YES
{
SET %Shield #TRUE
GOSUB TargetCursor
SET %ShieldID #LTARGETID
}
RETURN

;=======================
SUB ReArm
EXEVENT DRAG %1
;WAIT 10
EXEVENT DROPPD
WAIT 2
RETURN

;=======================
SUB TargetCursor
SET #TARGCURS 1
WHILE #TARGCURS = 1
WAIT 20
RETURN

;=======================
SUB TecmoSplashIntro
MENU font
MENU hide
MENU clear
MENU window transparent 0
MENU show
MENU font name verdana
MENU font color silver
MENU font bgcolor black
MENU window color black
MENU window size 260 125
MENU window title Welcome !
MENU font size 10
MENU font style bi
MENU text presenting 25 15 Presenting...
MENU font color 22222
MENU font size 20
MENU font style b
FOR %trans 0 90
{
MENU Window Transparent %trans
}
GOSUB TecmoStarWarsText text1 52 40 Tecmo's
GOSUB TecmoStarWarsText text2 42 70 ReArm
GOSUB TecmoStarWarsText text3 160 70 It
MENU font size 8
MENU font color silver
MENU text text4 195 86 ©
WAIT 40
SET #LPC 50
WAIT 2s
MENU hide
MENU clear
RETURN

;=======================
SUB TecmoStarWarsText
FOR %font 1 21
{
WAIT 0
MENU font size %font
MENU delete text %1
MENU text %1 %2 %3 %4
}
RETURN

[Dav87E]

nn ne capisco molto di script, pero' a quanto ho visto scelgo l'arma che devo usare e ogni volta che vengo disarmato me la riarma da solo in automatico;

quello che intendevo io è: io ho una laefbalde, e una katana;
premo il tasto 1 ---> mi disarma (da qualsiasi cosa ho in mano) e mi arma la leafblade;
premo il tasto 2----> mi disarma (da qualsiasi cosa ho in mano) e mi arma la katana

l'ho fatto su razor, ma se tipo ho 2 leafblade me le equipa random...pensavo che su euox si potesse fare una cosa simile settando gli id dell'arma in modo tale da nn andare a random....
esiste?

[GiaPly3]

Si che si può, basta avere gli id di entrambe le leaf.

[TheGod]

ecco quà! devi solo inserire dopo i due set gli id delle due armi ed il gioco è fatto ^^ buon divertimento

set %katana
set %leafblade

main:
onhotkey 1
 gosub wear %katana
onhotkey 2
 gosub wear %leafblade
goto main

sub wear
 finditem %1 c_ , #backpackid
 if #findkind = 1
  {
  event macro 24 2
  wait 10
  }
 else
  return
 exevent drag %1
 wait 5
 exevent droppd
 wait 5
 return

[Dav87E]

altra domanda xD :

su easy uo, il tasto 1 sarebbe ---> on hotkey 1.....e la freccia dx e sx? ---> on hotkey right??

[TheGod]

altra domanda xD :

su easy uo, il tasto 1 sarebbe ---> on hotkey 1.....e la freccia dx e sx? ---> on hotkey right??

con le onhotkey 1/2/3/blabla si intendono i numeri sopra le lettere (non quelli del tastierino numerico per intenderci), la freccia destra e sinistra non si può impostare sù easyuo =( comunque per lo script ok? l'ho buttato giù al volo ^^ tra l'altro ora te l'ho edito un attimo che mi sono dimenticato una cosa per non farlo impallare (non succede teoricamente ma potrebbe capitare)

EDIT: ok corretto lo script ^^

[Dav87E]

set RTGHTH %katana
set RHTHTH %leafblade

cosi?

[TheGod]

set RTGHTH %katana
set RHTHTH %leafblade

cosi?

nu così:

set %katana RTGHTH
set %leafblade RHTHTH