[EASYUO - Req] world to screen

[Angelofdeath]

Ciao mi serve 1 sub k converte le coordinate del mondo in coordinate dello screen xke sul sito di euo ho trovato solo quella inversa e quella k ho io ha la limitazione di funzionare solo a 2 title di distanza dal target cosa k nn mi torna molto comoda..va bene anke se mi linkate quella k aveva usato Mith nella versione dello script x prendere i bod k aveva postato..l'ultima volta ultilizzai quella inserita nel suo script e andava..grazie
bye

[Boydon]

A che ti serve? Perchè se devi aprire i menu di pop-up ci sta il comodo Exevent PopUp.

[Angelofdeath]

Ho scriptato pokissimo euox mi puoi dare la sintassi cn 1 breve spiegazione o 1 guida?

[Angelofdeath]

Chiedo scusa x le noie xo provando qst sintassi:
set %vendor DRLF
finditem %vendor G_10
if #findkind <> -1
Exevent Popup #findid 1
halt

mi si apre il paperdoll e non il gump..mi sapresti spiegare il xke?

[Angelofdeath]

Ah no gra ho capito il funzionamento del numero alla fine della sintassi

[Boydon]

Per la documentazione rifarsi sempre al manuale ufficiale:

Exevent PopUP


Ad ogni modo ti metto la sub che usavo io per aprire i Menu (prima che fosse introdotto l'event pop up).
Se vedi bene è inclusiva di sub per convertire le coordinate da world a monitor.

;==================================
; Script Name: BMUseContextMenu
; Author: Bad_Maniac
; Copyright: Bad_Maniac
; Version: 1.00
; Client Tested with: 4.0.10b
; EUO version tested with: 1.42 build 00A5
; Shard OSI / FS: Both
; Revision Date: ---
; Public Release: 02/05/2005
; Purpose: Opens an NPC's context menu, and clicks the selected option.
;==================================
;* Parameters:
;* %1 ID of the NPC to use
;* %2 Wich option in the menu to click, 1 being the top one
;* Returns:
;* #TRUE if sucessful (It will try 6 times internally before failing).
;* #FALSE on total failiure.
;==================================
SUB BMUseContextMenu
  SET %_ctx_lpc #LPC
  LINESPERCYCLE 100
  SET %_ctxvendor %1
  SET %_ctx_option %2
  SET %_ctx_open_retry 6
  SET %ctx_xoff 3
  SET %ctx_yoff 50
ctxopenstart:
  FINDITEM %_ctxvendor G_12
  IF #FINDKIND = -1
    GOTO ctx_fail
  GOSUB worldXYZToScreenXY #FINDX #FINDY #FINDZ
  SET %ctx_cursx !_cursorX + %ctx_xoff
  SET %ctx_cursy !_cursorY - %ctx_yoff
  CLICK %ctx_cursx %ctx_cursy F DMC

  SET %ctxtimeout #SCNT2 + 25
ctxmenuwait:
  IF #CONTID <> N/A || #CONTNAME <> normal_gump
  {
    IF %_ctx_open_retry <= 0
      RETURN #FALSE
    IF #SCNT2 > %ctxtimeout
    {
      SET %ctx_xoff %ctx_xoff - 1
      SET %ctx_yoff %ctx_yoff + 5
      SET %_ctx_open_retry %_ctx_open_retry - 1
      GOTO ctxopenstart
    }
    IF #CONTID = %_ctxvendor
    {
      set %_cx #CONTPOSX + 35
      set %_cy #CONTPOSY + 35
      CLICK %_cx %_cy R DMC
      SET %_ctx_open_retry %_ctx_open_retry - 1
      GOTO ctxopenstart
    }
    GOTO ctxmenuwait
  }
  SET %_ctx_x #CONTPOSX
  SET %_ctx_y #CONTPOSY
  STR POS #CONTSIZE _
  STR DEL #CONTSIZE 1 #STRRES
  SET %ctxnumoptions ( #STRRES - 32 ) / 17
  IF %ctxnumoptions < %_ctx_option
    GOTO ctx_fail

  SET %_ctx_clickx %_ctx_x + 25
  SET %_ctx_clicky %_ctx_y + ( 17 * ( %_ctx_option - 1 ) ) + 25
  CLICK %_ctx_clickx %_ctx_clicky DMC
  GOTO ctx_sucess
ctx_fail:
  LINESPERCYCLE %_ctx_lpc
  RETURN #FALSE
ctx_sucess:
  LINESPERCYCLE %_ctx_lpc
RETURN #TRUE
;===============================
;* Convert 3D world coordinates to 2D screen coordinates.
;*
;* @purpose  Convert 3D world coordinates to 2D screen coordinates.
;* @author   the.WZA (namespace edit by Quintok)
;* @param    %1  worldx  req  World x-coordinate.
;*           %2  worldy  req  World y-coordinate.
;*           %3  worldz  req  World z-coordinate.
;* @return   %_cursorX and %_cursorY holds the screen coordinates.
;* @see      clickScreenXYZ checkScreenXY
sub worldXYZToScreenXY
  set %1 ( %1 - #charPosX ) * 22
  set %2 ( #charPosY - %2 ) * 22
  set !_cursorX #cliLeft + #clixres / 2 + %1 + %2
  set !_cursorY #cliTop + #cliyres / 2 + %1 - %2 - ( %3 - #charPosZ ) * 4
return