annuncio

**pstexano** · 03-03-2009, 13:45

codice:

sub CEOWorldSaveChecker
; sub to pause a script during a RunUO world save.
set %_text1 %1
set %_text2 %2
set %_text3 %3
if %_worldsaveupcoming
{
  if %_worldsavetimer < #scnt
  {
    set %_worldsavetimer #scnt + %5
    ;gosub popupworldsave 85 70 blue
    goto _WSC_WAIT1
  }
  return
}
_WSC1:
if %_worldsavejournalindex > #jindex
  return
scanjournal %_worldsavejournalindex
if %_text1  in #journal
{
  set %_worldsaveupcoming #true
  set %_worldsavetimer #scnt + %4
  set %_worldsavejournalindex  %_worldsavejournalindex + 1
  return
}
set %_worldsavejournalindex  %_worldsavejournalindex + 1
goto _WSC1
_WSC_WAIT1:
if %_worldsavetimer < #scnt
  goto _WSC_Complete
wait 5
set *CEOWorldSaving #true
if %_worldsavejournalindex > #jindex
  goto _WSC_WAIT1
scanjournal %_worldsavejournalindex
if %_text2 in #journal
{
  ;gosub popupworldsave 85 70 yellow
  set %_worldsavejournalindex  %_worldsavejournalindex + 1
  goto _WSC_WAIT2
}
set %_worldsavejournalindex  %_worldsavejournalindex + 1
goto _WSC_WAIT1
_WSC_WAIT2:
if %_worldsavetimer < #scnt
  goto _WSC_Complete
wait 5
if %_worldsavejournalindex > #jindex
  goto _WSC_WAIT2
scanjournal %_worldsavejournalindex
if %_text3 notin #journal
{
  set %_worldsavejournalindex  %_worldsavejournalindex + 1
  goto _WSC_WAIT2
}
_WSC_Complete:
set %_worldsavejournalindex  #jindex
set %_worldsaveupcoming #false
set *CEOWorldSaving #false
;menu delete worldsave
return





;===================================================
; Script Name:  sub s7UseRunebook
; Author:  snicker7
; Version:  2.0
; Client Tested with:  4.0.11c
; EUO version tested with:  1.42/1.5
; Shard OSI / FS:  OSI/FS
; Revision Date:  24Aug05
; Public Release:  24Aug05
; Global Variables Used: N/A
; Purpose:  Failsafe sub to recall, gate, sacred journey flawlessly. Options to use scrolls, default locations, recharge books with scrolls in pack if book runs out of charges, and perfect gate travel. Not for the feint of heart!
;===================================================Speak to the hand
;======= This file includes the main sub and =======Speak to the hand
;===== several support subs that are required. =====Speak to the hand
;===================================================Speak to the hand
;===== Much love for T-Mo and BM, but I needed =====Speak to the hand
;====== to write something I could only blame ======Speak to the hand
;======= myself for if it fails. even though =======Speak to the hand
;=================== it doesn't. ===================Speak to the hand
;===================================================Speak to the hand

; ===================================================================== ;
; ///////////////////////////////////////////////////////////////////// ;
; // EXCERPTS FROM S7SUBS.EUO ///////////////////////////////////////// ;
; ///////////////////////////////////////////////////////////////////// ;
; // Any reproduction of the subroutines below is strictly pro- /////// ;
; // hibited without express written permission of the author ///////// ;
; // (snicker7). Violation of the above will result in malicious ////// ;
; // actions by the aforementioned author performed upon your person // ;
; // including but not limited to: bodily harm, slander, maternal ///// ;
; // insults, possible legal action, and callin' the five-oh. Thank /// ;
; // you. ///////////////////////////////////////////////////////////// ;
; ///////////////////////////////////////////////////////////////////// ;
; ===================================================================== ;

;=/ 1NCLUD3D SUBS: /================================Speak to the hand
; s7UseRunebook: Duh, you know why it's there.
; s7ScanJournalFor: SuperMultiParameterJournalScanning Power!
; s7MoveToPos: Legendary snicker7 brand name drag and drop sub. updated!
; s7MoveToCont: Wrapper for the above sub, updated for 1.5 exevents!
; s7WaitForAction: Mildly obsolete, begging for a rewrite object-delay sub!
; s7WaitForVars: Classic sysvar wait sub. One line shorter than Quintok's!
;===================================================Speak to the hand

;----
;* @name s7UseRunebook
;* @author snicker7
;* @ver 2.0a 24Aug05
;* @purpose   do anything and everything travel related with a runebook
;* @params    %1   Rune or Runebook item ID to use
;*      %2   number of rune to travel to, use "default" for runes or default in runebook
;*      %3   travel method:
;*         r: recall
;*         g: gate
;*         c: sacred journey
;*         s: scrolls
;* @dependencies
;*      s7WaitForVars
;*      s7WaitForAction
;*      s7ScanJournalFor
;*      s7MoveToCont for recharging runebooks
;* @returns    #true   on success
;*      ERR_*   various errors.
;* @notes    none
;* @example:    gosub s7UseRunebook %bookID 14 r
;* @status done
sub s7UseRunebook
  if %0 < 3 || _ , %2 , _ notin _1_2_3_4_5_6_7_8_9_10_11_12_13_14_15_16_default_
    return ERR_IncorrectParams
  namespace push
  namespace local _s7URB
  set !runebook %1
  set !index %2
  set !method %3
  set !fails 0
  if #contsize = 452_236
  {
    set !_cx #contposx + 20
    set !_cy #contposy + 20
    click !_cx !_cy r f dmc
    wait 5
  }
  for !_ 1 1
  {
    finditem OTF_JEF_KEF G_0
    if #findkind <> -1
      set !_ 0
  }
  for !orb 1 1
  {
    if !fails > 2 2
      namespace pop
      return ERR_ , #journal
    set !jStart #jindex + 1
    if !index <> default
    {
      gosub s7WaitForAction 12
      set #lobjectid !runebook
      event macro 17 0
      gosub s7WaitForVars contname = generic_gump contsize = 452_236 3
      if ! #result 2
        set !fails !fails + 1
        set !orb 0
      if #result
      {
        set !_cy #contposy + 196
        set !_cx #contposx + 105 + ( ( ( !index / 2 ) + ( !index % 2 ) ) * 35 )
        if !index > 8
          set !_cx !_cx + 30
        click !_cx !_cy f dmc
        wait 5
        set !_cx #contposx + 135
        set !_cy #contposy + 144
        if !method = G
          set !_cy !_cy + 20
        if !method = C
          set !_cy !_cy + 36
        if !method = S
          set !_cy !_cy - 76
        if ( !index % 2 ) = 0
          set !_cx !_cx + 160
        set !charpos #charposx , _ , #charposy
        set !timeout #scnt2
        click !_cx !_cy f dmc
      }
    }
    if !index = default
    {
      set #ltargetid !runebook
      set #ltargetkind 1
      if !method = c
        event macro 15 210
      if !method = r
        event macro 15 31
      if !method = g
        event macro 15 51
      if !method = s
      {
        finditem WTL C_ , #backpackid
        if #findkind = -1 2
          namespace pop
          return ERR_NoRecallScrolls
        if #findkind <> -1 3
          set #lobjectid #findid
          gosub s7WaitForAction 12
          event macro 17 0
      }
      for !_ 1 1
      {
        if #targcurs <> 1
          set !_ 0
        gosub s7ScanJournalFor !jStart fizzles more_reagents tithing_points insufficient_mana
        if #result 3
          set !_ 1
          set !orb 0
          wait 20
      }
      set !charpos #charposx , _ , #charposy
      set !timeout #scnt2
      event macro 22 0
    }
    if !orb = 1
    {
      for !success 1 1
      {
        if #charposx , _ , #charposy = !charpos && !method in _r_c_s_
          set !success 0
        if !method = g
        {
          finditem OTF_JEF_KEF G_0
          if #findkind = -1
            set !success 0
          if #findkind <> -1
          {
            set #lobjectid #findid
            gosub s7WaitForAction 12
            event macro 17 0
            for !_ 1 1
            {
              if #charposx , _ , #charposy = !charpos
                set !_ 0
              if #contname = generic_gump && #contsize = 420_280
              {
                set !_cx #contposx + 20
                set !_cy #contposy + 260
                click !_cx !_cy f dmc
              }
            }
          }
        }
        gosub s7ScanJournalFor !jStart fizzles location_is_blocked not_yet_recovered no_charges_left more_reagents tithing_points insufficient_mana not_marked
        if #result || !timeout + 60 < #scnt2
        {
          if no_charges in #journal
          {
            finditem WTL C_ , #backpackid
            if #findkind = -1
              set !fails 2
            if #findkind <> -1
            {
              set !scrolls #findid
              finditem !runebook
              set #findmod 0
              gosub s7WaitForAction 12
              event drag !runebook
              for !_ 1 1
              {
                if #lliftedkind <> 1 2
                  wait 1
                  set !_ 0
              }
              str pos #contsize _
              set #strres #strres - 1
              str left #contsize #strres
              set !_cx #findx + #strres / 2
              str pos #contsize _
              str del #contsize 1 #strres
              set !_cy #findy + #strres / 2
              click !_cx !_cy p f dmc
              gosub s7MoveToCont !scrolls !runebook #backpackid 20_10
            }
          }
          set !fails !fails + 1
          set !success 1
          set !orb 0
        }
      }
      wait 20
    }
  }
namespace pop
return #true

**pstexano** · 03-03-2009, 13:46

codice:

sub s7ScanJournalFor
  set !SJFje #jindex + 1
  for !SJFji %1 !SJFje
  {
    scanjournal !SJFji
    for !SJFpi 2 %0
    {
      if % . !SJFpi in #journal
        return #true
    }
  }
return #false

;----
;* @name s7MoveToPos
;* @author snicker7
;* @ver 1.2 24Aug05
;* @purpose Just Another Item Dragger.
;* @params    %1 is the item to be dragged
;*      %2 is the x-coord to drop to
;*       %3 is the y-coord to drop to
;*      %4 is the timeout in seconds
;*       %5 is the amount to be dragged (blank for all)
;* @returns    #true if drop was successful
;*      #false on error (drop to backpack, insufficient params, failed to drag)
;*      halt on critical error
;* @notes moves any item to a position on the screen. Will
;*   attempt to drop on character if drop fails. If character
;*   drop fails, halts and error message to avoid crash.
;* @dependencies
;*      s7WaitForAction
;* @example: call s7Subs.euo s7MoveToPos #findid 7 9 4 77
;* @status unknown
sub s7MoveToPos
  if %0 < 4
    return #false
  namespace Push
  namespace Local _s7MvToPos
  set !_ID %1
  set !_x %2
  set !_y %3
  set !_tO %4
  set !_Amt #spc
  if %0 > 4
    set !_Amt %5
  set !_retry 0
  _s7MvToPos_SD:
  finditem !_ID
  if #findkind = -1 2
    namespace pop
    return #false
  gosub s7WaitForAction 13
  event drag #findid
  if #findstack > 1
  {
    set !_timeOut #scnt
    for !_ 1 1
    {
      if #contname <> stack_gump && #contname <> drag_gump
      {
        wait 1
        if !_timeOut + !_tO < #scnt
        {
          set !_retry !_retry + 1
          if !_retry > 2 2
            namespace pop
            return #false
          goto _s7MvToPos_SD
        }
        set !_ 0
      }
    }
    if !_Amt > #findstack
      set !_Amt #findstack
    msg !_Amt , $
  }
  set !_retry 0
  set !_timeOut #scnt
  for !_ 1 1
  {
    if #lliftedkind <> 1
    {
      wait 1
      if !_timeOut + !_tO < #scnt
      {
        set !_retry !_retry + 1
        if !_retry > 2 2
          namespace pop
          return #false
        goto _s7MvToPos_SD
      }
      set !_ 0
    }
  }
  set !_retry 0
  click !_x !_y p
  set !_timeout #scnt
  for !_ 1 1
  {
    if #lliftedkind = 1
    {
      wait 1
      if !_timeout + !_t0 < #scnt
      {
        set !_retry !_retry + 1
        if !_retry = 1
        {
          set !_x #clixres / 2
          set !_y ( #cliyres / 2 ) - 30
          click !_x !_y p
          set #result #false
          set !_timeout #scnt
        }
        if !_retry = 2 2
          display ok You have failed to drop an item to the correct position.$$The script is now halting to prevent a crash.
          halt
      }
      set !_ 0
    }
  }
  set #result #true
  namespace pop
return #result

;----
;* @name s7MoveToCont
;* @author snicker7
;* @ver 1.2 24Aug05
;* @purpose A wrapper for the sub s7MoveToPos for moving to containers.
;* @params    %1 is the item to be dragged
;*      %2 is the container to drag to
;*      %3 is the mother container in which %2 is contained
;*       %4 is the #findmod value for the container
;*       %5 is the amount to be dragged (blank for all)
;* @returns none
;* @notes this is mad basic. no error checking. That is up to you.
;* @dependencies   s7MoveToPos
;* @example: call s7Subs.euo s7MoveToCont #findid #backpackid #charid 140_220
;* @status tested good
sub s7MoveToCont
  namespace Push
  namespace Local _s7MoveToCont
  set !_ID %1
  set !_DCont %2
  set !_MCont %3
  set !_FMod %4
  if 1_5 in #euover
  {
    set !_Amt 65535
    if %0 > 4
      set !_Amt abs %5
    finditem !_ID
    if #findkind = -1 2
      namespace pop
      return #false
    gosub s7WaitForAction 13
    exevent drag #findid !_Amt
    exevent dropc !_DCont
    namespace pop
    return #true
  }
  set !_Amt #spc
  if %0 > 4
    set !_Amt %5
  set #result #true
  set !_retry 0
  for !_ 1 1
  {
    finditem !_DCont C_ , !_MCont
    if #findkind = -1
    {
      set #lobjectid !_MCont
      gosub s7WaitForAction 13
      event macro 17 0
      gosub s7WaitForVars contid = !_MCont 3
      if ! #result
      {
        set !_retry !_retry + 1
        if !_retry > 2 2
          namespace pop
          return #false
      }
      set !_ 0
    }
  }
  set !_retry 0
  set #findmod !_Fmod
  for !_ 1 1
  {
    gosub s7MoveToPos !_ID #findx #findy 4 !_Amt
    if ! #result
    {
      set !_retry !_retry + 1
      if !_retry > 2 2
        namespace pop
        return #false
      set !_ 0
    }
  }
namespace Pop
return #true

;----
;* @name s7WaitForAction
;* @author snicker7
;* @ver 1.1 31Jan05
;* @purpose waits 1.3 seconds before continuing, useful for waiting to perform
;*    another action
;* @params    none
;* @returns none
;* @notes probably not an original idea, but I need to use it frequently and it
;*    was easier to write it myself than to try to look for it as written by
;*    someone else

;* @example: call s7Subs.euo s7WaitForAction 13
;* @status tested good
sub s7WaitForAction
  _s7WaitForAction:
  if %_s7ActionTimer + %1 > #scnt2 2
    wait 1
    goto _s7WaitForAction
  set %_s7ActionTimer #scnt2
return

;----
;* @name s7WaitForVars
;* @author snicker7, inspired by Quintok, and of course, Smertrios
;* @ver 1.2 24Aug05
;* @purpose Multiple input sysvar waiter.
;* @params    %1*n is the gump sysvar being checked
;*      %2*n is the comparative operator (>, <, <>, =, etc)
;*      %3*n is the desired value of the sysvar
;*      %nfinal is the timeout in seconds
;* @returns #false if it times out
;*          #true if success
;* @notes    %1 does not require the preceding number sign
;*      one line shorter than Q's, no disrespect son
;*      originally written by Smertrios, included in Lexia
;*      Multiple inputs by Quintok, Obfuscation and name-
;*      spacing by snicker7!
;* @example: call s7Subs.euo s7WaitForVars contID = #backpackID contSize = 7_9 3
;* @status tested good
sub s7WaitForVars
  namespace Push
  namespace Local _s7WFVs
  set !C %0 / 3
  set !T #scnt + 5
  if ( %0 % 3 ) = 1
    set !T #scnt + % . %0
  for !i 1 !C
  {
    set !o 3 * !i - 2
    set !p !o + 1
    set !q !o + 2
    if ! ( # . % . !o % . !p % . !q )
      set !i 0
    if #scnt > !T 2
      namespace pop
      return #false
  }
  namespace Pop
return #true

**baffo81** · 03-03-2009, 14:42

Grande!Grandissimo!!!!!! E' un pezzo che lo aspettavo!!!!

**tnsj69sod** · 07-03-2009, 15:47

si pu� usare lo script se nn si ha una forgia in casa?
bella cmq, grazie mille!

**pstexano** · 08-03-2009, 02:26

Originariamente inviato da tnsj69sod Visualizza il messaggio

si pu� usare lo script se nn si ha una forgia in casa?

e come crafti?

**Zamia** · 08-03-2009, 19:34

Ma � possibile adattare lo script in modo che faccia i Bokuto anziche i No Dachi?

**tnsj69sod** · 08-03-2009, 21:47

ma perch� nn va a portare gli item craftati e continua invece a craftare anche dopo che ha raggiunto il limite di peso?

**pstexano** · 08-03-2009, 22:10

Originariamente inviato da Zamia Visualizza il messaggio

Ma � possibile adattare lo script in modo che faccia i Bokuto anziche i No Dachi?

boh, se ho tempo qualche giorno lo faccio

Originariamente inviato da tnsj69sod Visualizza il messaggio

ma perch� nn va a portare gli item craftati e continua invece a craftare anche dopo che ha raggiunto il limite di peso?

crafta un po' oltre il limite di peso perch� poi quando rimette i lingotti nella cassa il peso dovrebbe tornare sotto il massimo

**isterico** · 15-04-2009, 20:40

uppo Zamia e rompo le scatole anchio!!!
..non e' possibile modificarlo in modo che crafti BOKUTO ?

grazie!

e rigrazie ancora per lo script!

**pstexano** · 19-04-2009, 15:45

versione per carpenter, utilizzabile anche dalla banca, � sufficiente che tutte le risorse siano dentro una cassa o una bag nel primo lvello della banca

incollate questo e poi le due parti nel secondo e terzo post

codice:

set %casa 14
set %biblio 13
set %lag 0
set %tinker #true

display scegli il runebook
set #targcurs 1
while #targcurs = 1
  {
  }
set %libro #ltargetid

display scegli la cassa. devi essere vicino quando la clicchi
set #targcurs 1
while #targcurs = 1
  {
  }
set %cassa #ltargetid
set %cassax #charposx
set %cassay #charposy
}

set %_worldsavejournalindex #jindex
set *CEOWorldSaving #false
set %primo #true

finditem #charid G_
if #findtype in IS_HS
  set %umano #true
else
  set %umano #false

set %bokuto ( #maxweight - #weight ) / 7 - 1
if %umano
  set %bokuto %bokuto + 8


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;MAIN LOOP;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

loop:
move %cassax %cassay 0 20s
event macro 1 0 bank
wait 20
set #lobjectid %cassa
event macro 17 0
wait 15
wait %lag
repeat
  {
  event property #backpackid
  if 125/125 in #property
  halt
  gosub CEOWorldSaveChecker world_will_save_in world_is_saving world_save_complete 5 90
  if %tinker
    gosub tool
  else
    gosub tool2
  gosub crafta
  finditem KDP C_ , #backpackid
  set %crafted #findcnt
  }
until #findcnt >= %bokuto
wait 30
wait %lag
if #contname = generic_gump
  {
  set %clicx #contposx + 230
  set %clicy #contposy + 110
  click %clicx %clicy r
  }
finditem TLK C_ , #backpackid
if #findkind <> -1
  {
  exevent drag #findid #findstack
  exevent dropc %cassa
  wait 15
  wait %lag
  }
set %posx #charposx
set %posy #charposy
while #charposx = %posx && #charposy = %posy
{
gosub s7UseRunebook %libro %biblio r
}
gosub consegna
set %posx #charposx
set %posy #charposy
while #charposx = %posx && #charposy = %posy
{
gosub s7UseRunebook %libro %casa r
}
goto loop
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;SUB;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

sub tool2
tool2:
finditem EGG C_ , #backpackid
if #findkind = -1
  {
  finditem EGG C_ , %cassa
  if #findkind = -1
    {
    display hai finito le tongs
    halt
    }
  else
    {
    exevent drag #findid 1
    exevent dropc #backpackid
    wait 12
    wait %lag
    }
  goto tool2
  }
return

sub tool
tool:
finditem EGG C_ , #backpackid
if #findkind = -1
  {
  finditem ENK C_ , #backpackid
  if #findkind = -1 || #findstack < 10
    {
    trova:
    finditem ENK C_ , %cassa
    if #findcol <> 0 || #findstack < 4
      {
      ignoreitem #findid
      goto trova
      }
    exevent drag #findid 10
    exevent dropc #backpackid
    wait 15
    wait %lag
    }
  finditem KTL C_ , #backpackid
  set #lobjectid #findid
  event macro 17 0
  wait 10
  wait %lag
  if #findcnt = 1
    {
    set %clicx #contposx + 30
    set %clicy #contposy + 110
    click %clicx %clicy
    wait 5
    wait %lag
    set %clicx #contposx + 230
    set %clicy #contposy + 130
    click %clicx %clicy
    wait 30
    wait %lag
    }
  set %clicx #contposx + 30
  set %clicy #contposy + 110
  click %clicx %clicy
  wait 20
  wait %lag
  set %clicx #contposx + 230
  set %clicy #contposy + 210
  click %clicx %clicy
  wait 40
  wait %lag
  finditem EGG C_ , #backpackid
  if #findkind = -1
  goto tool
  if #contname = generic_gump
    {
    set %clicx #contposx + 230
    set %clicy #contposy + 110
    click %clicx %clicy r
    }
  }
finditem ENK C_ , #backpackid
if #findkind <> -1
  {
  exevent drag #findid #findstack
  exevent dropc %cassa
  wait 12
  }
return


sub crafta
finditem TLK C_ , #backpackid
if #findkind = -1 || #findstack < 20
  {
  trova:
  finditem TLK C_ , %cassa
  if #findcol <> 0 || #findstack < 20
    {
    ignoreitem #findid
    goto trova
    }
  set %stack #maxweight - #weight
  if %umano
  set %stack %stack + 60
  if 350 < %stack
  set %stack 350
  exevent drag #findid %stack
  exevent dropc #backpackid
  wait 15
  wait %lag
  }
if #contname <> generic_gump
  {
  finditem EGG C_ , #backpackid
  set #lobjectid #findid
  event macro 17 0
  wait 10
  wait %lag
  }
if %primo
  {
  set %clicx #contposx + 25
  set %clicy #contposy + 150
  click %clicx %clicy
  wait 20
  wait %lag
  set %clicx #contposx + 230
  set %clicy #contposy + 130
  click %clicx %clicy
  wait 60
  wait %lag
  set %primo #false
  }
set %clicx #contposx + 280
set %clicy #contposy + 415
click %clicx %clicy
set %wait #scnt2 + 60 + %lag
finditem KDP C_ , #backpackid
set %fatti #findcnt
wait 5
while %wait > #scnt2 && #findcnt = %fatti
{
finditem KDP C_ , #backpackid
}
return

sub consegna
finditem TKYM G_
move #findx #findy 0 15s
event macro 1 0 Arabella The Samurai
repeat
  {
  gosub CEOWorldSaveChecker world_will_save_in world_is_saving world_save_complete 5 90
  if #contname <> generic_gump || #contsize <> 345_359
    {
    set #lobjectid TKYM
    event macro 17 0
    wait 10
    wait %lag
    }
  set %clicx #contposx + 305
  set %clicy #contposy + 340
  click %clicx %clicy
  set %wait #scnt2 + 5
  wait 1
  while %wait < #scnt2 && #contname <> generic_gump
    {
    }
  set %clicx #contposx + 40
  set %clicy #contposy + 175
  click %clicx %clicy
  target
  finditem KDP C_ , #backpackid
  set #ltargetid #findid
  set #ltargetkind 1
  event macro 22 0
  set %wait #scnt2 + 5
  while %wait < #scnt2 && #contname <> generic_gump
    {
    }
  }
until #findcnt < 2
wait 20
if #contname = generic_gump
  {
  set %clicx #contposx + 230
  set %clicy #contposy + 110
  click %clicx %clicy r
  }
return

**isterico** · 19-04-2009, 16:11

testato funzionante!

**titultimakik** · 27-04-2009, 16:08

ciao
mi sapresti dire come posso modifarlo in tal modo da fare la quest (Mace and Shield Reading Glasses ) creando scudi invece di no-dashi e consegnarle al warrion invece che al samurai

grazie in anticipo ^_-

**fnurov** · 27-04-2009, 16:29

nothing

**Marino** · 10-02-2012, 12:58

dato che nel tempo sono state cambiate un p� di cose nei click dei tool vi posto una versione un p� pi� aggiornata

Crafta No-Dachi

Crafta Dashi

Crafta Bokuto - necessaria skill carpentary

annuncio

[EASYUO] folded steel reading glasses

[EASYUO] folded steel reading glasses

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta

Commenta