[EASYUO] Aegis' Uber Tamer

[Aegis]

Ok, dato che me l'han chiesto in tanti, anche se ormai nn gioco più a UO, ho tentato di sistemare il problema dei Paragon ( oltre a un altro piccolo bug del quale non mi ero accorto).

Non ho accesso all'ftp dello script, quindi posto la sub da cambiare...sostituite la vecchia con la nuova.

ps: NON l'ho mai testata, non ho nemmeno UO installato, e l'ho scritta in 10 minuti stamattina, se funziona tutto provvederò ad aggiornare il link allo script.

sub TameControl
set %MobToTame %1
event property %MobToTame
if tame in #PROPERTY
    {
    ignoreitem %MobToTame
    event ExMsg #CHARID 3 50  <Ignoring Target>
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }
finditem %MobToTame G_
if #FINDCOL = 1281
    {
    event ExMsg #CHARID 3 50  <Paragon Found: Proceeding to kill>
    gosub KillMob %MobToTame
    return
    }

menu delete Rail
menu text Rail 160 80 Paused
gosub CommandRail pause
event ExMsg %MobToTame 3 50  Tame me! Tame me!
set %TempFollowers #FOLLOWERS
set %tamTimer #SCNT

tameloop:
finditem %MobToTame G_
event property %MobToTame
if ( tame in #PROPERTY ) && ( %TempFollowers = #FOLLOWERS )
    {
    ignoreitem %MobToTame
    event ExMsg #CHARID 3 50  <Tamed by someone else: Ignoring Target>
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }


if ( get_there in #SYSMSG ) || ( #SCNT > %tamTimer + 20 ) || ( #FINDKIND = -1 )
    {
    event ExMsg #CHARID 3 50  <Ignoring Target>
    ignoreitem %MobToTame
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }
if #FINDDIST > 2
    {
    event pathfind #FINDX #FINDY #FINDZ
    wait 1s
    goto tameloop
    }

set %tamTimer #SCNT
event macro 13 35
target 2s
set #lTargetID %MobToTame
set #lTargetKind 1
event Macro 22

if %TempFollowers <> #FOLLOWERS
{
    gosub KillMob %MobToTame
    menu delete Tamed
    set %Tamed %Tamed + 1
    menu text Tamed 160 40 %Tamed
    return
}

goto tameloop
return

[bubbaverde]

provato ora i para li killa

grazie del fix

[camasutra]

Qualcuno sa perchè quando provo a fare una rail mi escono tutte finestre di windows in loop e nn scrive nulla?

[Giako]

ciao aegis


mi chiedevo se per favore potevi fare una versione del tuo script senza rail e senza il menu di config, cosi da andare direttamente al punto della finestra con gain ignored ecc

e per settare la config farlo direttamente nel file

e se potresti togliere anche summonelemental e kill con arma e anche cure self magari lascia solo gheal

chiedo troppo lo so
diventerebbe un semiautomatico senza il return back, andare in giro e appena vede un animale della lista parte a tamarlo

ci vorrebbe anche un sistema di sicurezza per disattivare il pathfinding senno si schiatta se si viene attaccati

thx in anticipo

[Drael]

se volete fare in modo che il pg spammi Guards ogni due o tre secondi, perchè non gli affiancate uno script molto semplice come questo?

msg Guards $ 
Wait 3s

lo fate partire insieme all'Aegis e non avete problemi.

Per Giako, per sistema di sicurezza per togliere il pathfind cosa intendi? tipo premi un tasto e si disattiva il pathfind? per evitare tipo PK a felucca o mostri?

[Giako]

un tasto o in automatico
per fermare la macro senno non si puo' scappare

sto studiando gli script, almeno ci sto provando....

cmq
meglio questa per le guardie

if #enemyid notin N/A
{
msg guards $
Wait 1s
}


o stop invece di msg guard $ per fermare la macro (mi sono dato la soluzione da solo)
forse e meglio avere anche un tasto

[Giako]

ho fatto una specie di collage di vari script (vedi altro post fatto da me)
ma non mi soddisfa

aegis e il migliore

[commander]

dovrei tamare i ridgeback pero nella stessa zona spawnano troppi dire wolf che mi seccano...a sto punto mi e venuto in mente se si puo fare una modifica allo script in cui mi porto un pet dietro che uccide sia animale tamati sia bestie che mi attaccano (per questo credo sia sufficiente tenere il pet in all guard)

thx in anticipo

[Ven88]

http://www.webalice.it/baracaia.robe...Uber_Tamer.txt

emh non per fare il guasta feste ma lo script è scritto male non si puo' copiare sorry


(l'altro che avevo mi si è impallato non conosce piu' il mio tamer. Mi da n|a e quando tama un pet cerca di ritamarlo in loop )

[zem90]

il migliore scrip per taming

[Drael]

Ecco lo script completo (con anche il fix dei paragon)

;===Aegis' Uber Tamer ============
;===Ver 2.0=======================
;===Author: Aegis=================
;===30/01/06======================
;================================
set %killMode 2
set %HealMethod 6
chooseskill anim
set %TameBase #SKILL
set *501 N/A
set %Tamed 0
set %Ignored 0
gosub CreateMenu
set %TempFollowers #FOLLOWERS
event property #CHARID
if [ notin #property
Display Ok Warning: Aegis'tamer might not work properly if you're not in a Guild.
gosub CommandRail start
set %tamTimer #SCNT
;============================================
;=====Loop Principale=========================
;============================================
MainTameLoop:
finditem *AegisTamerPlist G_ , %MaxFindRange
if #FINDKIND <> -1
    {
    set %charX #CHARPOSX
    set %charY #CHARPOSY
    set %charZ #CHARPOSZ
    gosub TameControl #FINDID
    if %pback = -1
        {
        set %tamTimer #SCNT
        while ( #SCNT < %tamTimer + 20 ) && ( ( %charX <> #CHARPOSX ) || ( %charY <> #CHARPOSY ) )
            {
            event pathfind %charX %charY %charZ
            event ExMsg #CHARID 3 50  <Pathfinding back to StandBy>
            wait 2s
            }
        event ExMsg #CHARID 3 50  <Resuming...>
        }
    wait 1s
    chooseskill anim
    if %TameBase <> #SKILL 2
        menu delete gained
        menu text gained 160 20 ( #SKILL - %TameBase )

    menu delete Rail
    menu text Rail 160 80 Running
    gosub CommandRail resume
    }

if *500 = done
    {
    wait 3s
    gosub CommandRail start
    }

if %HealMethod <> 6 && #HITS < #MAXHITS
    gosub HealSelf %HealMethod

wait 1
goto MainTameLoop

;************************************************
;==%%%%========###############============%%%%===
;===========&&&==#SUBROUTINES#==&&&==============
;==%%%%========###############============%%%%===
;************************************************
sub TameControl
set %MobToTame %1
event property %MobToTame
if tame in #PROPERTY
    {
    ignoreitem %MobToTame
    event ExMsg #CHARID 3 50  <Ignoring Target>
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }
finditem %MobToTame G_
if #FINDCOL = 1281
    {
    event ExMsg #CHARID 3 50  <Paragon Found: Proceeding to kill>
    gosub KillMob %MobToTame
    return
    }

menu delete Rail
menu text Rail 160 80 Paused
gosub CommandRail pause
event ExMsg %MobToTame 3 50  Tame me! Tame me!
set %TempFollowers #FOLLOWERS
set %tamTimer #SCNT

tameloop:
finditem %MobToTame G_
event property %MobToTame
if ( tame in #PROPERTY ) && ( %TempFollowers = #FOLLOWERS )
    {
    ignoreitem %MobToTame
    event ExMsg #CHARID 3 50  <Tamed by someone else: Ignoring Target>
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }


if ( get_there in #SYSMSG ) || ( #SCNT > %tamTimer + 20 ) || ( #FINDKIND = -1 )
    {
    event ExMsg #CHARID 3 50  <Ignoring Target>
    ignoreitem %MobToTame
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }
if #FINDDIST > 2
    {
    event pathfind #FINDX #FINDY #FINDZ
    wait 1s
    goto tameloop
    }

set %tamTimer #SCNT
event macro 13 35
target 2s
set #lTargetID %MobToTame
set #lTargetKind 1
event Macro 22

if %TempFollowers <> #FOLLOWERS
{
    gosub KillMob %MobToTame
    menu delete Tamed
    set %Tamed %Tamed + 1
    menu text Tamed 160 40 %Tamed
    return
}

goto tameloop
return
;==============%1 il Target Da Segare==============
sub KillMob
msg all guard$
if %killMode = 3 2
gosub KIllWMount %1
return

if %killMode = 2 2
gosub SummonEarth %1
return

msg all guard$
wait 1s
repeat
set #LTargetID %1
event macro 27
wait 1s
finditem %1
until #FINDKIND = -1

return
;===Sega con il mount==============================
;====%1 Il Target da segare=========================
sub KIllWMount
repeat
set #lObjectID #CHARID
event macro 17
wait 5
finditem %MyPetID
until #FINDKIND <> -1

WaitDeathMo:
msg all kill $
target 3s
set #lTargetID %1
set #lTargetKind 1
event Macro 22
wait 3s
finditem %1 G_15
if #FINDKIND <> -1
goto WaitDeathMo

monta:
msg all come$
set #lObjectID %MyPetID
event macro 17
wait 5
finditem %MyPetID
if #FINDKIND <> -1
goto monta

return
;===========SummonEarth==========================
;====%1 Il Target da segare=========================
sub SummonEarth
set %TempFollowers #FOLLOWERS
repeat
   event macro 15 61
   wait 5s
until %TempFollowers <> #FOLLOWERS
msg all guard $

repeat
   msg all kill $
   target 3s
   set #lTargetID %1
   set #lTargetKind 1
   event Macro 22
   wait 1s
finditem %1 G_15
until #FINDKIND = -1


msg An Earth Elemental Release$
msg An Earth Elemental Release$
return
;====================================================
;=%1 HealType
;==1: Heal 2: Gheal 3:CloseWounds 4:Bandages
sub HealSelf

while #HITS < #MAXHITS && %1 = 1
{
    event macro 15 3
    target 5s
    event macro 23
    wait 1s
}
while #HITS < #MAXHITS && %1 = 2
{
    event macro 15 28
    target 5s
    event macro 23
    wait 1s
}
while #HITS < #MAXHITS && %1 = 3
{
    event macro 15 202
    target 5s
    event macro 23
    wait 1s
}

while #HITS < #MAXHITS && %1 = 4
{
    findItem ZLF C_ , #BACKPACKID
    if #FINDKIND = -1 2
       Display Ok No Bandages Found!!! $ Script Halted.
       halt
    set #lObjectID #FINDID
    event Macro 17
    target 5s
    event macro 23
    set %bandTime ( 220 - #DEX )
    wait %bandTime
    wait 1
}

while #HITS < #MAXHITS && %1 = 5
{
    event macro 13 32
    wait 2s
}


return
;=============================

mi tocca tagliare lo script...unite la parte del prox post

[Drael]

sub CreateMenu
menu clear
set #MenuButton N/A
menu Font BGColor black
menu font color red
menu window color black
menu Window Title Aegis Uber Tamer Configuration
menu Window Size 260 260
menu Font Size 8

if *AegisTamerPlist = N/A 2
    {
    menu text hi 20 20 WELCOME To AEGIS' UBER TAMER $____ver 2.0____ $ $ - Checking peristent variables... $ - done$ 501 : *501 $ 502 : *502 $ 503 : *503 $ 504 : *504 $ AegisTamerPlist : *AegisTamerPlist $ $First run WARNING: $ This Script uses 5 persistent variables, $ which are stored permanently in your REGISTRY $under HKEY_CURRENT_USER\Software\EasyUO$ Used vars are listed over here $ THIS WINDOW WILL CLOSE IN 30sec
    menu Show 500 40
    wait 30s
    }
if *AegisTamerPlist <> N/A
    {
    menu text hi 20 20 WELCOME BACK -|- #CHARNAME -|- $ To AEGIS' UBER TAMER $____ver 2.0____
    menu Show 500 40
    wait 5s
    }
menu delete hi
menu Button AddTameButton 0 50 140 30 Add animal to ToTame list
menu Button ResetTameButton 0 80 140 20 Reset ToTame list
menu Button ConfirmButton 60 240 140 20 Submit And Start
menu text ListLabel 150 50 Current ToTame list:
menu text ListTypes 150 70 *AegisTamerPlist

menu text CheckKillMLabel 0 110 Select the Kill Mode:
menu combo create KillModeCombo 2 125 95
menu combo add KillModeCombo Weapon
menu combo add KillModeCombo Earth Elemental
menu combo add KillModeCombo Mounted Pet

menu Button FindMountButton 190 120 60 30 Get Pet ID

menu text EdtLabel 0 160 RailFile Name:
menu Edit RailNameEdit 0 175 220 Change , #spc , me!
menu Button UpdateRailButton 220 175 40 23 Submit
menu text Edt2Label 0 200 Current RailFile Name:  *502


menu text HealModeLabel 0 5 Select the Heal Method:
menu combo create HealModeCombo 2 20 130
menu combo add HealModeCombo Magery: Heal
menu combo add HealModeCombo Magery: Greater Heal
menu combo add HealModeCombo Chivalry: Close Wounds
menu combo add HealModeCombo Skill Healing: Bandages
menu combo add HealModeCombo Skill Spirit Speak
menu combo add HealModeCombo -----No Healing-----
menu combo SELECT HealModeCombo 6

menu text FindDistLabel 105 110 Max Find range:
menu combo create FindDistCombo 105 125 70
for %ind 1 25
menu combo add FindDistCombo %ind , #spc , tiles
menu combo SELECT FindDistCombo 13

menu Check PBackCheck 150 10 90 40 #false PathFind back after tame



rloop:
if #MenuButton = ConfirmButton
    {
     menu get KillModeCombo
     set %killMode #menures
     menu get HealModeCombo
     set %HealMethod #menures
     menu get FindDistCombo
     set %MaxFindRange #menures
     menu get PBackCheck
     set %pback #menures
     menu clear

     menu Font BGColor black
     menu font color red
     menu window color black
     menu text AlertRailLabel 20 20 If you wish to use an external rail $ script (like CEORailRunner),$ start it BEFORE clicking this $ button.
     menu Button ConfirmButton 50 100 180 40 Start Aegis' Uber Tamer
     set #MenuButton N/A

     while #MenuButton = N/A
     {
         wait 1s
         event ExMsg #CHARID 3 50 Waiting...
     }
     menu delete AlertRailLabel
     menu delete ConfirmButton
     menu text SkillLabel 20 20 Total Gained:
     menu text KilledLabel 20 40 Total Tamed and Killed:
     menu text IgnoredLabel 20 60 Total Ignored:
     menu text RailLabel 20 80 Rail Status:
     gosub CommandRail start


     return

    }

if #MenuButton = UpdateRailButton
    {
    menu get RailNameEdit
    wait 1s
    set %RfileName #menures
    set *502 #menures
    menu delete Edt2Label
    menu text Edt2Label 0 200 Current RailFile Name:  *502
    set #MenuButton N/A
    }
if #MenuButton = FindMountButton
    {
    set #targcurs 1
    while #targcurs = 1
        {
        event ExMsg #CHARID 3 50 Waiting...
        wait 1s
        }
    set %MyPetID #ltargetid
    event ExMsg #CHARID 3 50 Ok
    set #MenuButton N/A
    }
if #MenuButton = ResetTameButton
    {
    set *AegisTamerPlist _
    set #MenuButton N/A
    menu delete ListTypes
    menu text ListTypes 150 70 *AegisTamerPlist
    }
if #MenuButton = AddTameButton
    {
    set #targcurs 1
    while #targcurs = 1
        {
        event ExMsg #CHARID 3 50 Waiting...
        wait 1s
        }
    Finditem #ltargetid
    if #FINDTYPE in *AegisTamerPlist
    event ExMsg #CHARID 3 50 That is already in your Tame List!!
    if #FINDTYPE notin *AegisTamerPlist
        {
        set *AegisTamerPlist *AegisTamerPlist , _ , #FINDTYPE
        event ExMsg #CHARID 3 50 Target added.
        menu delete ListTypes
        menu text ListTypes 150 70 *AegisTamerPlist
        }
    set #MenuButton N/A
    }

goto rloop
return
;========Comanda la rail tramite il %1=====================
;   *501 : User Control: Used to control rail movement through an external program.
;            Values:
;                  start- Start the rail program
;                  pause - pause rail program
;                  resume - resume rail program
;                  stop - stop rail program

sub CommandRail
set *502 %RfileName
set *503 -1
set *504 run
set *501 %1
return

[noello]

chiedo se possibile mettere un check sui pet gia tamati, visto che con questo script è molto facile far andare via una persona, basta prendere un pet tamato e metterglielo accanto, e quest'ultimo proverà a tamarlo all'infinito, grazie..

[Aegis]

c'è già il check :\

set %MobToTame %1
event property %MobToTame
if tame in #PROPERTY
    {
    ignoreitem %MobToTame
    event ExMsg #CHARID 3 50  <Ignoring Target>
    set %Ignored %Ignored + 1
    menu delete Ignored
    menu text Ignored 160 60 %Ignored
    return
    }

[noello]

e ma qualcosa non va mi sembra abbastanza pesante com bug, io nn tamo away, o meglio, il pc è acceso a tamare e io guardo la tv se vuoi ma controllo lo schermo, e.. ti faccio un esempio:
tamo bull, arriva uno con bull gia tamato al seguito, appena lo vedo mi ci si incolla il pg, e questo col suo bel bull, puo' portarmi dove gli pare, anche in mezzo ai mostri, che tanto io cerco continuamente di tamarglielo spammando a nn finire "the creature is already tamed"

nn so..

edito per dire che il problema si verificava con la versione dello script nel primo topic, sto provando questa sopra, mi pare andare bene nn saprei pero' senza provare, bel lavoro