[EasyUO] macrare veterinary

[dopulus]

per macrarla dovete essere gildati ... provatelo e' figo

;================================== 
;================================== 
; Script Name:   Panther's Vet Trainer 
; Author:  Panther_sn 
; Version: 1.3 
; Client Tested with:  5.0.0b 
; EUO version tested with: euo 1.5 tv57  & euo 1.42.00B3 
; Shard OSI / FS: Only Tested On FS 
; Revision Date: 30 September 2005 
; Public Release: 1 May 2005 
; Global Variables Used: N/A 
; Purpose: To Train Vet On Freeshards 
;================================== 
; SETUP: 
;GET 2 ANIMALS (i RECCOMEND HORSES) AND STAND IN 1 SPOT 
;MAKE SURE YOU HAVE PLENTY OF BANDIES IN YOUR PACK 
; START SCRIPT 
; DO NOT RUN THIS SCRIPT UNATTENDED YOU NEVER KNOW WHAT WILL HAPPEN 
;============================================== 
 ; I Recommend being Guilded as Otherwise u will end up a criminal 
; U can change the %waitbetweenheals if you find the time between heals too long or slow 
; if you aren't guilded and press yes to being guilded be aware you will end up as a criminal. 
; I ACCEPT NO RESPONSIBILITY FOR LOST PETS 
;ENJOY 
set %waitbetweenheals 2s 
set %bandies ZLF 
;================= 
;DON'T EDIT BELOW HERE 
;=================== 
Display yesno Are You Guilded? 
if #dispres = no 
  { 
  display OK Get Guilded And Restart 
  Halt 
  } 
display yesno Do You Have 2 Pets? 
if #dispres = no 
  { 
  display OK Get 2 Pets and Restart 
  halt 
  } 
gosub menu 
display ok TARGET FIRST PET 
set #targcurs 1 
wait 5 
waitl1: 
if #targcurs = 1 
goto waitl1 
set %pet1 #ltargetid 
wait 10 
display ok TARGET SECOND PET 
set #targcurs 1 
wait 5 
waitl2: 
if #targcurs = 1 
goto waitl2 
set %pet2 #ltargetid 
wait 10 
msg all guard me$ 
wait 10 
msg all kill$ 
waitfortarget1: 
if #targcurs <> 1 
 goto waitfortarget1 
set #ltargetid %pet1 
set #ltargetKind 1 
event macro 22 
wait 25 
msg all kill$ 
waitfortarget2: 
if #targcurs <> 1 
 goto waitfortarget2 
set #ltargetid %pet2 
set #ltargetKind 1 
event macro 22 
wait 10 
finditem %pet1 G 
move #findx #findy 1 3s 
set #LPC 100 
 
mainloop: 
gosub heal %pet1 
gosub heal %pet2 
gosub display 
wait %waitbetweenheals 
goto mainloop 
 
sub heal 
set %to #scnt + 12 
finditem %bandies C_ , #backpackid 
if #findstack < 10 
{ 
msg all stop$ 
wait 1 
msg all stay$ 
menu hide 
display OK You only Have #findstack Bandies Left$ Get More And Restart 
halt 
} 
set #lobjectid #findid 
event macro 17 
healwait: 
wait 1 
if #targcurs <> 1 
{ 
if #scnt > %to 
{ 
  return 
} 
goto healwait 
} 
set #ltargetid %1 
set #ltargetKind 1 
event macro 22 
gosub scan 
wait 1 
return 
 
sub scan 
scanloop: 
if #menubutton = stop || #menubutton = closed 
{ 
msg all stop$ 
msg all stay$ 
menu hide 
halt 
} 
if #hits < #maxhits - 10 
{ 
msg all stop$ 
msg all stay $ 
menu hide 
halt 
} 
if TOO_FAR_AWAY in #sysmsg 
{ 
finditem %1 G 
wait 1 
move #findx #findy 1 3s 
wait 10 
return 
} 
if finish_applying in #sysmsg || 
 + that_being_is_not_damaged in #sysmsg || 
+ heal_what_little in #sysmsg || 
+ barely_help in #sysmsg 
{ 
return 
} 
if #scnt > %to 
{ 
return 
} 
goto scanloop 
 
sub display 
  menu delete vet4 
  chooseskill vete 
  str len #skill 
  str ins #skill #dot #strRes 
  set %vet #strRes 
  menu Font Color red 
  menu Font Style b 
  menu text vet4 120 70 %vet 
return 
 
 
 
sub menu 
;--------- EasyUO Menu Designer Code Begin --------- 
  menu hideeuo 
  menu Clear 
  menu Window Title PANTHER_SN'S VET TRAINER 
  menu Window Color black 
  menu Window Size 180 90 
  menu Font Transparent #true 
  menu Font Align Right 
  menu Font Name MS Sans Serif 
  menu Font Size 14 
  menu Font Style b 
  menu Font Color White 
  menu Font BGColor Red 
  menu Button stop 30 0 121 45 STOP 
  menu font size 6 
  menu Font Color white 
  menu Font Align left 
  chooseskill vete 
  if #skill < 300 
    { 
    display ok You need to buy Vet upto 30.0 first$ Buy and then restart 
    menu hide 
    halt 
    } 
  str len #skill 
  str ins #skill #dot #strRes 
  set %vetstart #strRes 
  set %vet #strRes 
  menu Font Style 
  menu Text  vet1 10 50 VET STARTED @ 
  menu Font Style b 
  menu Font Color red 
  menu text vet2 120 50 %vetstart 
  menu Font Color white 
  menu Font Style 
  menu Text  vet3 10 70 VET NOW @ 
  menu Font Color red 
  menu Font Style b 
  menu text vet4 120 70 %vet 
  menu Show 810 3 
  menu show 810 3 
set #menubutton NULL 
return 
;--------- EasyUO Menu Designer Code End ---------

Panther_sn's Vet Trainer

[stewiezorro]

io l'ho provato ma non me lo fa partire dice di comprare vet fino a 30..
ma io ce l'ho a 31!!!!
che posso fare?