[EasyUO - HELP] Targettare un container

[BlackBraveKnight]

Sto cercando di mettere insieme uno script per craftare bolas, per evitare le cose più complicate ho bindato due tasti con Razor: uno restocka da un container, l'altro lascia le bolas in un altro container. Per velocizzare e automatizzare il tutto vorrei che EasyUO semplicemente premesse il primo, targettasse il container, aspettasse, poi premesse il secondo tasto e ripartisse.


Ora, dato che il restock fa già comparire il cursore target, non serve il comando "target"; il problema è: come diamine faccio a fargli cliccare quel cacchio di container?


Ho l'ID del container, ovviamente, ma non so quale comando usare per dare il semplice ordine "clicca là sopra". Ho provato con "click" più le coordinate, ma il cursore deve stare all'interno del container in cui si trova il container delle risorse...

Start
key 1
wait 2s
click 863 263
wait 90s
key 2
wait 2s
goto Start

Ho messo la pausa di 90 secondi perché è l'intervallo di tempo che serve per trasformare in bolas la quantità di pelli e bola balls che prendo ad ogni restock.


Però 'sto scriptino si blocca spesso e non posso toccare il mouse altrimenti s'impalla... >_<

[youngevil2]

C'è questo script ma utilizza sempre lo stesso container

;==================================================
; Script Name: Bola Crafter
; Author: Regnent
; Version: 1
; Client Tested with: 5.0.1j
; EUO version tested with: 1.5 TV69
; Shard OSI / FS: OSI
; Revision Date: Mar 31, 2006
; Public Release: Mar 31, 2006
; Purpose: Craft bolas.
;==================================================

; You should only need to set the %secure variable.
; Resources (Ingots, and Leather), should be in the same
; secure container (%secure)
; This script is lag friendly.

; Requirements
; a) Tinkering
; b) Resources, ingots & leather in a container.
; c) at least one tinkering kit, craftable kind, in your backpack

; Directions
; 1) Open your resource container (As well as set %secure)
; 2) Ensure that yo have 1 tinker kit in your backpack.
; 3) Hit play
; 4) Script will run indefinatly until stopped.
; Completed bolas are put into %secure.

; Revision 1
; First release.


SET %secure FUCSPQD
SET %tooltype JTL


SET %CategoryOffSetX 30
SET %CategoryOffSetY 90
SET %SelectionOffSetX 240
SET %SelectionOffSetY 70
SET %Step 20

SET %BolaBallCategory 3
SET %BolaBallSelection 8
SET %BolaCategory 7
SET %BolaSelection 7
SET %TinkerCategory 2
SET %TinkerSelection 4


sub CalcBola
  event macro 8 2
  wait 5
  SET %BolaCount ( #MaxWeight - #Weight ) / 7
return

sub WaitForGump
  gump:
  if #contname <> %1
  {
    finditem %currenttool C_ , #backpackid
    if #findkind = -1
    {
      goto gumpexit
    }
    goto gump
  }
  gumpexit:
return

sub setitem
  wait 5
  set %var1 %1
  set %var2 %2
  finditem %tooltype C_ , #backpackid
  wait 5
  set %currenttool #findid
  if #findkind <> -1
  {
    set #lobjectid #findid
    set #lobjecttype #findtype
    event macro 17
    gosub waitforgump generic_gump
    wait 5
    set %clickx #contposx + %categoryoffsetx
    set %clicky #contposy + %categoryoffsety + ( %var1 * %step ) - %step
    click %clickx %clicky
    gosub waitforgump generic_gump
    wait 5
    set %clickx #contposx + %selectionoffsetx
    set %clicky #contposy + %selectionoffsety + ( %var2 * %step ) - %step
    click %clickx %clicky
    gosub waitforgump generic_gump
    wait 1s
  }
return

sub makelast
  if #contname <> generic_gump
  {
    finditem %tooltype C_ , #backpackid
    set %currenttool #findid
    set #lobjectid #findid
    set #lobjecttype #findtype
    event macro 17
    gosub waitforgump generic_gump
    wait 5
  }
  set %clickx #contposx + 285
  set %clicky #contposy + 415
  click %clickx %clicky
  gosub waitforgump generic_gump
  wait 5
return

sub checktool
  finditem %tooltype C_ , #backpackid
  while #findcnt < 2
  {
    gosub setitem %tinkercategory %tinkerselection
    finditem %tooltype C_ , #backpackid
    wait 5
  }
return

sub getsupplies
  finditem ENK C_ , %secure
  while #findcol <> 0 && #findkind <> -1
  {
    ignoreitem #findid
    finditem ENK C_ , %secure
  }
  if #findcol = 0 && #findkind = 0
  {
    SET %ingotcount %bolacount * 40
    exevent drag #findid %ingotcount
    exevent dropc #backpackid
    wait 5
    finditem ENK C_ , #backpackid
    wait 5
    SET %ingots #findid
  }
  else
  {
  }
  wait 1s
  finditem JJG C_ , %secure
  while #findcol <> 0 && #findkind <> -1
  {
    ignoreitem #findid
    finditem JJG C_ , %secure
  }
  if #findcol = 0 && #findkind = 0
  {
    SET %leathercount %bolacount * 3
    exevent drag #findid %leathercount
    exevent dropc #backpackid
    wait 5
    finditem JJG C_ , #backpackid
    wait 5
    SET %leather #findid
  }
  else
  {
  }
  wait 1s
return

gosub CalcBola
gosub getsupplies
gosub checktool
gosub setitem %bolaballcategory %bolaballselection

finditem %ingots C_ , #backpackID
while #findstack >= 10
{
  gosub makelast
  finditem %ingots
}


finditem %leather C_ , #backpackID
set %leathercount #findstack
gosub setitem %bolacategory %bolaselection
finditem FKF C_ , #backpackID
wait 5
set %bolacount #findstack
while %bolacount >= 4 && %leathercount >= 3
{
  gosub makelast
  finditem FKF C_ , #backpackID
  set %bolacount #findstack
  finditem %leather C_ , #backpackID
  wait 5
  set %leathercount #findstack
}
wait 1s
finditem KTO C_ , #backpackid
wait 5
if #findkind <> -1
{
  exevent drag #findid #findstack
  exevent dropc %secure
  wait 1s
}

Non l'ho mai testato, ma penso che in SET %secure XXXX dovrai mettere l'id della cassa dove hai i materiali e ti rimetterà le bolas fatte là.
Spero di aver capito bene.


Per il tuo non ho capito bene, il key 1 e il key 2 che ti fanno? (ah, non server fare start e goto start visto che una volta finito lo script rinizia da solo)

[BlackBraveKnight]

1 restocka bola balls (fatte precedentemente, a mano o quasi) e pelle dal container, 2 invece mette le bolas in un altro container.

Va benissimo usare un solo container, io ne ho due solo perché l'ultimo script che ho provato ne richiedeva due. ^^

Grazie mille, ora provo questo; nel topic in cui chiedevo uno script crafta-bolas non ha risposto nessuno e quindi ho pensato di provare a farne uno, ma ovviamente se ce n'è uno già fatto da qualcuno più esperto, tanto meglio!

Ormai quelle le ho fatte, più tardi provo a craftarne qualcun'altra e vediamo se funziona.

Per quanto riguarda "start" e "goto start", beh, ho copiato la cosa da altri script, credevo che servisse. Non ce n'è bisogno, meglio.
Grazie per il suggerimento, allora.