script sposta oggetti

[fuser]

c.d.t. se potete farmi, o linkarmi uno script che faccia queste cose vi sono grato:

targetto le cose che voglio spostare
targetto la cassa, il pet,o la bag dove voglio che vengano spostate
clikko start e sposti tutte le cose contenute in quel pet, bag,cassa ecc in quel pet cassa o bnackpot specificato.

praticamente uno script sposta roba.
(razor nn me lo fa fare)

[Duku]

Questo va bene, non sempre, ma è buono: io lo usavo per spostare 100-120 PoF a botta dal beetle nelle casse. Te lo divido in 7 post

;==================================
; Script Name: RKUltraOrganizer.txt
; Author: Roadkill, copyright IAW Roadkill Public License, see www.easyuo.com
; Version: 3.1
; Client Tested with: 4.0.3e
; EUO version tested with: build 0096
; Shard OSI / FS: OSI
; Revision Date: 20Aug04
; Purpose: find,sort,organize,move, buy items based on type and properties.
;==================================
;Instructions: load it up and hit play. Read the messages, click help button, read.
;******configuration: NOTHING REQUIRED! You MAY change the following if needed**
set %globalvar 888    ;var used with ceofilesystem for saving settings
set %delay 10         ;increase to 15 or 20 if lag problems during drag/drop
;*****DO NOT TOUCH BELOW HERE!*********
initevents
set %version 3.1
set %firstMenuPass #true
gosub ReadInTypeLists
gosub InitializeCheckboxes
gosub ReadInTemplateArray
gosub ReadInPropArrays
gosub ShowEUOMenu1
event Macro 8 2
wait 1s
set %mainpack #backpackid
set %ignoreBagids #charid , _ , %mainpack
mainloop:
	if #menubutton <> n/a
	{
		menu Font Style b
		gosub menuline EUOLabel1 0 0 red black btnface - status:
		menu Font Style
		gosub #menubutton
		set #menubutton n/a
		menu Font Style b
		sound
		gosub menuline EUOLabel1 0 0 lime black btnface - status:
		menu Font Style
		set #lpc 10
	}
	wait 10
	gosub ExclusiveAndOr %EUOCheckBoxANDchecked %EUOCheckBoxORchecked
goto mainloop
;following menu code HIGHLY modified, do NOT open this up with MenuDesigner, it will
;overwrite and erase all the functions!
;**
;* @name showEUOMenu1
;* @ver 1.1 by Roadkill 27May04
sub showEUOMenu1
	menu Clear
	menu Window Title Roadkill's UltraOrganizer ver. %version
	menu Window Color BtnFace
	menu Window Size 415 300
	menu Font Name MS Sans Serif
	menu Font Size 8
	menu Font Style b
	menu Font Color Black
	menu Font Transparent #false
	menu Font Align Left
	menu Text EUOLabel1 0 0 status:
	menu Font Color Red
	menu Text status 42 0 Look here for messages! Setup checkboxes then click a button.$
		+Remember, by default only the last-clicked open bag$is searched,
		+unless you check box to search all-open.
	menu Text LastType 366 224 last type
	menu Shape EUOShape1 164 40 2 181 3 7 1 Yellow 7 Yellow
	menu Shape EUOShape2 76 40 2 181 3 7 1 Yellow 7 Yellow
	menu Shape EUOShape3 250 138 165 79 3 7 1 Black 7 Blue
	menu Shape EUOShape4 0 217 417 2 3 7 1 Yellow 7 Yellow
	;menu Shape EUOShape5 0 267 417 2 3 7 1 Lime 7 Lime
	;menu Shape EUOShape6 0 243 417 2 3 7 1 Lime 7 Lime
	menu Shape EUOShape6 0 242 417 50 3 7 1 Lime 7 Lime
	;menu Font Style i
	menu Font Color black
	;menu Font BGColor gray
	;menu Text EUOLabel2 0 270 Container Settings: by default, only the last-clicked
	;	+ open container is searched
	menu Font Style
	menu Font BGColor btnFace
	menu Button Help 342 14 75 25 HELP
	menu Button IndexItems 342 40 75 21 INDEX items
	menu Button FindItems 342 60 75 21 FIND items
	menu Button SetDropSpot 348 80 69 17 Set DropSpot
	menu Button SortItems 342 97 75 21 SOR&T items
	menu Button BuyItems 342 118 75 21 BUY items
	menu Button OpenVendors 250 120 90 19 Open Vendors
	menu Button GetItemType 290 220 75 21 get ItemType
	menu Button WTF 2 267 35 20 WTF?
	menu Font BGColor aqua
	menu Check EUOCheckBox1 0 42 75 17 %box1checked All Jewelry
	menu Font BGColor BtnFace
	menu Check EUOCheckBox2 8 60 59 17 %box2checked rings
	menu Check EUOCheckBox3 8 76 67 17 %box3checked bracelets
	menu Font BGColor aqua
	menu Check EUOCheckBox4 0 94 73 17 %box4checked All Armor
	menu Font BGColor BtnFace
	menu Check EUOCheckBox5 8 112 63 17 %box5checked metal
	menu Check EUOCheckBox6 8 130 63 17 %box6checked leather
	menu Check EUOCheckBox7 8 148 63 17 %box7checked bone
	menu Check EUOCheckBox8 8 166 63 17 %box8checked non-Med
	menu Check EUOCheckBox9 8 182 63 17 %box9checked Med
	menu Font BGColor aqua
	menu Check EUOCheckBox10 0 200 71 17 %box10checked Shields
	menu Check EUOCheckBox11 78 42 85 17 %box11checked All Weapons
	menu Font BGColor BtnFace
	menu Check EUOCheckBox12 86 60 69 17 %box12checked Swords
	menu Check EUOCheckBox13 86 76 69 17 %box13checked Fencing
	menu Check EUOCheckBox14 86 94 69 17 %box14checked Mace
	menu Check EUOCheckBox30 86 112 69 17 %box30checked Archery

	menu Font BGColor aqua
	menu Check EUOCheckBox15 78 130 85 17 %box15checked All Regeants
	menu Font BGColor BtnFace
	menu Check EUOCheckBox16 86 148 75 17 %box16checked Mage Regs
	menu Check EUOCheckBox17 86 166 77 17 %box17checked Necro Regs
	menu Font BGColor aqua
	menu Check EUOCheckBox18 78 182 85 17 %box18checked MageScrolls
	menu Check EUOCheckBox19 78 200 85 17 %box19checked NecroScrolls


	menu Check EUOCheckBox20 166 200 81 17 %box20checked Jewels
	menu Check EUOCheckBox21 168 42 73 17 %box21checked All Fishing
	menu Font BGColor BtnFace
	menu Check EUOCheckBox29 176 176 57 17 %box29checked Shells
	menu Check EUOCheckBox27 176 142 59 17 %box27checked Pillows
	menu Check EUOCheckBox26 176 126 57 17 %box26checked Skulls
	menu Check EUOCheckBox25 176 110 57 17 %box25checked Bones
	menu Check EUOCheckBox22 176 58 71 17 %box22checked BodyParts
	menu Check EUOCheckBox23 176 76 71 17 %box23checked BarrelParts
	menu Check EUOCheckBox28 176 158 61 17 %box28checked Globes
	menu Check EUOCheckBox24 176 92 57 17 %box24checked Shoes
	menu Check custom 0 220 63 19 %customchecked Custom
	menu Font BGColor white
	str lower %EditCustom
	menu Edit EditCustom 64 220 223 #strres
	menu set EditCustom #strres
	;------propfilter section--
	menu Font BGColor lime
	menu Check propfilter 0 244 71 23 %propfilterchecked use Prop Filter
	menu Font BGColor white
	menu font size 8
	menu Combo Create ComboBoxProp1 70 244 129
	gosub PopulateComboBox ComboBoxProp1 proplist 0 %proplisttotal
	menu set ComboBoxProp1 %prop1
	menu Combo Create ComboBoxProp2 288 244 129
	gosub PopulateComboBox ComboBoxProp2 proplist 0 %proplisttotal
	menu set ComboBoxProp2 %prop2
	menu font size 8
	menu Font BGColor teal
	menu Check EUOCheckBoxAND 200 246 43 17 %EUOCheckBoxANDchecked AND
	menu Font BGColor lime
	menu Check EUOCheckBoxOR 244 246 43 17 %EUOCheckBoxORchecked OR
	menu font BGColor white
	menu Edit EuoEditCustomProp1 50 267 90 customprop1
	menu Edit EuoEditCustomProp2 250 267 90 customprop2
	menu Edit EuoEditNumProp1 185 267 30
	menu Edit EuoEditNumProp2 380 267 30
	menu combo create ComboBoxEvalProp1 140 267 40
		menu combo add ComboBoxEvalProp1 all
		menu combo add ComboBoxEvalProp1 >=
		menu combo add ComboBoxEvalProp1 <=
	menu combo create ComboBoxEvalProp2 340 267 40
		menu combo add ComboBoxEvalProp2 all
		menu combo add ComboBoxEvalProp2 >=
		menu combo add ComboBoxEvalProp2 <=
	;--------save/load section-----
	menu Font BGColor BtnFace
	menu Button SaveSetting 256 142 63 45 Save Setting
	menu Button LoadSetting 256 188 63 25 Load Setting
	menu Font BGColor white
	menu Combo Create EUOComboBoxLoad 320 190 91
	if %lasttemplate >= 2
		gosub PopulateComboBox EUOComboBoxLoad templatename 2 %lasttemplate
	menu Combo Create EUOComboBoxSave 320 164 91
	gosub PopulateComboBox EUOComboBoxSave templatename 1 %lasttemplate
	menu Edit EUOEditSave 320 142 91 new names here
	menu Font BGColor purple
;	menu Check EUOCheckBoxAll 250 122 73 17 %EUOCheckBoxAllchecked ALL items!
	menu Check EUOCheckBoxAll 0 15 42 27 %EUOCheckBoxAllchecked ALL!

	;----test section for moving container checkboxes up----
	menu Font BGColor BtnFace
	;menu Check EUOCheckBoxSearchAll 0 284 158 13 %EUOCheckBoxSearchAllchecked
	;	+ Search All Open Containers
	;menu Check EUOCheckBoxIgnoreWorn 170 284 183 13 %EUOCheckBoxIgnoreWornchecked
	;	+ Ignore items in mainpack or worn
	menu Font Style i
		menu Font Color black
		menu Font BGColor gray
		menu Text EUOLabel2 250 42 Container Settings:
		menu Font Style
	menu Check EUOCheckBoxSearchAll 250 56 90 30 %EUOCheckBoxSearchAllchecked
		+ search all open contnrs
	menu Check EUOCheckBoxIgnoreWorn 250 87 90 34 %EUOCheckBoxIgnoreWornchecked
		+ Ignore items in mainpack or worn
	menu Font BGColor btnFace
;--------------
	menu Shape EUOShape7 248 42 2 175 3 7 1 Yellow 7 Yellow
	if %firstMenuPass
	{
		set #menubutton n/a
		menu select ComboBoxEvalProp1 1
		menu select ComboBoxEvalProp2 1
		menu Show 421 270


	}
	set %firstMenuPass #false
return
;==============
;**
;* @name ReadInTypeLists
;* @credits: 40% of lists courtesy of CEO. Lists presented here in broken out
;*	format so users can understand them and make use of them if desired.
sub ReadInTypeLists
	set %containertypes _CKF_LKF_ZJF_JIF_HIF_KIF_IIF_CUD_HKF_VMF_BUD_KUD_
	set %ringtypes _lwl_ujg_
	set %bracelettypes _cwl_ijg_
	set %jewelrytypes %ringtypes , %bracelettypes
	set %mageregtypes _KUF_JUF_KZF_JZF_MZF_WZF_RZF_SZF_
	set %necroregtypes _NZF_DUF_TZF_UZF_YZF_IUF_
	set %regtypes %mageregtypes , %necroregtypes
	set %jeweltypes _HVF_UVF_FVF_EVF_OVF_VUF_GVF_RVF_BVF_
	set %necroscrolltypes _kym_pym_sym_tym_wym_
	set %mageryscrolltypes _AUL_BUL_cul_dul_EUL_FUL_GUL_hul_iul_JUL_KUL_LUL_MUL_nul_oul_PUL_
		+QUL_RUL_SUL_tul_UUL_vul_wul_XUL_YUL_zul_avl_gvl_fvl_ivl_hvl_cvl_
		+NTL_otl_ptl_qtl_rtl_stl_ttl_utl_VTL_wtl_XTL_YTL_ZTL_
		+qxl_pxl_zxl_nxl_wxl_vxl_yxl_xxl_zfj_byl_cyl_dyl_eyl_fyl_gyl_hyl_iyl_jyl_kyl_
	set %shelltypes _xwf_lxf_ywf_zwf_gxf_jxf_mxf_axf_kxf_
	set %skulltypes _rck_mck_sck_
	set %bodyparttypes _hwk_kwk_pwk_iwk_mwk_dwk_vvk_
	set %bonetypes _fjk_xik_djk_zik_bjk_kjk_yik_ajk_
	set %pillowtypes _ooh_moh_noh_aoh_boh_coh_loh_hoh_koh_ioh_znh_
	set %barrelparttypes _xsl_dtl_ysl_btl_etl_
	set %globetypes _xbg_icg_
	set %fishtypes _FQD_GQD_DQD_EQD_
	set %fishsteaktypes _IND_
	set %shoetypes _QVI_CWI_TVI_AWI_PVI_NVI_ZVI_OVI_

[Duku]

	set %shieldtypes _LIK_MIK_CLK_AIK_CIK_LYD_GIK_NIK_ZHK_HLK_BLK_FIK_BIK_OIK
	set %bonearmortypes _zph_yph____wph_pph__bqh_qph__vph__xph_cqh_aqh_
	set %leatherarmortypes _njl_qjl__jkh__qkh_dlh__hkh_pkh__skh_kkh__vkh_elh_
	set %studdedarmortypes __alh_ulh_llh__ykh_glh__xkh_flh__rlh_mlh_
	set %otherLeatherarmortypes _atk_zsk_osk_nsk_usk_ssk_rsk_qsk_psk_ysk_
	set %tailorableTypes %bonearmortypes , %leatherarmortypes , %studdedarmortypes ,
		+ %otherLeatherarmortypes
	set %medHelmetTypes _YVI_GZH_HZH_NJL_BWI_KWI_IWI_EWI_QJL_JWI_XVI_CZH_HWI_JJN_
		+NZH_BZH_TDI_OZH_VSH_WVI_VVI_QSH_KZH_PZH_DZH_
	set %nonmedHelmetTypes _DSH_ASH_TSH_ESH_YPH_GSH_OSH_ZPH_ZRH_IWL_CSH_
		+CSH_BSH_FSH_DPH_LKO_NWL_MKH_
	set %helmetTypes %medHelmetTypes , %nonmedHelmetTypes
	set %medGorgotTypes _JKH_RJG_SJG_FJG_MWL_
	set %nonmedGorgotTypes _NSH_ALH_
	set %GorgotTypes %nonmedGorgotTypes , %medGorgotTypes
	set %medArmTypes _HKH_PKH_
	set %nonmedArmTypes _BQH_JSH_XLH_GLH_MSH_YLH_QPH_YKH_DLO_
	set %armTypes %medArmTypes , %nonmedArmTypes
	set %medTunicTypes _QKH_DLH_
	set %nonmedTunicTypes _HSH_ULH_LLH_ZOH_IKH_VLH_KSH_WLH_WPH_PKO_PPH_RSK_
	set %femaleMedTunicTypes _ATK_ZSK_OSK_NSK_
	set %femaleNonMedTunicTypes _USK_SSK_MSK_TSK_LSK_
	set %TunicTypes %medTunicTypes , %nonmedTunicTypes , %femaleMedTunicTypes , %femaleNonMedTunicTypes
	set %medGloveTypes _KKH_SKH_WTO_
	set %nonmedGloveTypes _VPH_ISH_AQH_BMH_USH_XKH_FLH_KMH_RKO_
	set %GloveTypes %medGloveTypes , %nonmedGloveTypes
	set %medLeggingTypes _VKH_ELH_
	set %nonmedLeggingTypes _HMH_LSH_IMH_CQH_WSH_APH_MLH_RLH_NKH_XPH_NKO_
	set %femaleMedLeggingTypes _QSK_YSK_PSK_
	set %leggingTypes %medLeggingTypes , %nonmedLeggingTypes , %femaleMedLeggingTypes
	;weapons------
	set %unkweapontypes _MPF_BNF_WTH_OLH_JOH_EMH_BFF_QMH_SRH_OSF_INF_FSF_YPO_JSF_CPH_DMH_URH_CFF
	set %swordtypes _asf_hnf_fmh_cnf_lsf_nsf_isf_smh_rmh_csf_zrf_mph_lph_
		+_msf_bsf_kpo_guo_ktf_jtf_bph_eph_zsf_atf_jph_soh_poh_nmh_omh_lpo_zto_xth_yth_
		+hsf_ksf_npo_xpo_fuo_jpo_qpf_npf__KPH_FYG_RHM_
	set %fencingtypes _aqf_ppf_tsf_wsf_buo_vpo_wpo_wrh_vrh_xrh_yrh_ltf_mtf_opo_rrh_cuo_
	set %macetypes _pmh_gmh_zpf_cqf_fff_rpf_trh_ysf_xsf_fbg_vth_auh_zth_uoh_voh
		+_auo_mpo_buh_cuh_dmh_gff_qoh_hff_tlh_gbg_
	set %bowtypes _WOH_TOH_QPO_SPO_
	set %rhandbowtypes _WOH_TOH_JSF_USF_LMH_MMH_
	set %lhandbowtypes _QPO_SPO_PPO_RPO_
	set %xbowtypes _JSF_USF_LMH_MMH_PPO_RPO_
	;----
	set %hats _ZPH_KWI_IWI_EWI_WVI_DPH_NWL_CZH_BWI_MKH_HZH_YVI_ZJF_QJL_JWI_ASH_DSH_XVI_JWI_OSH_CSH_ESH_GSH_FSH_YPH_
	set %chest _LLH_PPH_QKH_WLH_LSK_OSK_WLH_ULH_IKH_ZOH_NSK_HSH_FZH_KSH_DLH_HSH_DLH_WPH_
	set %legs _APH_VKH_RLH_NKH_HKH_XPH_MLH_CQH_HMH_GLH_PKH_YLH_ELH_IMH_
	set %arms _YLH_YKH_GLH_JSH_BQH_MSH_QPH_HKH_PKH_XLH_YKH_
	;----checkbox type settings---------
	set %box1types %jewelrytypes
	set %box2types %ringtypes
	set %box3types %bracelettypes
	set %box4types %helmetTypes , %gorgotTypes , %armtypes , %tunictypes , %glovetypes , %leggingtypes
	set %box5types _DSH_ASH_TSH_ESH_GSH_OSH_ZRH_IWL__NSH_JSH_XLH_MSH_YLH_DLO_
	+_HSH_ZOH_IKH_VLH_KSH_WLH_WPH_PKO_RSK__USK_SSK_MSK_TSK_LSK__ISH_BMH_USH_
	+_KMH_RKO__HMH_LSH_IMH_WSH_APH_NKH_NKO_MKH_FSH_csh_
	set %box6types %leatherarmortypes , %studdedarmortypes , %otherLeatherarmortypes
	set %box7types %bonearmortypes
	set %box8types %nonmedHelmetTypes , %nonmedGorgotTypes , %nonmedArmTypes ,
	+ %nonmedTunicTypes , %femaleNonMedTunicTypes , %nonmedGloveTypes , %nonmedLeggingTypes
	set %box9types %medhelmettypes , %medGorgotTypes , %medArmTypes ,
	+ %medTunicTypes , %femaleMedTunicTypes , %medGloveTypes , %medLeggingTypes ,
	+ %femaleMedLeggingTypes
	set %box10types %shieldtypes
	set %box11types %unkweapontypes , %swordtypes , %fencingtypes , %macetypes , %bowtypes , %xbowtypes
	set %box12types %swordtypes
	set %box13types %fencingtypes
	set %box14types %macetypes
	set %box15types %regtypes
	set %box16types %mageregtypes
	set %box17types %necroregtypes
	set %box18types %mageryscrolltypes
	set %box19types %necroscrolltypes
	set %box20types %jeweltypes
	set %box21types %bodyparttypes , %barrelparttypes , %shoetypes , %bonetypes ,
		+ %skulltypes , %pillowtypes , %globetypes , %shelltypes
	set %box22types %bodyparttypes
	set %box23types %barrelparttypes
	set %box24types %shoetypes
	set %box25types %bonetypes
	set %box26types %skulltypes
	set %box27types %pillowtypes
	set %box28types %globetypes
	set %box29types %shelltypes
	set %box30types %bowtypes , %xbowtypes
	;-------
	set %totalCheckBoxtypes 30  ;<<==critical this is correct for numbered ones!
return
;=======
sub InitializeCheckboxes
	for !i 1 %totalCheckBoxtypes
	{
		set % . Box . !i , checked #false
	}
	set %customchecked #false
	set %propfilterchecked #false
	set %EUOCheckBoxANDchecked #false
	set %EUOCheckBoxORchecked #true
	set %EUOCheckBoxAllchecked #false
	set %EUOCheckBoxSearchAllchecked #false
	set %EUOCheckBoxIgnoreWornchecked #true
	set %EditCustom type , #spc , custom , #spc , string , #spc , here, , #spc , ex.: , #spc , POF_RWF_ZWF
return
;======
;**
;* @name ReadInTemplateArray
;* @ver 1.0 by Roadkill 10May04
;* @purpose populates the array "templatename1..30" for use to build the comboboxs
;	EUOComboBoxSave	and EUOComboBoxLoad
;* @params
;* @returns %lasttemplate and loads %templatename1 to %lasttemplate
;* @info %templatename1 holds the "use new name above" setting.
;* @status done tested good
sub ReadInTemplateArray
set %templatename1 Use_New_Name_Above
	for !i 2 30
	{
		gosub getGlobalVar %globalvar UltraOrg template . !i templatename . !i nolock
		if %templatename . !i = n/a
		{
			set %lasttemplate !i - 1
			return
		}
	}
return
;======
;**
;* @name BuildSearchString
;* @ver 1.0 by Roadkill
;* @purpose scan all checkboxes, if checked then append their string to SearchString
;*	also scan all custom and custom edit field, in prep for saving vars
;* @params all %vars used global
;* @returns %SearchString holds the search string of types
;* @info DB is of format:
; euocheckbox1,2,3 etc.  %box1checked (#t/#f), %box1types _abc_def_
sub BuildSearchString
	set !lpc #lpc
	set #lpc 1000
	gosub menuline status 42 0 yellow red - -  scanning your checkboxes...
	set %SearchString
	menu get EUOCheckBoxAll
	if #menures
	{
		set %SearchString *
		goto _exitBuildSearchString
	}
	for !i 1 %totalCheckBoxtypes
	{
		menu get EUOCheckBox . !i
		set % . Box . !i , checked #false
		;set boxstatus holder, append string if not already in
		;  using a temp var to help concatenate the ., variablename
		if #menures
		{
			set % . Box . !i , checked #true
			set %tmp box , !i , types
			set %boxString % . %tmp
			if %boxString NOTIN %SearchString
			set %SearchString %SearchString , %boxString
		}
	}
_exitBuildSearchString:
	;scan all other boxes and fields so data is current for saving and
	;add in any string in the custm edit field if custom checked
	menu get custom
	set %customchecked #menures
	if #menures
	{
		menu get editCustom
		set %editCustom #menures
		if %SearchString <> *
			set %SearchString %SearchString , #menures
	}
	set #lpc !lpc
 return
;============
sub Closed
	set #menubutton n/a
	wait 10
	halt
return
;============
sub WTF
	gosub menuline status 42 0 yellow red - -  Explaining WTF about property filtering...
	display OK Once you've set up the TYPES of things you want to look for, using$
	+the checkboxes and the custom field, you can elect to FURTHER filter those items$
	+using properties, in the lime-area(check the "use_Prop_filter" box).  You can look for two different$
	+properties, either one or both.
	display OK To find items with BOTH properties, check the "AND" box, for either property$
	+check the "OR" box. If you only want to look for one property, use the first drop-down$
	+and leave the other blank or set to the first choice "---stat.props---".$
	+Each drop-down property-box contains all 87 loot-properties$
	+(stat.props,_armor/jewelry.props,_weapon.props,_skills.props,_other.props)
	display OK Custom Property strings:$If you need to filter on something not in the$
	+drop-downs, you can select the VERY LAST choice in the drop-down,"//use_custom.prop//"$
	+Then the editbox underneath becomes active, you can type your property-word such as "deviously" if$
	+you were looking for level-5 TreasureMaps.
	display OK Property Intensity:$On the second propertyline there is another dropdown and then$
	+a small editfield next to each custom-property-field.  You can use these to filter for$
	+an "intensity" or number-size for each property, whether from the drop-down or$
	+custom-property-field. Select "All"(no-filtering),">=",or"<=", then enter your number (i.e.15)
	display OK Example:$I want to find level-4&5 treasure-maps. I use "getItemType" button to put XVH$
	+into the custom-field, check the custom box and make sure nothing else is search-checked.$
	+I check "search-all-open-containers", and open all my map-bags. I check "usePropFilter", "OR"$
	+and select the last drop-down "//use_custom.prop//" in each property-drop-down$
	+......more.........
	display ok ...then type "cleverly" and "deviously" in the custom-property-fields,
	+then hit$"INDEXitems"-to_write_a_nice_file_of_the_maps,$"FINDitems"-to_read_the
	+properties_of_each_one_and_decide_whether_to_move_it_(say Fel vs. Tram),$
	+"SORTitems"-to_just_move_them_all_to_a_spot_under_my_cursor,_or$"BUYitems"-
	+to read price/properties of matching vendor-maps and decide to buy or not.
	gosub menuline status 42 0 black red - -  Setup checkboxes then click a button.
	+  If you check an "all" box, you don't$ have to check sub-boxes. You may also
	+ select props to filter$ for. Only the active container is searched by default.
return
;============
sub OpenVendors
	display OK Not Yet Implemented
return

[Duku]

;============
sub Help
	set #menubutton n/a
	menu Font BGColor Lime
	menu Button Help 342 14 75 25 HELP
	gosub menuline status 42 0 lime black - -  Click on a button for Info, or HELP
		+button again to leave HELP and return to the $normal program. "status:"
		+ is RED when program busy,$ GREEN when ready (and a 'ping' sounds).
_helploop:
	if #menubutton <> n/a
		goto _help , #menubutton
	goto _helploop
_helpHelp:
	menu Font BGColor BtnFace
	menu Font Color WindowText
	menu Button Help 342 14 75 25 HELP
	gosub menuline status 42 0 black red - -  Setup checkboxes then click a button.
	+  If you check an "all" box, you don't$ have to check sub-boxes. You may also
	+ select props to filter$ for. Only the active container is searched by default.
	return
_helpIndexItems:
	gosub menuline status 42 0 lime black - -  Writes a file of all items in
	+ container that match your checkboxes and propfilter$File will be called
	+ RKIndexlist_#contid, or you can choose your$ own filename.
	set #menubutton n/a
	goto _helploop
_helpFindItems:
	gosub menuline status 42 0 lime black - -  Finds all items in 
	+ container(s) that match your checkboxes and propfilter,$displays their props,
	+ gives you choice to move them.
	set #menubutton n/a
	goto _helploop
_helpSortItems:
	gosub menuline status 42 0 lime black - -  Moves/sorts all items in containter(s)
	+ that match your checkboxes and propfilter$and drops them to a spot set with
	+ your cursor. Useful for$ treasure chests and MIBs to empty trash or good loot.
	set #menubutton n/a
	goto _helploop
_helpBuyItems:
	gosub menuline status 42 0 lime black - -  Finds items in vendor bag(s) that match your
	+ checkboxes and propfilter,$ gives option to buy the item. If you answer 'yes' the 'buy
	+ gump'$ is shown, which you then click buy or cancel. No more clicking!
	set #menubutton n/a
	goto _helploop
_helpSetDropSpot:
	gosub menuline status 42 0 lime black - -  This is used for "FIND items" to
	+ place the items you accept$ somewhere other than your backpack, such as
	+ vendorbag or$ ground. If it can't drop the item there, it puts in mainpack.
	set #menubutton n/a
	goto _helploop
_helpSaveSetting:
	gosub menuline status 42 0 lime black - - Saves all settings to a selected existing
	+ template or a new one (up to 30) $ using CEOfilesystem. You can use them with any 
	+ character.$ Useful for pre-setting say "Trash" and "GoodLoot" for MIBs.
	set #menubutton n/a
	goto _helploop
_helpLoadSetting:
	gosub menuline status 42 0 lime black - - Loads settings from selected previously
	+ saved templates. These settings$ work with any character/account. You can erase$
	+ all saved settings by typeing "set * , %globalvar" in EUO and play.
	set #menubutton n/a
	goto _helploop	
_helpGetItemType:
	gosub menuline status 42 0 lime black - - When you click this, you have 5 seconds
	+ to drag an item$ and it's 'Type' for use in the 'custom' field is reported$
	+ as well as being appended to your 'custom' type-string.
	set #menubutton n/a
	goto _helploop	
_helpWTF:
	gosub menuline status 42 0 lime black - - Runs through a series of 6 display-boxes
	+ which explain$WTF is up with those property-controls and how to use them.
	set #menubutton n/a
	goto _helploop
_helpOpenVendors:
	gosub menuline status 42 0 lime black - - When you click this, all vendors in
	+ range of you$will have their packs opened and all their sub-bags up to$
	+ 3-levels deep so you can search them all with the BUY button.
	set #menubutton n/a
	goto _helploop		
;=============
;**
;* @name GetSearchContainer
;* @purpose sends back "C" if "searchallcontainers"box is checked, or C_#contid if not;
;*	the #contid of whatever active container is open is sent back, if the gump
;*	with focus is NOT a container a display box lets you target one interactively
;*	Also checks status of "ignore worn items and mainpack" and passes back as @%2
;* @params %1 req holds varname for single or all containers
;*	%2 req holds varname for status of ignore worn/mainpack box
;*	%3 opt if #true only the checkbox status are updated, for saving
;* @returns @%1 holds "C" or "C_#contid"
;*	@%2 holds status of ignore worn items checkbox
;*	also %EUOCheckBoxSearchAllchecked and %EUOCheckBoxIgnoreWornchecked updated
;*	for template saves
sub GetSearchContainer
	set % . %2 #false
	set %EUOCheckBoxIgnoreWornchecked #false
	if %0 < 3
		set %3 #false
	menu get EUOCheckBoxIgnoreWorn
	if #menures
	{
		set %EUOCheckBoxIgnoreWornchecked #true
		set % . %2 #true
	}
	menu get EUOCheckBoxSearchAll
	set %EUOCheckBoxSearchAllchecked #false
	if #menures
	{
		set %EUOCheckBoxSearchAllchecked #true
		set % . %1 C
		return
	}
	if %3
		return
	if #conttype notin %containertypes
	{
		display ok No container was active, dblclick on the container$
		+to use or drag it, be SURE IT IS OPEN! You have 5 sec
		wait 5s
	}
	set % . %1 C_ , #contid
return
;=============
;**
;* @name IndexItems
;* @purpose write a file with a list of all items matching criteria
;* @status done. tested
sub IndexItems
	gosub BuildSearchString
	gosub GetPropFilter
	gosub GetSearchContainer indexcont ignoreworn
	set !filename RKIndexlist_
	set !filename !filename , %indexcont , _.txt
	gosub menuline status 42 0 black red - - The indexlist for container(s) will be called
	+ !filename and$ will be written to same DIR as script/EUO. Dont ask
	+ where it is,$ use search. Please respond to the DISPLAY box now.
	display yesno YES= use the default name ( !filename )$
	+NO=Use my own filename (type filename into the "SAVE setting" editwindow$
	+         then click "SAVE setting" button)
	if #dispres = no
	{
		set #menubutton n/a
		_indexfilename:
		wait 10
		if #menubutton <> savesetting
			goto _indexfilename
		menu get EUOeditSave
		set !filename #menures
		set #menubutton n/a
		gosub menuline status 42 0 black red - -  file will be called !filename
	}
	set !lpc #lpc
	set #lpc 1000
	set !_waidx 0
_IItop:
	gosub FilterItems
	if #result = #false
		goto _IIexit
	set !_waidx !_waidx + 1
	set %Indexarray . !_waidx !_waidx , #spc , #property
	ignoreitem #findid 9
	goto _IItop	
_IIexit:
	ignoreitem reset 9
	if !_waidx > 0
	{
	  gosub menuline status 42 0 black red - - writing the file...
	  gosub WriteFastDOSarray Indexarray 1 !_waidx !filename
	  gosub menuline status 42 0 black red - - File !filename written!
	}
	set #lpc !lpc
return
;================
;**
;* @name FindItems
;* @author Roadkill
;* @ver 1.0 9May04
;* @purpose Finds all items in a container that match your checkboxes and propfilter
;*    displays their props and gives you choice to move them to another spot
;* @params 	
;* @returns
;* @notes mod RKPropsorter for this sub
;* @status done, but looking at ability to move to specific container
sub FindItems
	gosub BuildSearchString
	gosub menuline status 42 0 black red - - Checking props for search types,
	+ you'll have choice to move matching items$to your mainpack/dropspot, don't touch paperdoll!
	gosub GetPropFilter
	gosub FindPaperdollnMainpackXY %mainpack paperdollx paperdolly mainpackx mainpacky
	gosub GetSearchContainer indexcont ignoreworn
	finditem %SearchString %indexcont
	if #findkind = -1
	{
		gosub menuline status 42 0 black red - - No matching items found
		return
	}
	set !drpmsg mainpack
	if %dropspotset
		set !drpmsg dropspot(mainpack_backup)
_FIsearch:
	gosub FilterItems
	if #result = #false
		return
	str lower !drpmsg
	display yesno Move this item to #strres ?$ #property
	if #dispres = yes
	{
		if %dropspotset
		   gosub MoveItemToPos %currentitem %dropspotx %dropspoty 0
		if ! %dropspotset || #lliftedkind = 1
		   gosub MoveItemToPos %currentitem %mainpackx %mainpacky 0
	}	
	ignoreitem #findid 9
	goto _FIsearch	
;==========
;**
;* @name SortItems
;* @author Roadkill
;* @ver 1.1 19Aug04
;* @purpose sets dropspot and runs filterItem, moves matching items to dropspot
;* @params 
;* @returns
;* @status: untested, uses new FilterItem with propvalues

[Duku]

sub SortItems
	gosub BuildSearchString
	gosub menuline status 42 0 black red - - Checking props for search types,
	+ matching items will be moved to spot$underneath your cursor when you press "ENTER"
	+ at the DISPLAY OK prompt.
	gosub GetPropFilter
	gosub GetSearchContainer indexcont ignoreworn
	finditem %SearchString %indexcont
	if #findkind = -1
	{
		gosub menuline status 42 0 black red - - No matching items found
		return
	}
	display OK Place your cursor over the spot you want the matching items dropped,$
	+ be sure it is a reachable spot and not an open search container. Remember,$
	+ dropping on pack edges is 1337!  When ready PRESSSS "ENTER".$
	+(LONG PRESS!--not a jab,not a click!)
	set !dropx #cursorx
	set !dropy #cursory
_SIsearch:
	gosub FilterItems
	if #result = #false
		return
	gosub MoveItemToPos %currentitem !dropx !dropy 0
	ignoreitem #findid 9
	goto _SIsearch
;=========
;**
;* @name FilterItems
;* @author Roadkill
;* @ver 1.1 19Aug04
;* @purpose extracted item filtering for main subs. not always used, due to
;*	desire to optimize user feedback at proper spots...
;* @params assumes globals: %searchstring, %indexcont, %ignoreworn, %ignorebagids,
;*	%propfilterchecked, %prop1, %evalprop1, %prop2, %evalprop2, %propAndOr
;* @returns #result is #true if matching item found, #false if not found
;*	if found, %currentitem is set to the #findid
;* @changes: ignorelist 9 is appended if item found, or reset if no matches found,
;*	#property, #result, %currentitem,#lpc set high (reset upon no matchexit)
sub FilterItems
	set !lpc #lpc
	set #lpc 1000
_Filtsearch:
	finditem %SearchString %indexcont
	if #findkind = -1
	{
		gosub menuline status 42 0 black red - - No more matching items found
		ignoreitem reset 9
		set #lpc !lpc
		return #false
	}
	if %ignoreworn && #findbagid IN %ignoreBagids
	{
		ignoreitem #findid 9
		goto _Filtsearch
	}
	set %currentitem #findid
	event property #findid
	if ! %propfilterChecked
		return #true
;	%EvalProp1, %EvalProp2 holds all | >= | <=
;	%numProp1, %numProp2   holds the number to compare prop1 and prop2 against
;check for first property condition being met, only sent to slow getpropnum if needed
	set !prop1met #false
	if %prop1 IN #property
	{
		if %EvalProp1 = all
			set !prop1met #true
		else
		{
			gosub getPropNum %prop1 propnum
			if %propnum %EvalProp1 %numProp1
				set !prop1met #true
		}
	}
;check for 2nd property condition being met, only sent to slow getpropnum if needed
	set !prop2met #false
	if %prop2 IN #property
	{
		if %EvalProp2 = all
			set !prop2met #true
		else
		{
			gosub getPropNum %prop2 propnum
			if %propnum %EvalProp2 %numProp2
				set !prop2met #true
		}
	}
	;now evaluate the ANDOR of both prop evaluations
	if !prop1met  %propAndOr !prop2met
		return #true
	ignoreitem %currentitem 9
goto _Filtsearch
;==========
sub SetDropSpot
	if %dropspotset
	{
		set %dropspotset #false
		gosub menuline status 42 0 black red - - DropSpot De-Activated!
		menu Font BGColor BtnFace
		menu Font Color WindowText
		menu Button SetDropSpot 348 80 69 17 Set DropSpot
		return
	}
	gosub menuline status 42 0 black red - - This is used for "FIND items" to
	+ place the items you accept$ somewhere other than your backpack, such as a
	+ vendorbag.$ If it can't drop the item there, it will put in mainpack.
	display OK Place your cursor over the spot you want the matching items dropped,$
	+ be sure it is a reachable spot!!!! Remember,dropping on pack edges is 1337!$
	+ When ready PRESSSS "ENTER".
	set %dropspotx #cursorx
	set %dropspoty #cursory
	set %dropspotset #true
	menu Font BGColor lime
	menu Font Color WindowText
	menu Button SetDropSpot 348 80 69 17 Set DropSpot
return
;========
sub BuyItems
	gosub BuildSearchString
	gosub GetPropFilter
	gosub GetSearchContainer indexcont ignoreworn
_BItop:
	gosub FilterItems
	if #result = #false
		goto _BIexit
	gosub menuline status 42 0 black red - - Be sure "Search All Open Containers"
	+ is set as you want$ Checking open vendor bag(s) for matching items...$
	+ You will be given TWO chances to CANCEL the buy, don't worry.
	display yesno Would you like to see the "Buy Gump" for this item?$ #property
	if #dispres = yes
	{
		set #ltargetkind 1
		set #ltargetid %currentitem
		event macro 3 0 vendor buy
		target
		event macro 22 0
		gosub sysVarWait contname = generic_gump 30
		gosub sysVarWait contname <> generic_gump 600
	}
	ignoreitem #findid 9
	goto _BItop
_BIexit:
	ignoreitem reset 9
return
;=========
;**
;* @name SaveSetting
;* @author Roadkill
;* @ver 1.0 9May04
;* @purpose saves all menu settings to a template name found in the combo box, or if
;*	"use above" selected, gets name from edit field above. Reloads templates/menu.
;*	Uses CEOFileSystem, credits him for those subs elsewhere.
;* @params
;* @returns
;* @notes
;* @status done but not tested
sub SaveSetting
	;first update all the status variables
	gosub BuildSearchString
	gosub GetPropFilter
	gosub GetSearchContainer indexcont ignoreworn #true
	menu get EUOComboBoxSave
	set !pointer #menures
	;if the combobox holds the first element ("use above"), query the edit field
	if !pointer = n/a || !pointer = 1
	{
		menu get EUOEditSave
		set %newtemplatename #menures
		;check for no name in #menures and kick out with error message
		if %newtemplatename = n/a
		{
		gosub menuline status 42 0 black red - - You can't save a new template without a name!
		return
		}
		;now we know a new template is being generated named #menures, increment %lasttemplate and update vars
		set %lasttemplate %lasttemplate + 1
		set %templatename . %lasttemplate #menures
		set !pointer %lasttemplate
	}
	gosub menuline status 42 0 black red - - Saving current settings in template named %templatename . !pointer
	;write allcheckboxes and vars to ceofilesystem
	for !i 1 %totalCheckBoxtypes
	{
		gosub putGlobalVar %globalvar UltraOrg template , !pointer Box , !i , checked
	}
	gosub putGlobalVar %globalvar UltraOrg template , !pointer templatename . !pointer
	gosub putGlobalVar %globalvar UltraOrg template , !pointer customchecked
	gosub putGlobalVar %globalvar UltraOrg template , !pointer editcustom
	gosub putGlobalVar %globalvar UltraOrg template , !pointer propfilterchecked
	gosub putGlobalVar %globalvar UltraOrg template , !pointer prop1
	gosub putGlobalVar %globalvar UltraOrg template , !pointer prop2
	gosub putGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxANDchecked
	gosub putGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxORchecked
	gosub putGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxAllchecked
	gosub putGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxSearchAllchecked
	gosub putGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxIgnoreWornchecked
	;all checkbox settings and templatename now written, reload with new templates
	gosub ReadInTemplateArray
	gosub ShowEUOMenu1
	gosub menuline status 42 0 black red - - Settings saved/reloaded as template named %templatename . !pointer
	menu combo select EUOComboBoxLoad !pointer
return
;=========
;**
;* @name LoadSetting
;* @author Roadkill
;* @ver 1.0 9May04
;* @purpose Reads template name from combobox and gets all menu settings from
;*	*ceofilesystem matching that name, then rewrites menu with those settings
;* @params
;* @returns
;* @notes  the initial menu writing should be done via this after init status read in!
;* @status done but not tested
sub LoadSetting
	menu get EUOComboBoxLoad
	;we must add 1 to the #menures,since the combobox was populated from #2 on...
	set !pointer #menures + 1
	;if there is nothing in the load combobox, msg so and return
	if #menures = n/a || #menures < 1
	{
		gosub menuline status 42 0 black red - - There is no template selected to load!
		return
	}
	gosub menuline status 42 0 black red - - Loading saved template settings named %templatename . !pointer
	;read in allcheckboxes and vars from ceofilesystem

[Duku]

	for !i 1 %totalCheckBoxtypes
	{
		set !gg Box , !i , checked
		gosub getGlobalVar %globalvar UltraOrg template , !pointer !gg nolock
	}
	gosub getGlobalVar %globalvar UltraOrg template , !pointer templatename . !pointer nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer customchecked nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer editcustom nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer propfilterchecked nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer prop1 nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer prop2 nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxANDchecked nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxORchecked nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxAllchecked nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxSearchAllchecked nolock
	gosub getGlobalVar %globalvar UltraOrg template , !pointer EUOCheckBoxIgnoreWornchecked nolock
	;all checkbox settings now loaded, write the menu (menu needs #false replaced with var still...)
	gosub ShowEUOMenu1 
	gosub menuline status 42 0 black red - - LOADED! template named %templatename . !pointer
	menu combo select EUOComboBoxLoad #menures
return
;===================
;**
;* @name GetItemType
;* @author Roadkill
;* @ver 1.0 16May04
;* @purpose reports an items type in a textfield and appends it in the custom edit field
;* @params 	
;* @returns
;* @notes 
;* @status 
sub GetItemType
	gosub menuline status 42 0 black red - - Drag the item whose type you want then$
	+ dont touch anything, you have 5 seconds
	wait 5s
	if POF_RWF_ZWF in %EditCustom
		set %EditCustom _ , #lliftedtype
	else
		set %EditCustom %EditCustom , _ , #lliftedtype
	gosub menuline LastType 366 224 btnFace red - - #lliftedtype	
	;menu delete EditCustom
	;menu Font BGColor white
	;menu Edit EditCustom 64 220 223 %EditCustom
	str lower %EditCustom
	menu set EditCustom #strres
	gosub menuline status 42 0 black red - - The item you dragged is type: #lliftedtype $
	+ and will be added to custom string. Hand edit if wrong.
return
;==========
;**
;* @name GetPropFilter
;* @author Roadkill
;* @ver 1.2 19Aug04 -added custom prop
;* @purpose reads the menu to get the propfilter info. If last selection
;*	custom is selected, reads saveeditfield for a custom prop string
;* @params 	
;* @returns #result is #true if props are checked (not used...)
;	%propfilterChecked #true/#false on whether propfilter is used at all
;	%propAndOR holds || or && on relationship between prop1/2
;	%prop1, %prop2, hold the propstring from dropdown OR customfields
;	%EvalProp1, %EvalProp2 holds all | >= | <=
;	%numProp1, %numProp2   holds the number to compare prop1 and prop2 against
;* @notes
;* @status tested
sub GetPropFilter
	set %propfilterChecked #false
	menu get propfilter
	if ! #menures
		return #false
	set %propfilterChecked #true
	menu get ComboBoxProp1
	;have to adjust by -1 since I made the proplists zero based :(
	set !adj #menures - 1
	set %prop1 %proplist . !adj
	menu get ComboBoxProp2
	set !adj #menures - 1
	set %prop2 %proplist . !adj
	;check for custom property string and read in from save edit field
	if custom in %prop1
	{
		menu get EuoEditCustomProp1
		set %prop1 #menures
	}
	if custom in %prop2
	{
		menu get EuoEditCustomProp2
		set %prop2 #menures
	}
	;check the and or boxes
	set %propAndOR n/a
	menu get EUOCheckBoxAND
	set %EUOCheckBoxANDchecked #menures
	if #menures
		set %propAndOR &&		
	menu get EUOCheckBoxOR
	set %EUOCheckBoxORchecked #menures
	if #menures
		set %propAndOR ||
	if %propAndOr = n/a
	{
		set %prop2 none
		set %propAndOr ||
	}
	;check the prop intensity comboboxes and edit fields
	;evalprop1/2 are 0 when blank, 1=all, 2= >=, 3= <=
	menu get ComboBoxEvalProp1
	set %EvalProp1 all
	if #menures > 1
	{
		set %EvalProp1 >=
		if #menures = 3
			set %EvalProp1 <=
		menu getnum EuoEditNumProp1
		set %numProp1 #menures
		;should add error checking here for no or bad number..bah..
	}
	menu get ComboBoxEvalProp2
	set %EvalProp2 all
	if #menures > 1
	{
		set %EvalProp2 >=
		if #menures = 3
			set %EvalProp2 <=
		menu getnum EuoEditNumProp2
		set %numProp2 #menures
		;should add error checking here for no or bad number..bah..
	}	
return #true
;=============
sub ExclusiveAndOr
	;memorize last known status for comparison
	if ! %exclusiveAndOrInit
	{
		set !oldANDchecked %1
		set !oldORchecked %2
	}
	set !andtoggled #false
	set !ortoggled #false
	menu get EUOCheckBoxAND
	set !ANDchecked #menures
	menu get EUOCheckBoxOR
	set !ORchecked #menures
	if !ANDchecked = ! !oldANDchecked
		set !andtoggled #true
	if !ORchecked = ! !oldORchecked
		set !ortoggled #true
	if !andtoggled && !ANDchecked
	{
		menu Font BGColor lime
		menu Check EUOCheckBoxOR 244 246 43 17 #false OR
		set !oldANDchecked #true
		set !oldORchecked #false
		set %EUOCheckBoxAndChecked #true
		set %EUOCheckBoxOrChecked #false
	}
	if !ortoggled && !ORchecked
	{
		menu Font BGColor teal
		menu Check EUOCheckBoxAND 200 246 43 17 #false AND
		set !oldANDchecked #false
		set !oldORchecked #true
		set %EUOCheckBoxAndChecked #false
		set %EUOCheckBoxOrChecked #true		
	}
	set %exclusiveAndOrInit #true
return
;==============
;**
;* @name ReadInPropArrays
;* @ver 1.2 12Aug04  added ---prop--- dividers, renumbered.
;* @author Roadkill
;* @purpose: set an array of props that can be used to build the combo box AND compare with
;	the actual #property, so they must be accurate wording
;* @status done. zero based?
sub ReadInPropArrays
;set %proplist0 none
;--stat props--
set %proplist0 ----stat.props---------
set %proplist1 strength , #spc , bonus
set %proplist2 intelligence , #spc , bonus
set %proplist3 dexterity , #spc , bonus
set %proplist4 Hit , #spc , Point , #spc , Increase 
set %proplist5 Mana , #spc , Increase 
set %proplist6 Stamina , #spc , Increase 
set %proplist7 Hit , #spc , Point , #spc , Regen 
set %proplist8 Mana , #spc , regeneration
set %proplist9 Stamina , #spc , regeneration 
;--armor/jewelry props
set %proplist10 ----armor/jewelry.props----
set %proplist11 Luck 
set %proplist12 Night , #spc , Sight 
set %proplist13 Faster , #spc , Casting 
set %proplist14 Faster , #spc , Cast , #spc , Recovery
set %proplist15 Lower , #spc , Mana , #spc , Cost 
set %proplist16 Lower , #spc , Reagent , #spc , Cost
set %proplist17 Self , #spc , Repair 
set %proplist18 Mage , #spc , Armor 
set %proplist19 Enhance , #spc , Potions 
set %proplist20 Durability , #spc , Increase 
set %proplist21 Reflect , #spc , Physical , #spc , Damage
set %proplist22 Physical , #spc , Resist 
set %proplist23 Fire , #spc , Resist 
set %proplist24 Cold , #spc , Resist 
set %proplist25 Poison , #spc , Resist 
set %proplist26 Energy , #spc , Resist 
set %proplist27 Lower , #spc , Requirements
;--weapon props--
set %proplist28 ----weapon.props---------
;-----there is a problem with this DI, the leading #spc nerfs it, read thread for 
;answer, from ximan I think...
set %proplist29 $Damage , #spc , Increase 
set %proplist30 Hit , #spc , Chance , #spc , Increase 
set %proplist31 Defense , #spc , Chance , #spc , Increase 
set %proplist32 Spell , #spc , Damage , #spc , Increase 
set %proplist33 Swing , #spc , Speed , #spc , Increase 
set %proplist34 Hit , #spc , Lower , #spc , Attack 
set %proplist35 Hit , #spc , Lower , #spc , Defense 
set %proplist36 Life , #spc , Leech 
set %proplist37 Mana , #spc , Leech 
set %proplist38 Stamina , #spc , Leech 
set %proplist39 Slayer
set %proplist40 Spell , #spc , Channeling
set %proplist41 Mage , #spc , Weapon 
set %proplist42 Use , #spc , Best , #spc , Weapon , #spc , Skill 
set %proplist43 Hit , #spc , Physical , #spc , Area 
set %proplist44 Hit , #spc , Fire , #spc , Area 
set %proplist45 Hit , #spc , Cold , #spc , Area 
set %proplist46 Hit , #spc , Poison , #spc , Area 
set %proplist47 Hit , #spc , Energy , #spc , Area 
set %proplist48 Hit , #spc , Harm 
set %proplist49 Hit , #spc , Fireball 
set %proplist50 Hit , #spc , Lightning 
set %proplist51 Hit , #spc , Dispel 
set %proplist52 Physical , #spc , Damage 
set %proplist53 Fire , #spc , Damage 
set %proplist54 Cold , #spc , Damage 
set %proplist55 Poison , #spc , Damage 
set %proplist56 Energy , #spc , Damage

[Duku]

;--skills props--
set %proplist57 ----skills.props--------
set %proplist58 Anatomy
set %proplist59 Animal , #spc , Lore
set %proplist60 Animal , #spc , Taming
set %proplist61 Archery
set %proplist62 Chivalry
set %proplist63 Discordance
set %proplist64 Evaluate , #spc , Intelligence
set %proplist65 Fencing
set %proplist66 Focus
set %proplist67 Healing
set %proplist68 Mace , #spc , Fighting
set %proplist69 Magery
set %proplist70 Meditation
set %proplist71 Musicianship
set %proplist72 Parrying
set %proplist73 Necromancy
set %proplist74 Peacemaking
set %proplist75 Provocation
set %proplist76 Resisting , #spc , Spells
set %proplist77 Spirit , #spc , Speak
set %proplist78 Stealth
set %proplist79 Stealing
set %proplist80 Swordsmanship
set %proplist81 Tactics
set %proplist82 Veterinary
set %proplist83 Wrestling
;--other props--
set %proplist84 ----other.props---------
set %proplist85  Rarity
set %proplist86  Insured
set %proplist87  Exceptional
set %proplist88 //use_custom.prop//

set %proplisttotal 88
;set the props for first menu draw
set %prop1 none
set %prop2 none
return
;/////Below subs excerpted/published from RKsubs.txt and other authors/////
;----
;* @name menuline
;* @author Roadkill
;* @ver 1.1 9May04
;* @purpose writes a menu line in lowercase, all menu functions included,
;*	changes bg and font before and after, message can be any length
;* @params 	%1 is the name of the text field, like 'status'
;*		%2 is the x menu-coord of the text field
;*		%3 is the y menu-coord of the text field
;*		%4 is the bgcolor, use - if no change
;* 		%5 is the font color, use - if no change
;* 		%6 is the exit bgcolor , use - if no change
;* 		%7 is the exit fontcolor , use - if no change
;* 		%8 and on are the message
;* @returns none
;* @notes be sure to change the field name and write position to your line info
;*	where it says:   menu text status 50 5 #strres    (status, 50, 5 may change)
;* @example: gosub menuline status 50 5 red black black lime need more bones #dot paused #dot
;*	or   gosub menuline status 50 5 - - - - need more bones
;* @status tested good
sub menuline
	if %4 <> -
		menu font bgcolor %4
	if %5 <> -
		menu font color %5
	menu delete %1
	set !_statusmsg %8
	if %0 < 9
		goto _statusLower
	for !_i 9 %0
	{
		set !_statusmsg !_statusmsg , #spc , % . !_i
	}
_statusLower:
	str lower !_statusmsg
	menu text %1 %2 %3 #strres
	if %6 <> -
		menu font bgcolor %6
	if %7 <> -
		menu font color %7
return
;============
;**
;* @name PopulateComboBox
;* @author Roadkill
;* @ver 1.1 12Aug04
;* @purpose builds the adds population in a combobox , in lowercase
;* @params %1 is the name of the combobox
;* 	%2 is the name of the array to use
;*	%3 is the start point in the array
;*	%4 is the last point in the array to use
;* @returns
;* @notes the combo box itself must first be created with its position
;* @example menu Combo Create ComboBoxProp1 70 244 129
;*	gosub PopulateComboBox ComboBoxProp1 proplist 0 %proplisttotal
;* @status done
sub PopulateComboBox
	for !_i %3 %4
	{
		set !gg %2 , !_i
		set !ggg % . !gg
		str lower !ggg
		;menu Combo Add %1 % . !gg
		menu Combo Add %1 #strres
	}
return
;========================
;**
;* Name: FindPaperdollnMainpackXY
;* Finds the XY for your paperdoll AND mainpack for dropping WITHOUT causing subpacks to close
;*	if paperdoll not open,it will open it.  Requires known mainpackID, can be gotten with
;*	my FindMainPack
;* @ver 1.1 14Jun04
;* @author  Roadkill
;* @purpose Finds the XY for your paperdoll AND mainpack for dropping WITHOUT causing subpacks to close
;* @param   %1  ID of your mainpack (backpack)     req use my FindMainPack to get this
;*          %2  @return varname for paperdollx     req
;*          %3  @return varname for paperdolly     req
;*          %4  @return varname for mainpackx      req
;*          %5  @return varname for mainpacky      req
;* @return  the varnames passed in as %2-%5 are loaded and returned
;* @example call rksubs.txt FindPaperdollnMainpackXY %mainpack paperdollx paperdolly mainpackx mainpacky
;* @status: tested
Sub FindPaperdollnMainpackXY
_FPMXY:
	finditem %1
	if #findkind = -1
	{
		event macro 8 1
		wait 1s
		display ok please move your paperdoll where you want it, you have 4 seconds
		wait 4s
		goto _FPMXY
	}
	set % . %2 #findx
	set % . %3 #findy
	set % . %4 #findx + 140
	set % . %5 #findy + 220
return
;==================
;**
;* @name WriteFastDOSArray
;* @ver 1.2 11May04
;* @author  Roadkill, credit to jjarmis for figuring out how to do CR/LF in string!
;* @purpose write the values from an array into multiline file
;*     	using single DOS write for speed instead of slow loop.
;* @params %1 the varname of array holding data to write, 1line/element
;*   	%2 req holds the starting record to write
;*   	%3 req holds the final record to write
;*   	%4 req holds the filename to write too.
;*	%5 opt holds the buffersize to stay below (default 2000, limit is 2010)
;* @returns
;* @example call rksubs.txt WriteFastDOSarray writearray 1 30 testfile.txt
;* @status
sub WriteFastDOSArray
	set !lpc #lpc
	set #lpc 1000
	set !doslengthlimit %5
	if %0 < 5 || %5 = n/a
		set !doslengthlimit 2000
	;get comspec for OS
   	str left #osver 1
   	set !filecmd cmd.exe
   	if #strres = 1
   		set !filecmd command.com
   	;test for allow exec
   	if exec notin #opts
   	{
   		display OK You MUST have "allow Execute" enabled to write a file,$
   		+ and right now you DON'T! Fix it...you have 10 seconds.
   		wait 10s
   	}
   	set !writestring %1 , %2
   	set !writestring % . !writestring
   	set !wstart %2 + 1
   	set !crlf #spc , >> , #spc , %4 , #spc , && , #spc , echo , #spc
   	for !z !wstart %3
   	{
   		set !element %1 , !z
      		set !element % . !element
      		str len !element
      		set !elementlen #strres
      		str len !writestring
      		set !writestringlen #strres
      		if !writestringlen + !elementlen > !doslengthlimit
      		{
      	   		execute !filecmd /c echo !writestring >> %4
      	   		set !writestring #smc , ---bufferdump---
      		}
      		set !writestring !writestring , !crlf , !element
   	}
     	execute !filecmd /c echo !writestring >> %4
	set #lpc !lpc
return
;===========
;**
;* @name getPropNum
;* @ver 1.0
;* @author Kal-In-Ex (parser engine idea, this rewrite by RK to meet needs)
;* @purpose looks for %1 propstring in #property (already exists)
;* @params %1= the propstring (substring) to look for in #property
;* 	%2= the varname to return the propstring intensity in
;* @returns #result #false if the propstring notin #property (shouldn't happen..)
;*	#result #true if the propstring is in #property but no intensity ("magearmor")
;*	#result holds the intensity (same as @%2) if it exists, so you can test #result
;*	@%2 holds the intensity, or n/a if no intensity
;* @example gosub getPropNum slayer numprop <=#result would be #true, %numprop = n/a
sub getPropNum ;%prop1 propnum
	set % . %2 n/a
	str pos #property %1
	if #strres = 0
		return #false
	set !pos #strres    ;holds the pos of the propstring start in #property
	str len %1          ;strres now holds the length of the propstring
	set !pos !pos + #strres   ;!pos now holds the pos of the END of the propstring in #property
	set !propnum        ;!propnum cleared
	for !_ 1 1
	{
		str mid #property !pos 1  ;do until; char after propstring now extracted
		if #strres notin $/:%+ , #spc   ;if it's not an end delimiter, append to !propnum
			set !propnum !propnum , #strres
		if #strres notin $/     ;if it's notin $/, continue the loop on next char
		{
			set !_ 0
			set !pos !pos + 1
		}
	}
	str len !propnum
	if #strres = 0
		return #true    ;the prop exists but no intensity
	set % . %2 !propnum
return !propnum
;===========
;**
;* @name openVendors
;* @ver 1.0
;* @author rk
;* @purpose
;* @params %1=
;* 	%2=
;* @returns
;* @example
sub openVendors
_ovfindvendors:
	findItem hs_is G


return

; ===================================================================
; Name: MoveItemToPos
;ver 1.4 17mar04 by Roadkill, orig ideas/code by Scriptfellow
;	added wait 3 before click
;	-added error flag into #result/return
; Purpose: Moves an item to a specific screen position
; 	Mod: watches for full containers and sets an error flag to abort out of loops
; %1 = item id
; %2 = screen x coord
; %3 = screen y coord
; %4 = amount (if 0 it will move the whole stack)
sub MoveItemToPos
	set %_item %1
	set %_x %2
	set %_y %3
	set %_amount %4
	set %error #false
	finditem %_item
	set %dontwait 0
	if #FINDID = #LLIFTEDID
		set %dontwait 1
	set %oldliftedid #LLIFTEDID
	event drag #FINDID
	wait 5
	if #LLIFTEDID = %oldliftedid
	{
		if #FINDSTACK > 1
		{
			if %dontwait = 1
				goto enteramount
			set %start #SCNT + 2
waitfordrag:
			if #SCNT > %start
				goto enteramount
			if #CONTname <> stack_gump
				goto waitfordrag
enteramount:
		WAIT 3
			if %_amount = 0
				msg $
			if %_amount > 0
				msg %_amount $
		}
	}
	if #LLIFTEDID <> %oldliftedid
		wait %delay
	else
		wait 3
	click %_x %_y p
	wait %delay
	if that_container_cannot IN #sysmsg
	{
		set %error #true
		set %errormessage Sub_MoveItemToPos/container_is_full
		return %errormessage
	}
return #true

[Duku]

;===========================================================
; Name: sysVarWait
; Author: Smertrios
; Parameters: %1 = name of the system variable without the preceeding '#'
;             %2 = some operator like <, >, =, in, notIn
;             %3 = a value to compare with EasyUO system variable %1
;             %4 = timeout value equal to %4 * .1 seconds so 10 = 1s
; Purpose: compares a system variable to some other value returning
;          when the comparison evaluates as true
; Return: %return (1 if ok or 0 if timedout), also #result
; example call rksubs.txt sysVarWait #contname = generic_gump 30
;-----------------------------------------------------------
sub sysVarWait
	set %timeOut #sCnt2 + %4
	set %return 1
svw1:
	if # . %1 %2 %3
		return %return
	if #sCnt2 < %timeOut
		goto svw1
	set %return 0
return %return
;======================
;================================== 
; Script Name:  CEO's * variable management subs (pseudo filesystem) 
; Author: CEO 
; Version: 1.0 
; Client Tested with: 4.0.1b 
; EUO version tested with: 1_41_103 
; Shard OSI / FS: OSI 
; Revision Date: 040219 
; Public Release: 040219 
; Globals Used: User specified (2 total) 
; Purpose: Allows you to use a * variable as a pseudo-filesystem 
;======================================= 
; CEO's global variable management subs: 
;      getGlobalVar  . putGlobalVar  . delGlobalVar 
;======================================= 
Sub getGlobalVar 
;ver 1.0 posted 19Feb04 by CEO 
;purpose: Allows you to store multiple variables in one global variable unique to 
;             each player and script. getGlobaVar retrieves a value from a global variable. 
;@returns: #result = #false if variable not found, #true if found 
;            % . %3 contains variable value 
;%1 is the global/persistant variable to use ( %1 + 1 is used for locking) 
;%2 is the script identifer or pseudo filename 
;%3 is #charid or pseudo filename 
;%4 is the variable to search for and return in %. %3  
;%5 is for lock control. By default getGlobalVar uses a lock to return a value. In some cases you may want to 
;       retrieve a variable (mostly for speed) without needing a lock as long as you are aware of 
;      any potentional conflicts, that very rarely may occur. Set this param to NOLOCK to access 
 ;     global storage without a lock. 
;sample usage: 
;               gosub getGlobalVar 50 MyScript #charid backpackid 
; Using global var *50 finds the variable labeled MyScript#charidbackpackid and returns it in %backpackid 
; 
;               gosub getGlobalVar 50 MyScript #charid clothstat NOLOCK 
; Using global var *50 find the variable labeled MyScript#charidclothstat and returns it in %clothstat without using a lock 
; Warning: do not use *1000. * %1 + 1 is used for locking and there is no *1001! 
nameSpace push 
nameSpace local #systime , _ , %2 , _ , %3 , _ , %4 , _ , GET 
set !lpc #lpc 
set #lpc 1000 
set !lock %1 + 1 
if ( %0 = 5 ) && ( %5 = NOLOCK ) 
   goto getGlobalVar_skiplock 
set !lockcount 0 
getGlobalVar_waitforlock: 
if * . !lock <> N/A && * . !lock <> #nsname 
{ 
   wait 1 4 
   set !lockcount !lockcount + 1 
   if !lockcount < 10 
      goto getGlobalVar_waitforlock 
   if * . !lock <> N/A 
   { 
      set !currentlock * . !lock 
      if !currentlock = N/A 
         goto getGlobalVar_waitforlock 
      str pos !currentlock _ 
      set !strres #strres - 1 
      str left !currentlock !strres 
      set !systime #systime - #strres 
      if !systime < 10000 ; if over 10 seconds assume a broken lock and take it 
      { 
         set !lockcount 0 
         goto getGlobalVar_waitforlock 
      } 
   } 
} 
set * . !lock #nsname 
wait 3 2 
if  * . !lock <> #nsname 
{ 
   set !lockcount 0 
   goto getGlobalVar_waitforlock 
} 
getGlobalVar_skiplock: 
set !global * . %1 
set !varName %2 , ^ , %3 , ^ , %4 , | 
str pos !global !varName 
set #result #strres <> 0 
if #result 
{ 
   set !varNamePos #strres 
   str len !varName 
   set !delString !varNamePos + #strres - 1 
   str del !global 1 !delString 
   set !global #strres 
   str pos !global | 
   set !varNamePos #strres - 1 
   str left !global !varNamePos 
   set % . %4 #strres 
} 
if ( %0 < 5 || %5 <> NOLOCK ) && * . !lock = #nsname 
   set * . !lock N/A 
set #lpc !lpc 
nameSpace Clear 
nameSpace Pop 
return #result 
;===========================
Sub putGlobalVar 
;ver 1.0 posted 19Feb04 by CEO 
;purpose: Allows you to store multiple variables in one global variable unique to 
;             each player and script. putGlobaVar stores a value into a global variable. 

;@returns: #result = #false if variable not found, #true if found 
;            % . %3 contains variable 
;%1 is the global/persistant variable to use 
;%2 is the script identifer or pseudo filename 
;%3 #charid or other identifier 
;%4 is the variable name of the variable to save into the* variable identified in %1 
;sample usage: 
;               gosub putGlovalVar 50 MyScript #chardid backpackid 
; Using global var *50 stores/updates the variable labeled MyScript#charidbackpackid  with %backpackid 
; Warning: do not use *1000. * %1 + 1 is used for locking and there is no *1001! 
nameSpace push 
nameSpace local #systime , _ , %2 , _ , %3 , _ , %4 , _  , PUT 
set !lpc #lpc 
set #lpc 1000 
set !lock %1 + 1 
set !lockcount 0 
putGlobalVar_waitforlock: 
if * . !lock <> N/A && * . !lock <> #nsname 
{ 
   wait 1 4 
   set !lockcount !lockcount + 1 
   if !lockcount < 10 
      goto putGlobalVar_waitforlock 
   if * . !lock <> N/A 
   { 
      set !currentlock * . !lock 
      if !currentlock = N/A 
         goto putGlobalVar_waitforlock 
      str pos !currentlock _ 
      set !strres #strres - 1 
      str left !currentlock !strres 
      set !systime #systime - #strres 
      if !systime < 10000 ; if over 10 seconds assume a hung lock and take it 
      { 
         set !lockcount 0 
         goto putGlobalVar_waitforlock 
      } 
   } 
} 
set * . !lock #nsname 
wait 4 
set !global * . %1 
set !varName %2 , ^ , %3 , ^ , %4 , | 
str pos !global !varName 
if #strres = 0 
{ 
   if  * . !lock <> #nsname 
   { 
      set !lockcount 0 
      goto putGlobalVar_waitforlock 
   } 
   if  |CEO*FILESYSTEM| notin !global 
      set !global |CEO*FILESYSTEM| 
   set * . %1 !global , !varName , % . %4 , | 
   set * . !lock N/A 
   set #lpc !lpc 
   nameSpace clear 
   nameSpace pop 
   return #true 
} 
set !varNamePos #strres 
str len !varName 
set !splitString !varNamePos + #strres - 1 
str left !global !splitstring 
set !globalPart1 #strres 
str del !global 1 !splitString 
set !global #strres 
str len !global 
set !globalLen #strres 
str pos !global | 
set !splitString !globalLen - #strres + 1 
str right !global !splitstring 
set !global #strres 
if  * . !lock <> #nsname 
{ 
   set !lockcount 0 
   goto putGlobalVar_waitforlock 
} 
set * . %1 !globalPart1 , % . %4 , !global 
set * . !lock N/A 
set #lpc !lpc 
nameSpace clear 
nameSpace pop 
return #true 
;=====end of code=========

Incollalo tutto senza modificare nulla

[fuser]

grazie anche se mi piacerebbe una cosa molto più easy easy, io dovrei spostare lingotti, sabbia, pietre , minerali e gemme non mi serve la lista di tutti gli item del gioco e tralaltro non ci sono quelle che servono a me, accetto ancora altri script, rpeto a me basta unos cirpt che faccia un target di dove si trova la roba e un target di dove metterla.

[Duku]

Guarda che con 3 click puoi spostare tutto, puoi personalizzarlo, le POF mica ci sono nella lista -.-

[antonio.gl]

Dovrebbe fare al caso tuo:

;==================================
; Script Name: sposta_oggetti.txt
; Author: antonio.gl
; Version: 1
; Client Tested with: 6.0.5
; EUO version tested with: build 132
; Shard OSI / FS: FS
; Revision Date: 25Mag08
; Purpose: sposta qualsiasi oggetto da un contenitore a un altro
;==================================
;Istruzioni: premere play :D
set %pausa 8
;########NON TOCCARE NIENTE QUI SOTTO###############à
event sysmessage Seleziona un oggetto del tipo che vuoi spostare.
set #targcurs 1
while #targcurs = 1
  wait 1
finditem #ltargetid
set %type #findtype
event sysmessage Seleziona il contenitore d'origine.
set #targcurs 1
while #targcurs = 1
  wait 1
set %from #ltargetid
event sysmessage Seleziona il contenitore di destinazione.
set #targcurs 1
while #targcurs = 1
  wait 1
set %to #ltargetid
finditem %type C_ , %from
event sysmessage Spostamento di , #spc , #findcnt , #spc , oggetti in corso...
for %i 0 #findcnt
{
  exevent dropc %to
  set #findindex %i
  exevent drag #findid #findstack
  wait %pausa
  exevent dropc %to
  wait %pausa
}
event sysmessage Operazione Terminata.
stop