Musicanship

[wickedoz]

Ciao a tutti , ho provato a macrare music ma nel giro di 2 ore mi è salita di 0.2 , quindi vorrei sapere il giusto metodo x far crescere questa skill

Saluti

[acenik]

Re: Musicanship

Originally posted by wickedoz
Ciao a tutti , ho provato a macrare music ma nel giro di 2 ore mi è salita di 0.2 , quindi vorrei sapere il giusto metodo x far crescere questa skill

Saluti

Devi muoverti mentre la usi, prova in barca o seguendo un animale (alt+clic sx sull'animale)

[Aido]

io music l'ho macrata in pochissimo

[Ergo]

A me in una notte è arrivata a 100

Vai con la barca al largo ad est dell'isola di hytlot, quella zona è sgombra da ostacoli, e la barca se la viaggia che è un piacere!

[anasmana]

Comprati una barca.
Comprati na decina di strumenti musicali (anche quelli normali dal vendor).
Vai con la barca a largo di skara brae, per "largo" intendo tutto a ovest della mappa in pieno mare.
Portati un cavallo in barca con te (non devi cavalcarlo).
Utilizza la seguente macro per easyuo:

;================================== 
; Script Name: vesks 8X8peace&music-trainer 
; Skill Gain Range: up to 120 both musicianship and peacemake 
; Author: Veskandar with alot of help from Goldfish 
; Version: 1.1a 
; Client Tested with: 4.0.0q 
; EUO version tested with: 1.40 
; Shard OSI / FS: tested on OSI / probebly will work on FS but not tested 
; Revision Date: --/--/-- 
; Public Release: 10/23/2003 
; Purpose: This script will train both music and peacemake at the same time using 
;               the 8X8 method you need a ship (facing either north or south) an 
;                animal with you on the ship and instruments (crafted) in your main 
;                backpack 
;================================== 
initevents 
; === SETUP === 
set %boatongain #false  
set %boaty #charposy  
set %gain 0 
set %instrument QRF_NRF_MQF_PRF_LQF_OQF 
chooseSkill peac 
set %peace #skill 
event skillLock peac up 
chooseSkill musi 
set %music #skill 
event skillLock musi up 
msg raise anchor$ 
wait 5 
msg slow forward$ 
wait 2s 
; === END SETUP === 
;**************************************************** 
mainloop: 
gosub AntiBlock 
set %boaty #charposy 
Event Macro 8 7 
wait 30 
finditem %instrument C 
wait 10 
if #findKind = -1 
{ 
   Display ok You are out of instruments. The script will now halt. 
   msg stop$ 
   halt 
} 
set #lObjectID #findID 
event Macro 17 0 
wait 5 
gosub gainCheck 
event Macro 13 9 
target 
event Macro 23 0 
wait 7 
gosub gainCheck 
if %gain = 1 
{ 
   gosub 8x8 
} 
wait 6s 
goto mainloop 
;**************************************************** 
sub gainCheck 
set %boaty #charposy 
chooseskill peac 
if %peace < #skill 
{ 
   msg stop$ 
   set %peace #skill 
   set %gain 1 
   set %boatongain #true 
} 
chooseskill musi 
if %music < #skill 
{ 
   msg stop$ 
   set %music #skill 
   set %gain 1 
   set %boatongain #true 
} 
return 
;**************************************************** 
sub 8x8 
set %gain 0 
set %sgain 0 
set %boaty #charposy 
start8x8: 
for %forward8 1 8 
{ 
   msg one forward$ 
   wait 1s 
   set %boaty #charposy 
} 
wait 20 
gosub AntiBlock 
playmusic: 
finditem %instrument C 
wait 10 
if #findKind = -1 
{ 
   display Ok You are out of instruments the script will now halt. 
   msg stop$ 
   halt 
} 
set #lObjectID #findID 
Event Macro 17 0 
wait 5 
event Macro 13 9 
target 
event Macro 23 0 
wait 10 
checkforfail: 
scanJournal 1 
if calm_everyone,_but_fail. in #journal 
{ 
   deleteJournal 
   wait 10s 
   goto playmusic 
} 
scanJournal 1 
if You_play_poorly,_and in #journal 
{ 
   deleteJournal 
   wait 10s 
   goto playmusic 
} 
goto success 
success: 
gosub gainCheck 
if %gain = 0 
{ 
   set %sgain %sgain + 1 
} 
if %gain = 1 
{ 
   set %gain 0 
   set %sgain 0 
} 
if %sgain > 3 
{ 
   set %gain 0 
   set %sgain 0 
   msg slow forward$ 
   set %boatongain #false 
   return 
} 
if %sgain <= 3 
{ 
   goto start8x8 
} 
goto success 
return ;Not needed, but like CEO says 'Always good to see one' 

sub AntiBlock 
;purpose - get the boat out of a jam 
   if %boaty <> #charposy  || %boatongain 
      return 
   set %boatx #charposx 
   set %boaty #charposy 
UnBlock: 
   Event Macro 3 0 left 
   wait 2s 1s 
   if %boatx = #charposx 
   { 
      Event Macro 3 0 right 
      wait 2s 1s 
   }  
   if %boatx = #charposx 
   { 
      Event Macro 3 0 back 
      wait 4s 
      goto UnBlock 
   } 
   Event Macro 3 0 slow forward 
   set %boatx #charposx 
   set %boaty #charposy 
   wait 3s 1s 
   if #charposx = %boatx && #charposy = %boaty 
   goto UnBlock 
return 
end 
;****************************************************

Io in una decina, massimo 15 ore ho fatto 100 di music e 70 di peace.

Ciao

[arambenjo]

Come ti hanno già detto è facile e veloce salire music andando in barca, i miei pg sono saliti a 100 in circa 6 ore, peace circa 10.
Ora sto tentando di alzare provocation su un pg ma è un po più ardua.buona strimpellata