[Richiesta] Easyuo

[fcdarko]

Salve,

mi servirebbe uno script semplice che attacchi in automatico il mob che mi ha targhettato



grazie

[fcdarko]

trovato

potete chiudere

[Traif1502]

Potresti mica postarlo o mandarmelo per PM?

[fcdarko]

ciao traif

praticamente è uno scriptino che aiuta nel far salire archery

molto semplice da impostare all'inizio (ti chiede 3 cose)

;==================================
; Script Name: Safespot Archery Trainer
; Author: deepgreen
; Version: 1.00
; Client Tested with: 4.0.0p
; EUO version tested with: 1.40 Build0056
; Shard OSI / FS: OSI
; Revision Date: 12.10.03
; Public Release: 12.10.03
; Purpose: Train Archery on a Safespot
;==================================

initevents
ignoreitem reset

gosub config
gosub setup


loop:
gosub check
gosub attackenemy
goto loop

;===============================================================
;================ THE SUBS ======================================
;===============================================================

;===== CONFIG =====
sub config
menu clear
menu Window size 200 50
menu window color black
menu font bgcolor black
menu font color white
menu show
menu text label 10 2 How many weapons ?
menu edit editbox 10 20 130
menu button okbutton 150 5 40 40 OK
gosub waitforok
menu getnum editbox 5
set %amtweps #menures
menu delete okbutton
menu delete editbox
for %i 1 %amtweps
{
menu delete label
menu text label 10 2 Target , #spc , Weapon , #spc , %i
gosub waitfortarget
set %wep . %i #ltargetid
}

menu delete label
menu text label 10 2 Target , #spc , Ammonition
gosub waitfortarget
set %ammo #ltargetid

menu delete label
menu text label 10 2 Target , #spc , Enemy
gosub waitfortarget
finditem #ltargetid
set %enemy #findtype

menu hide

return

;======= WAITFORTARGET =========
sub waitfortarget
set #targcurs 1
wait 10
targetloop:
if #targcurs = 1
  goto targetloop
return

;======== WAITFOROK=============

sub waitforok
okloop:
if #menubutton <> okbutton
  goto okloop
set #menubutton N/A
return


;====== SETUP ==========
sub setup
event macro 8 2
set %currentwep %wep . 1
set %i 2
set #lhandid %currentwep
event macro 24 1
wait 2s
return

;==== CHECK =====
sub check
event property %currentwep
str Del #property 1 163
str del #strres 3 6
if #strres < 40
{
  if %counter = %amtweps
  {
    gosub arm %wep . %counter
  }
}

if #charghost <> NO
  gosub logout

finditem %ammo
if #findkind = -1
{
  wait 1s
  finditem %ammo
  if #findkind = -1
  {
    gosub logout
  }
}
return

;==== ATTACK ENEMY ======
sub attackenemy
finditem %enemy G
if #findkind = -1 2
  ignoreitem reset
  goto loop
set #ltargetid #findid
event macro 22 0
event macro 27 0
ignoreitem #findid
wait 2s
return

;==== ARM =====
sub arm
event macro 24 1
set #lhandid %1
wait 5s
event macro 24 1
set %currentwep #lhandid
set %counter %counter + 1
return

;===== LOGOUT =========
sub logout
event macro 20 0
wait 3s
click 600 450 f
halt
return

se ci sono dubbi chiedi pure