Tweet
[EASYUO HELP] Autolooter
Cerco aiuto per uno script autolooter che uso mentre gioco (non away), dovrei aggiungere bone pile, rib cage ecc...potete aiutarmi pls??
grazie in anticipo
ecco il codice:
grazie in anticipo
ecco il codice:
codice:
;=============================================================
; Script Name: BadManiac's Automagic Looting 2
; Author: BadManiac
; Version: 2.56
; Client Tested with: 5.0.0b
; EUO version tested with: 1.42.00B2 and 1.5 Test Version 56
; Shard OSI / FS: OSI / works on FS with correct item types
; Revision Date: 12/09/2005
; Public Release: 05/12/2004
; Global Variables Used:
; *bml_busy Denotes Script is busy looting
; *bml_minvalue Contains the last min value for equipment
; *bml_settings Contains the last used settings for the script
; *bml_hotkey Stores the current looting hotkey
; Purpose:
; Powerful fast Automagic Looting with item evaluation, corpse cutting,
; resource gathering and cutting, and looting equipment over a certain value
;=============================================================
SET #LPC 50
IGNOREITEM RESET BmLooter
;=============================================================
;One delay timing, this timer is the only thing you need to edit if the script has
;problems. Should be around 5, but 4 or 3 works fine for low ping high speed
;conn's
;Dialup and high ping users might have to set it as high as 6 or 7.
;=============================================================
SET %bml_waittime 6
;=============================================================
;Time to wait between actions to prevent errors. Lowering it might cause errors
;=============================================================
SET %bml_action_wait 13
;=============================================================
; The lootlists are set here, other is a list of random other loot that doesn't fit
; anywhere else.
;=============================================================
SET %gold POF_
SET %jewels HVF_UVF_FVF_EVF_OVF_VUF_GVF_RVF_BVF_VVF_NVF_ZVF_
SET %reagents KUF_JUF_KZF_JZF_MZF_WZF_RZF_SZF_DUF_TZF_UZF_YZF_IUF_
SET %scrolls AUL_BUL_cul_dul_EUL_FUL_GUL_hul_iul_JUL_KUL_LUL_MUL_nul_oul_PUL_QUL_RUL_SUL_tul_UUL_vul_wul_XUL_YUL_zul_avl_gvl_fvl_ivl_hvl_cvl_NTL_otl_ptl_qtl_rtl_stl_ttl_utl_VTL_wtl_XTL_YTL_ZTL_qxl_pxl_zxl_nxl_wxl_vxl_yxl_xxl_zfj_byl_cyl_dyl_eyl_fyl_gyl_hyl_iyl_jyl_kyl_kym_pym_sym_tym_wym_uym_
SET %arrowsbolts RWF_LNK_FKF_
SET %solenloot GMF_OKF_TTO_IJG_
SET %jukaloot JSL_USL_WOH_YWL_
SET %paragonloot IIF_IKF_BUD_HIF_
;Resource loot lists
SET %feather VLK_
SET %wool HFG_
SET %bones OJK_XIK_SJK_IJK_TJK_BJK_UJK_DJK_MJK_AJK_LJK_FJK_RJK_EJK_ZIK_YIK_JJK_GJK_KJK_HJK_
SET %leather EEG_GED_DEG_
;Itemtypes for bones and leather after cutting with scissor
SET %cutresources JJG_GUF_
;Seeds, TMap, Gargoyle Pickaxe, Demon Bones, Tribal Berry, Origami Paper, Healthy Gland
SET %other PDF_XVH_QPF_OZF_QQD_QIP_NWK_
;=============================================================
;user1 and user2 are for the users personal lists. They are selectable
;in the menu and you can add your own loot types to them.
;The lists below are examples of what you may want to include
;=============================================================
;Plate of Cookies, Fertile Dirt, Tribal Mask,Mask of Orcish Kin, Evil Orc Helm, Fire Horn
SET %user1 SLI_NZF_PZH_VSH_NWL_IWL_ZWF_
;Bandage, Parrots
SET %user2 ZLF_YJM_
;=====================================
;Set lootlists for equippment
;=====================================
GOSUB SetEquipLootlists
;=============================================================
;This is a list of the different bags types that will be opened and looted,
;as well as types for knives and scissors for cutting corpses and leather.
;DON'T EDIT. unless you know what you are doing.
;=============================================================
SET %bags ZJF_LKF_CKF_YKK
SET %knives TSF_GMH_BNF_CNF
SET %scissors KAG_JAG
;=====================================
; This is the INIT part of the script
;=====================================
GOSUB CheckFreeShard bml_freeshard
GOSUB ShowLootMenu
GOSUB LootInit
;Init End
;=====================================
;The script main loop starts here
;=====================================
mainloop:
;Make script less intrusive by checking for lifted objects, target cursor, charcter status or char movement.
GOSUB CheckStatus
IF ! #RESULT
GOTO mainloop
GOSUB CheckWeight
;If hotkey is set, wait until the specified key is pressed before starting to loot.
IF %hotkey
{
FOR %i 1 1
{
SET %i 0
ONHOTKEY *bml_hotkey
{
SET %i 1
KEY BACK
}
}
}
;All is well, go ahead and look for corpses in range to loot.
GOSUB LookForCorpse
IF #RESULT <> #FALSE
{
;Set global to denote that we are busy looting
SET *bml_busy #TRUE
GOSUB LootPack #RESULT
IF #RESULT
IGNOREITEM %bml_corpse BmLooter
GOSUB TidyPack
}
;Set global to denote that we are done looting
SET *bml_busy #FALSE
WAIT %bml_waittime
GOTO mainloop
;================================================================
;SUBROUTINES START HERE.
;================================================================
SUB LootInit
IF %mcut
{
FINDITEM %scissors C_ , #BACKPACKID
IF #FINDKIND = -1
{
DISPLAY OK You need scissors to cut looted resources. $ HALTED!
HALT
}
FINDITEM %knives C_ , #BACKPACKID
IF #FINDKIND = -1
{
DISPLAY OK You need a knife to cut corpses to loot resources. $ HALTED!
HALT
}
}
IF %lootbag = #TRUE
{
SET #LTARGETID N/A
DISPLAY OK Please target your LOOTBAG and click it. $
SET #TARGCURS 1
findbag:
WAIT 1
IF #TARGCURS = 1
GOTO findbag
SET %origx #CURSORX
SET %origy #CURSORY
SET %lootbagid #LTARGETID
FINDITEM %lootbagid C
SET %lxmod %origx - #FINDX
SET %lymod %origy - #FINDY
SET %regbagid %lootbagid
SET %rxmod %lxmod
SET %rymod %lymod
}
IF %regbag = #TRUE
{
DISPLAY OK Please target our REGBAG and click it.$
SET #LTARGETID N/A
SET #TARGCURS 1
findregbag:
WAIT 1
IF #TARGCURS = 1
GOTO findregbag
SET %origx #CURSORX
SET %origy #CURSORY
SET %regbagid #LTARGETID
FINDITEM %regbagid C
SET %rxmod %origx - #FINDX
SET %rymod %origy - #FINDY
}
SET %bml_charpos #CHARPOSX , #CHARPOSY
;Reset globals for Seg'sBandage healer and CEOMedic
SET *510 ok
SET *BUSY 0
RETURN
SUB LookForCorpse
FINDITEM YFM G_2
;If the corpse is a friends (green) or innocents (killed by someone else), or too far away. Don't loot it.
IF #FINDKIND = -1 || #FINDDIST > 2
RETURN #FALSE
SET %bml_corpse #FINDID
IF #FINDKIND <> -1 && #FINDTYPE = YFM
{
;If everything is fine, and the found object is a corpse you have right to loot, and it is within range.
;Find the loot- and reg bags and set the coordinates accordingly
FINDITEM %lootbagid C
IF #FINDKIND = -1
{
EVENT EXMSG #CHARID 3 33 Can't find lootbag, paused.
PAUSE
RETURN #FALSE
}
SET %lootx #FINDX + %lxmod
SET %looty #FINDY + %lymod
FINDITEM %regbagid C
IF #FINDKIND = -1
{
EVENT EXMSG #CHARID 3 33 Can't find regbag, paused.
PAUSE
RETURN #FALSE
}
SET %regbx #FINDX + %rxmod
SET %regby #FINDY + %rymod
}
RETURN %bml_corpse
: algander#6292
Commenta