Tweet
ieri sera non avendo un ciufolo da fare, stufo delle solite barre di razor/injection mi son messo a fare una stat bar con easyuo.
Per ora disegna solo mana hp stamina e pozze heal cure ref inoltre se poisonato segna la barra degli hp verde, se sotto mortal arancione.
l'aggiornamento della barra sembra buono , non ho notato particolari artefatti grafici o residui
se volete cambiare la lunghezza della barra basta cambiare la variabile %v1
se avete dei consigili o robba da implementare sono ben lieto di ascoltarvi
;Scriptolo:
;_________________________________________________ _____________________
Per ora disegna solo mana hp stamina e pozze heal cure ref inoltre se poisonato segna la barra degli hp verde, se sotto mortal arancione.
l'aggiornamento della barra sembra buono , non ho notato particolari artefatti grafici o residui
se volete cambiare la lunghezza della barra basta cambiare la variabile %v1
se avete dei consigili o robba da implementare sono ben lieto di ascoltarvi
;Scriptolo:
;_________________________________________________ _____________________
codice:
set #lpc 400
menu clear
;Menu hideEUO
set %curePot NUF
set %HealPot UUF
set %StamPot ZUF
set #menubutton 0
set #menures n/a
set %v1 200 ;Lunghezza barre hp/mana/stamina
set %v2 45 ;Altezza Menu
set %x1 %v1 + 70
Menu show
Menu window size %x1 %v2
Menu window color black
Menu font size 10
menu Window Title JacK(OF) Stat Bar
set #menubutton closed
;$BBGGRR (where
;BB = hex value of blue colorchannel,
;GG = hex value of green color channel,
;RR = hex value of red channel).
;all colors rendered on the screen are created from these 3 primary colors. Each color ranges from 0 (darkest) to 255 (brightest) -- or $00 to $FF.
set %ColoreMana $C91100
set %ScrittaMana white
set %ColoreHP red
set %ScrittaHP BLACK
set %ColoreHPPoison Green
set %ScrittaHPPoison BLACK
set %ColoreHPMortal $0066FF
set %ScrittaHPMortal BLACK
set %ColoreStamina Yellow
set %ScrittaStamina BLACK
set %XHp 0
set %XMana 0
set %XStamina 0
set %HPPre 99
set %CurePre 99
set %StamPre 99
Loop:
gosub DisegnaBarre
gosub DisegnaPozze
wait 10
goto loop
sub DisegnaPozze
gosub DisegnaHpPot
gosub DisegnaCurePot
gosub DisegnaStaminaPot
return
sub DisegnaHpPot
gosub CheckPot %HealPot
if #result <> %HPPre
{
set %HPPre #result
Menu font bgcolor %ColoreHP
Menu font color %ScrittaHP
menu Delete HPPOT
menu button HPPOT %v1 0 70 15 Heal: #result
}
return
sub DisegnaCurePot
gosub CheckPot %curePot
if #result <> %CurePre
{
set %CurePre #result
Menu font bgcolor %ColoreHPPoison
Menu font color white
menu Delete CUREPOT
menu button CUREPOT %v1 15 70 15 Cure: #result
}
return
sub DisegnaStaminaPot
gosub CheckPot %StamPot
if #result <> %StamPre
{
set %StamPre #result
Menu font bgcolor %ColoreStamina
Menu font color %ScrittaStamina
menu Delete STAMPOT
menu button STAMPOT %v1 30 70 15 Stam: #result
}
return
sub DisegnaBarre
gosub DisegnaHp
gosub DisegnaMana
gosub DisegnaStamina
return
sub DisegnaHp
if %XHp <> #hits
{
set %XHp #hits
gosub CalcolaBarra #hits #maxhits
Menu font bgcolor %ColoreHP
Menu font color %ScrittaHP
if C in #charstatus
{
Menu font bgcolor %ColoreHPPoison
Menu font color %ScrittaHPPoison
}
if D in #charstatus
{
Menu font bgcolor %ColoreHPMortal
Menu font color %ScrittaHPMortal
}
menu Delete HP
menu button HP 0 0 #result 15 #hits
}
return
sub DisegnaStamina
if %XStamina <> #stamina
{
set %XStamina #stamina
gosub CalcolaBarra #stamina #maxstam
Menu font bgcolor %ColoreStamina
Menu font color %ScrittaStamina
menu Delete STAMINA
menu button STAMINA 0 30 #result 15 #stamina
}
return
sub DisegnaMana
if %XMana <> #mana
{
set %XMana #mana
gosub CalcolaBarra #mana #maxmana
Menu font bgcolor %ColoreMana
Menu font color %ScrittaMana
menu Delete MANA
menu button MANA 0 15 #result 15 #mana
}
return
sub CalcolaBarra
return ( ( %v1 * %1 ) / %2 )
sub CheckPot
finditem %1 C_ , #backpackid
return #FINDSTACK
Commenta