[EASYUO] Wool -> Clothes

[fnurov]

script takes wool from bank. transforms to clothes and places clothes back to bank.
works only in luna tailor room. no recall needed

set %secureid HIUUDND
set %maxweight 500
set %loomx 976
set %loomy 527
set %bankx 979
set %banky 524
set %wheelid RWYOMMD
set %loom GMVUHND
set %banker1 FGMN
set %banker2 QGMN

set %wool OFF
set %yarn NLF
set %bolt ZZF
set %cloth CUI
set %wooloryarn OFF_NLF
set %nextpathfind #systime

set #lpc 1000
finditem KAG
if #findkind = -1
{
   event exmsg #charid 0 0 no scissors
   halt
}
set %scissors #findid
gosub Moveto %bankx %banky

while #true
{
      gosub OpenSecure
      finditem %cloth C_ , #backpackid
      if #findkind <> -1
      {
         exevent drag #findid #findstack
         exevent dropc %secureid
         wait 10
      }
      set %cantakewool ( %maxweight - #weight ) / 4
      finditem %wool C_ , %secureid
      if #findkind <> -1
      {
         exevent drag #findid %cantakewool
         exevent dropc #backpackid
         wait 11
      }
      gosub moveto %loomx %loomy
      finditem %wooloryarn C_ , #backpackid
      set %next170 #systime
      set %nextwheel #systime
      while #findkind <> -1
      {
            if #systime >= %next170
            {
               if #systime >= %nextwheel
               {
                  finditem %wool C_ , #backpackid
                  if #findkind <> -1
                  {
                     set #lobjectid #findid
                     event macro 17 0
                     set %next170 #systime + 550
                     set %nextwheel #systime + 3550
                     target 40
                     set #ltargetid %wheelid
                     set #ltargetkind 1
                     event macro 22 0
                  }
                  else
                      set %nextwheel #systime + 9999999
               }
               else
               {
                   finditem %yarn C_ , #backpackid
                   if #findkind <> -1
                   {
                      set #lobjectid #findid
                      event macro 17 0
                      set %next170 #systime + 550
                      target 40
                      set #ltargetid %loom
                      set #ltargetkind 1
                      event macro 22 0
                   }
               }
            }
            sleep 10
            finditem %wooloryarn C_ , #backpackid
      }
      finditem %bolt C_ , #backpackid
      while #findkind <> -1
      {
            if #systime >= %next170
            {
               set #lobjectid %scissors
               event macro 17 0
               set %next170 #systime + 550
               target 40
               set #ltargetid #findid
               set #ltargetkind 1
               event macro 22 0
            }
            finditem %bolt C_ , #backpackid
      }
      gosub Moveto %bankx %banky
}

Sub MoveTo
    while ( #charposx <> %1 || #charposy <> %2 )
    {
          if #systime >= %nextpathfind
          {
             event pathfind %1 %2 #charposz
             set %nextpathfind #systime + 3000
          }
          sleep 10
    }
return #true

sub OpenSecure
    finditem %secureid
    if #findkind = -1
    {
       repeat
          exevent popup %banker1 2
          exevent popup %banker2 2
          finditem %secureid
          sleep 10
       until #findkind = 0
    }
    set #lobjectid %secureid
    set %next170 #systime
    repeat
          if #systime >= %next170
          {
             event macro 17 0
             set %next170 #systime + 1000
          }
          sleep 10
    until #contid = %secureid
return