[euox] some binds for tamers

[fnurov]

script made actualy for pg tamer with one pet eval, chiva, but u can use just what u need.
i think all that it does is quite clear from name of subs. just set correct %petid and %blesslength and keys thay u want to use ofcause.

in order to cast fast increase euox process priority in windows

script in 3 posts

;script    PowerTamer
;auther    Felix
;version   1.2


set %PetId FPZD

set %blesslength 150000 ; how long your bless lasts in ms
set %jindex #jindex
set %dlpc 1000 ; lines per second in wait for key time
set %flpc 10000 ; lines per second in exec time
set %d 11
set #lpc %dlpc

set %humans IS_HS_XU_AV_LAB_MAB_PAB
set %doombosses _
set %doomspawn _

set %enemies %humans + %doombosses + %doomspawn
set %lEnemyCNT 0
set %findI 1

set %blessid1 #charid
set %blessid2 %petid
set %blessT1 0
set %blessT2 0
set %blessq 2
set %blessi 1

set %castdist 10
set %bands ZLF
set %bandagedelay #systime
set %fireballarrow 1

loop:
onhotkey a
  gosub allkill
onhotkey d
  gosub fireball
onhotkey f
  gosub lighting
onhotkey 4
  gosub setenemy
onhotkey 3
  gosub atackenemy
onhotkey z alt
 gosub telesitpet
onhotkey q alt
  gosub ghealself
onhotkey f3
  gosub remcurseself
onhotkey q
 gosub healself
onhotkey r
 gosub telefar
onhotkey f1 alt
 gosub healpet
onhotkey f2 alt
 gosub curepet
onhotkey f1
 gosub bandagepet
onhotkey f2
 gosub ghealpet
onhotkey f3 alt
 gosub remcursepet
onhotkey f4
 gosub blessself
onhotkey f4 alt
 gosub blesspet
onhotkey 5 alt
 gosub addtoblesslist
onhotkey 5
 gosub blessfromlist
onhotkey s shift
 gosub explo
onhotkey f shift
 gosub flame
onhotkey 5 shift
 gosub clearbless
ONHOTKEY 9
 gosub wallofstone
;onhotkey w
 ;gosub nexttarget
;onhotkey w alt
 ;gosub prevtarget
;onhotkey e
 ;gosub setchosentarget
sleep 10
goto loop

sub wallofstone
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    if #targcurs = 1
    {
      click #CURSORX #CURSORY dmc
      goto _wallofstoneEXIT
    }
    event macro 15 23
    target 30
    if #targcurs = 1
    {
       click #CURSORX #CURSORY dmc
    }
    _wallofstoneEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub flame
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %enemyid
    if #findcnt = 1
    {
        event ExMsg #findid 2 3 TARGET
        event macro 15 50
        target 50
        finditem %enemyid
        if #findcnt = 1 && #targcurs = 1 && #finddist <= %castdist
        {
             set #ltargetid %enemyid
             set #ltargetkind 1
             event macro 22 0
        }
    }
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub clearbless
    set %blessq 2
    set %blessi 1
return

sub setchosentarget
    set #lpc %flpc
    set %enemyid %possibleEnemyId
    event ExMsg %enemyid 3 273 NEW ENEMY SET
    set #lpc %dlpc
return

sub nexttarget
    set #lpc %flpc
    set %exitnexttarget #false
    repeat
          if #findcnt <> %lEnemyCNT
          {
              finditem %enemies
              set %findI 1
              set %lEnemyCNT #findcnt
          }
          set #findindex #findindex + 1
          if #findindex > #findcnt 1
             set #findindex 1
          if #findrep in 3_4_6
          {
             set %possibleEnemyId #findid
             event ExMsg %possibleEnemyId 2 3 THIS TARGET?
             set %exitnexttarget #true
          }
          sleep 1
    until %findI = #findindex || %exitnexttarget
    set #lpc %dlpc
return

sub prevtarget
    set #lpc %flpc
    set %exitprevtarget #false
    repeat
          if #findcnt <> %lEnemyCNT
          {
              finditem %enemies
              set %findI 1
              set %lEnemyCNT #findcnt
          }
          set #findindex #findindex - 1
          if #findindex = 0 1
             set #findindex #findcnt
          if #findrep in 3_4_6
          {
             set %possibleEnemyId #findid
             event ExMsg %possibleEnemyId 2 3 THIS TARGET?
             set %exitprevtarget #true
          }
          sleep 1
    until %findI = #findindex || %exitprevtarget
    set #lpc %dlpc
return


sub explo
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %enemyid
    if #findcnt = 1
    {
        event ExMsg #findid 2 3 TARGET
        event macro 15 42
        target 40
        finditem %enemyid
        if #findcnt = 1 && #targcurs = 1 && #finddist < 9
        {
             set #ltargetid %enemyid
             set #ltargetkind 1
             event macro 22 0
        }
    }
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub blessfromlist
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    if #systime > %blessT . %blessi
    {
         set %find %blessid . %blessi
         finditem  %find G_ , 8
         if #findcnt = 1
         {
              event macro 15 16
              target 30
              finditem %blessid . %blessi
              if #findcnt = 1 && #finddist <= 8
              {
                set #ltargetid %blessid . %blessi
                set #ltargetkind 1
                event macro 22 0
                event ExMsg %blessid . %blessi 2 3 BLESSED
                set %blessT . %blessi #systime + %blesslength
              }
         }
    }
    set %asd #systime - %blessT . %blessi
    set %blessi %blessi + 1
    if %blessi > %blessq
    {
       set %blessi 1
    }
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub addtoblesslist
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    set %endwait #systime + 3000
    set #targcurs 1
    while #targcurs = 1 && #systime < %endwait
    {
          wait 1
    }
    if #systime > %endwait
    {
          set #targcurs 0
          goto _addtoblesslistEXIT
    }
    if #ltargetkind = 1
    {
       for %i 1 %blessq
       {
           if %blessid . %i = #ltargetid
           {
              event ExMsg #ltargetid 2 3 ALREADY IN BLESS LIST
              GOTO _addtoblesslistEXIT
           }
       
       }
       set %blessq %blessq + 1
       set %blessid . %blessq #ltargetid
       set %blessT . %blessq 0
       event ExMsg #ltargetid 2 3 ADDED TO BLESS LIST
    }

    _addtoblesslistEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub blesspet
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %petid
    if #findcnt = 0 || #finddist > 10
    {
     goto _blesspetEXIT
    }
    event macro 15 16
    target 20
    set #ltargetid %petid
    set #ltargetkind 1
    event macro 22 0
    set %blessT2 #systime + %blesslength
    _blesspetEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc

return

sub blessself
    set #lpc %flpc
    event macro 15 16
    target 30
    event macro 23 0
    set %blessT1 #systime + %blesslength
    set #lpc %dlpc
return

sub remcursepet
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %petid
    if #findcnt = 0 || #finddist > 10
    {
     goto _remcursepetEXIT
    }
    event macro 15 209
    target
    set #ltargetid %petid
    set #ltargetkind 1
    event macro 22 0
    _remcursepetEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc

return

sub remcurseself
    set #lpc %flpc
    event macro 15 209
    target
    event macro 23 0
    set #lpc %dlpc
return

[fnurov]

sub ghealself
set #lpc %flpc
    _healselfStart:
    if C in #CHARSTATUS
    {
       set #targcurs 0
       event macro 15 24
       target 30
       event macro 23 0
       goto _ghealselfEXIT
    }
    if #hits < #maxhits
    {
       set #targcurs 0
       event macro 15 28
       target 30
       event macro 23 0
       goto _ghealselfEXIT
    }
    _ghealselfEXIT:
    set #lpc %dlpc
return

sub ghealpet
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    if #systime > %bandagedelay
    {
       finditem %petid
       if #findcnt = 1 && #finddist < 3
       {
          finditem %bands
          set #lobjectid #findid
          event macro 17 0
          target 10
          set #ltargetid %petid
          set #ltargetkind 1
          event macro 22 0
          set %bandagedelay #systime + 1800
       }
    }
    finditem %petid
    if #findcnt = 0 || #finddist > 10
    {
     goto _ghealpetEXIT
    }
    event macro 15 28
    target 30
    set #ltargetid %petid
    set #ltargetkind 1
    event macro 22 0
    _ghealpetEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub bandagepet
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    if #systime < %bandagedelay
    {
       goto _bandagepetEXIT
    }
    finditem %petid
    if #findcnt = 0 || #finddist > 2
    {
       goto _bandagepetEXIT
    }
    finditem %bands
    set #lobjectid #findid
    event macro 17 0
    target 10
    set #ltargetid %petid
    set #ltargetkind 1
    event macro 22 0
    set %bandagedelay #systime + 1800
    _bandagepetEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub atackenemy
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %enemyid
    if #findcnt = 1
    {
     set #ltargetid %enemyid
     event macro 27 0
     event ExMsg #ltargetid 2 3 ENEMY IS ATACKED
    }
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub lighting

    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %enemyid
    if #findcnt = 0
    {
        goto _lightingEXIT
    }
    event ExMsg #findid 2 3 TARGET
    event macro 15 29
    target 30
    finditem %enemyid
    if #findcnt = 0 || #targcurs = 0
    {
        goto _lightingEXIT
    }
    set #ltargetid %enemyid
    set #ltargetkind 1
    event macro 22 0
    _lightingEXIT:
    set #targcurs 0
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc

return

sub fireball
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %enemyid
    if #findcnt = 0
    {
        goto _fireballEXIT
    }
    event ExMsg #findid 2 3 TARGET
    if #finddist < 2
    {
    ;harm
    event macro 15 11
    target 18
    finditem %enemyid
    if #findcnt = 0 || #targcurs = 0
    {
        goto _fireballEXIT
    }
    set #ltargetid %enemyid
    set #ltargetkind 1
    event macro 22 0
    }
    else
    {
        if #mana < 30
        {
           set %fireballarrow 2
        }

        if %fireballarrow = 1
        {
         ;fireball
         event macro 15 17
         target 24
          finditem %enemyid
          if #findcnt = 0 || #targcurs = 0
          {
           goto _fireballEXIT
           }
          set #ltargetid %enemyid
          set #ltargetkind 1
          event macro 22 0
          set %fireballarrow 2
          goto _fireballEXIT
          }
          ;arraow
           if %fireballarrow = 2
           {
            event macro 15 4
            target 15
            finditem %enemyid
            if #findcnt = 0 || #targcurs = 0
            {
             goto _fireballEXIT
            }
            set #ltargetid %enemyid
            set #ltargetkind 1
            event macro 22 0
            set %fireballarrow 1
            goto _fireballEXIT
           }
    }
    _fireballEXIT:
    set #targcurs 0
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc


return

sub setenemy
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    set %endwait #systime + 2000
    set #targcurs 1
    while #targcurs = 1 && #systime < %endwait
    {
          wait 1
    }
    if #systime > %endwait
    {
          set #targcurs 0
          goto _setenemyEXIT
    }
    if #ltargetkind = 1
    {
       set %enemyid #ltargetid
       event ExMsg %enemyid 3 273 NEW ENEMY SET
    }

    _setenemyEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc

return


sub allkill
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    finditem %petID
    if #findcnt = 0
    {
       goto _allkillEXIT
    }
    event macro 1 0 all kill
    set %endwait #systime + 1000
    while #targcurs = 0 && #systime < %endwait
    {
     wait 1
    }
    if #systime > %endwait
    {
      goto _allkillEXIT
    }
    set %endwait #systime + 2000
    while #targcurs = 1 && #systime < %endwait
    {
     wait 1
    }
    if #systime > %endwait
    {
     set #ltargetid #backpackid
     set #ltargetkind 1
     event macro 22 0
      goto _allkillEXIT
    }
    set %enemyID #LTARGETID
    event ExMsg %enemyid 3 273 NEW ENEMY SET
    
    _allkillEXIT:
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc

return

sub healpet
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    if #systime > %bandagedelay
    {
       finditem %petid
       if #findcnt = 1 && #finddist < 3
       {
          finditem %bands
          set #lobjectid #findid
          event macro 17 0
          target 10
          set #ltargetid %petid
          set #ltargetkind 1
          event macro 22 0
          set %bandagedelay #systime + 1800
       }
    }
    set #targcurs 0
       event macro 15 3
       target 12
       set #ltargetkind 1
       set #ltargetid %petid
       event macro 22 0
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub curepet
    set #lpc %flpc
    set %ltarget #ltargetid
    set %lkind #LTARGETKIND
    if #systime > %bandagedelay
    {
       finditem %petid
       if #findcnt = 1 && #finddist < 3
       {
          finditem %bands
          set #lobjectid #findid
          event macro 17 0
          target 10
          set #ltargetid %petid
          set #ltargetkind 1
          event macro 22 0
          set %bandagedelay #systime + 1800
       }
    }
     set #targcurs 0
       event macro 15 10
       target 15
       set #ltargetid %petid
       set #ltargetkind 1
       event macro 22 0
    set #ltargetid %ltarget
    set #LTARGETKIND %lkind
    set #lpc %dlpc
return

sub healself
    set #lpc %flpc
    _healselfStart:
    if C in #CHARSTATUS
    {
       set #targcurs 0
       event macro 15 10
       target 15
       event macro 23 0
       goto _healselfExit
    }
    if #hits < #maxhits
    {
       set #targcurs 0
       event macro 15 3
       target 12
       event macro 23 0
       goto _healselfExit
    }
    _healselfExit:
    set #lpc %dlpc
return

sub telefar
  set #lpc %flpc
  set %ltarget #ltargetid
  set %lkind #LTARGETKIND
  event macro 15 21
     target 20
     set %x #CHARPOSX
     set %y #CHARPOSY
     set %z #CHARPOSZ
     if #CHARDIR = 0 1 ;N
        set %y %y - %d
     if #CHARDIR = 1 2 ;NE
        set %y %y - %d
        set %x %x + %d
     if #CHARDIR = 2 1 ;E
        set %x %x + %d
     if #CHARDIR = 3 2 ;SE
        set %x %x + %d
        set %y %y + %d
     if #CHARDIR = 4 1 ;S
        set %y %y + %d
     if #CHARDIR = 5 2 ;SW
        set %y %y + %d
        set %x %x - %d
     if #CHARDIR = 6 1 ;W
        set %x %x - %d
     if #CHARDIR = 7 2 ;WN
        set %x %x - %d
        set %y %y - %d
     set #ltargetx %x
     set #ltargety %y
     set #ltargetz %z
     set #ltargetkind 2
     event macro 22 0
_telefarExit:
set #LTARGETKIND %lkind
set #ltargetid %ltarget
set #lpc %dlpc
return

sub telesitpet
  set #lpc %flpc
  set %ltarget #ltargetid
  set %lkind #LTARGETKIND
  finditem %PetId G_ , 12
  If #FindCnt = 0
  {
   goto _telesitpetExit
  }
  set %sTime #systime
  event macro 15 21
     target 20
     finditem %PetId
     if #findx > #charposx
     {
        set #ltargetx #FINDX - 1
     }
     else
     {
         set #ltargetx #FINDX + 1
     }
     if #findy > #charposy
     {
        set #ltargety #FINDy - 1
     }
     else
     {
         set #ltargety #FINDy + 1
     }
     set #ltargetz #FINDZ
     set #ltargetkind 2
     event macro 22 0
     ;wait 1
     set #lobjectid %petid
     event macro 17 0
_telesitpetExit:
set #LTARGETKIND %lkind
set #ltargetid %ltarget
set #lpc %dlpc
return

sub RelPorWaitForCurs
;%1 time of starting casting
set !ChangeTargKindTime %1 + 700
set %TargKindChanged #false
set !fl 1

[fnurov]

while !fl = 1
{
      set !njindex #jindex
      for !j !jindex !njindex
      {
          scanjournal !j
          if disturbed in #journal && : notin #journal
          {
             set %result disturbed
             goto _RelPorWaitForCursExit
          }
          if the_spell_fizzles. in #journal && #CHARNAME in #journal
          {
              set %result fizzles
              goto _RelPorWaitForCursExit
          }
          if cast_a_spell_while_frozen. in #journal && : notin #journal
          {
              set %result frozen
              goto _RelPorWaitForCursExit
          }
          if  #systime > !ChangeTargKindTime
          {
            set %result ok
            goto _RelPorWaitForCursExit
          }
      }
      set !jindex !njindex + 1
      sleep 1
}
_RelPorWaitForCursExit:
set !jindex %njindex + 1
return %result
;end RelPorWaitForCurs

Sub ScanJournalForError
_ScanJournalForErrorStart:
      set !njindex #jindex
      for !j !jindex !njindex
      {
          scanjournal !j
          if the_location_is_too_far_away in #journal && : notin #journal
          {
             set %result error
             goto _ScanJournalForErrorExit
          }
          if target_cannot_be_seen. in #journal && : notin #journal
          {
             set %result error
             goto _ScanJournalForErrorExit
          }
          if cannot_teleport_to_that_spot. in #journal && : notin #journal
          {
             set %result error
             goto _ScanJournalForErrorExit
          }

      }
      if !njindex <> #jindex
      {
            set !jindex !njindex + 1
            goto _ScanJournalForErrorStart
      }
set %result ok
set !jindex !njindex + 1
_ScanJournalForErrorExit:
return %result

[fnurov]

new version