[UOSteam] Ripara tutto

[maliciousotter]

Un uccellino (ASD) mi ha detto che qualcuno cercava una macro per riparare tutto l'equip con un click, ma cercando nel forum non trovo richieste.

Come funziona la macro:

• marcare delle rune nei varii negozi e metterle in un runebook (nel caso del blacksmith, vicino ad incudine e forgia), una per negozio, tanto se c'è qualcuno sopra al tile di recall riprova all'infinito finché non siete lì (non ho messo il check sul flizz però, solo sul blocked);
• scegliere nella lista "repairrune" le collocazioni delle rune che avete marcato e aggiungere eventualmente quelle che non ci sono (ne ho messe due di base, la prima runa e la seconda)
• tenere in sacca abbastanza repair deed per fare tutto, non c'è bisogno che siano contati, ma almeno che siano abbastanza per ogni tipo
• avere lrc 100 o i reagenti necessari
• far partire la macro

//===============================================
// Piattaforma: UOSteam
// Titolo: Ripara Tutto
// Versione: 1.0.1
// Autore: Malicious Otter
// Shard: UODreams
//===============================================
//
// Serve:
// - un runebook con le rune settate da
//   tailor, black, fletcher ecc
// - repair deeds a sufficienza
// - tenere la roba da riparare addosso
//
// Codici rune(da 1 a 16) per recall:
// 5, 11, 17, 23, 29, 35, 41, 47, 53, 59,
// 65, 71, 77, 83, 89, 95
// Per sacred journey aggiungere 2.
//
//===============================================
// settaggi preliminari
//===============================================
// removelist 'repairrune'
if not listexists 'repairrune'
  createlist 'repairrune'
  pushlist 'repairrune' 5
  pushlist 'repairrune' 11
  // pushlist 'repairrune' x
  // pushlist 'repairrune' x
endif
// removelist 'liv'
if not listexists 'liv'
  createlist 'liv'
  pushlist 'liv' 1
  pushlist 'liv' 2
  //  pushlist 'liv' 3 = stivali
  pushlist 'liv' 4
  pushlist 'liv' 6
  pushlist 'liv' 7
  //  pushlist 'liv' 8 = anello
  //  pushlist 'liv' 9 = talismano
  pushlist 'liv' 10
  //  pushlist 'liv' 12 = cintura
  pushlist 'liv' 13
  //  pushlist 'liv' 14 = bracciale
  //  pushlist 'liv' 17 = gonna
  //  pushlist 'liv' 18 = orecchini
  pushlist 'liv' 19
  //  pushlist 'liv' 20 = mantello
  //  pushlist 'liv' 22 = tunica
  //  pushlist 'liv' 23 = maglietta
endif
//===============================================
// settaggi in game
//===============================================
headmsg "Uhm... dov'era piu' il runebook...?" 49
promptalias 'repairbook'
//===============================================
// inizio
//===============================================
for 0 to 'repairrune'
  useobject 'repairbook'
  waitforgump 0x554b87f3 15000
  replygump 0x554b87f3 repairrune[]
  pause 2000
  while @injournal 'blocked'
    useobject 'repairbook'
    waitforgump 0x554b87f3 3000
    replygump 0x554b87f3 repairrune[]
    pause 2000
  endwhile
  clearjournal
  for 0 to 'liv'
    if @findlayer 'self' liv[]
      setalias 'pezzo' 'found'
      moveitem 'pezzo' 'backpack' 0 0 0
      pause 500
      clearjournal
      while not dead 'self'
        if @injournal 'You must be' or @injournal 'full repair'
          break
        endif
        if @findtype 0x14f0 444 'backpack'
          setalias 'deed' 'found'
          useobject 'deed'
          waitfortarget 15000
          target! 'pezzo'
          ignoreobject 'deed'
          pause 500
        else
          break
        endif
      endwhile
      clearignorelist
      equipitem 'pezzo' liv[]
    endif
  endfor
endfor