Tintin ++

[perplessa]

ok ripropongo sul forum nuovo la guida di tin tin ++ che ha proposto allanon. Che e' sempre molto utile per chi vorrebbe usare tin tin ++ per chi ha linux o per chi come me ha un mac e non sa come fare. Copio e incollo

Il progetto e' accessibile su
http://tintin.sourceforge.net/
e' un client esclusivamente testuale, e la sua forza sta proprio in questo: niente e nessuno mai vi obblighera' a togliere le mani dalla tastiera per impugnare il perfido mouse, inoltre potrete contare su potenti script in grado di rendere la vostra vita muddistica un po' piu comoda.
Si si, il vero muddaiolo e' colui che soffre e riscrive i comandi 100 volte di fila finche le unghie non sanguinano, ma d'altra parte il vero uomo e' colui che veste e mangia gli animali che uccide o i frutti che coltiva, eppure tutti noi utilizziamo scarpe e cellulari Cool

Iniziamo, io mi riferiro' alla versione per GNU/linux, non avendo, materialmente, un windows su cui provare, non dovrebbe essere troppo differente, specie se siete esperti maneggiatori di windows xp e quindi avete installato e disinstallato centinaia di antivirus, antitrojan, antispam,antiqua e antila'.


1) Installare il programma
Alla pagina
http://tintin.sourceforge.net/download.php
scaricare la versione appropriata.
Gli utenti Gnu/linux possono scegliere se compilare il codice sorgente o utilizzare la versione pacchettizzata per la Slackware,
in quest'ultimo caso, molto comodo e' il convertitore alien
Esempio, sulla mia ubuntu scrivero' in una shell
sudo alien tintin-1.96.5-slackware-9.1.tar.gz
e dopodicche installero il pacchetto con un doppio click o con un semplice
sudo dpkg -i blablabla.deb

2) utilizzare file di configurazione
Tintin++ abbiamo detto e' un coso solo e puramente testuale, quindi ci si aspetterebbe che una volta avviato, si debbano scrivere le istruzioni per accedere ad Equilibrium: bella seccatura direte voi, oggigiorno io doppioclicco su qualcosa e si apre il mondo (ed entrano i virus, bella forza Very Happy).
E invece no!! la potenza del tintin++ e' che accetta file di configurazione puramente testuali, quindi immaginate che in un unico file ci stanno tutti gli alias, le macro, i trigger e gli script che vi servono, giocate da quale pc volete, tanto basta sempre e solo portarsi dappresso questo misero e piccolo file di testo!

Quindi il prossimo passo sara'
3) utilizzare tintin++ per accedere a Equilibrium Mud
Basta creare un file con dentro
Codice:
#session equilibrium 82.104.216.203 4000

e poi lanciare questo comando
Codice:
./tintin++ nomefile

e magicamente sarete su Equilibrium
Lungi da me spiegarvi cosa vuol dire session e comandi vari, c'e' il manuale online che dice tutto!

Agli utenti window, come a quelli linux e mac, bastera fare un collegamento, un alias o cme si chiami nel vostro sistema operativo

4) sfruttiamo un po' della potenza di tintin++
Iniziamo mostrando pezzi del mio file di configurazione

Codice:

#session equilibrium 82.104.216.203 4000
#split
#ticker {autosave} {save} {300}
#config {repeat enter} on

Mi collega al mud
#split crea una piccola linea di delimitazione tra quella che e' l'area dell'ouput del mud, e quella che e' l'area di input del giocatore.
Il ticker mi ripete il comando ogni 300 secondi, in questo caso e' il comando utilissimo SAVE, cioe ogni 5 minuti salva il vostro stato
L'ultima linea dice di considerare il semplice invio di una riga vuota come una ripetizione del comando precedente (attenzione a non appoggiarvi quindi sul tasto invio perche' dopo 30 comandi ripetuti il mud vi freezera'!)

Codice:

#MACRO {\eOQ} {sacrifica corpo}
#MACRO {\e[17~} {gruppo}
#macro {\e[24~} {prendi ritorno zaino; recit ritorno}

semplici macro,
per sapere come usare bene il comando macro, scrivere #help macro
e lui stesso vi spieghera' tutto

Codice:

#act {Un bel fiore di calendula e' stato lasciato qui}{pren calend;m calendu}
#act {Una pera e' davanti a te} {pren tutto}
#act {Una mela rossa e' davanti ai tuoi piedi} {pren tutto}

Sono i cosiddettri trigger, cioe' azioni da fare quando si verifica un certo output, in questo caso passegiando per la wild raccoglierete fiori mele e pere

Codice:

#alias arma {p pip;formulo 'armatura alchemica' %0;m pip}
#alias scud {p ratt;formulo 'scudo alchemico'}
#ALIAS {m}{metti %0 cappello}
#ALIAS {p}{prend %0 cappello}
#alias medi {#loop {1 5} med}
#alias bagno {rimuov tutto;posa tutto;bagn;bagn;prend tutto;indoss tutto}
#alias z {gdico &W-->&P %0 &W<--}

Alias, come vedete, in alcuni alias si fa riferimento ad altri alias, cioe alias annidati, cio' e' possibile purche l'alias sia la prima parola del rigo
cioe:
Codice:

p pipistrello
p pipistrello

il primo richiama l'alias p, il secondo no, e' una semplice riga

Altra cosa, vedete che l'alias medi, utilizza il comando #loop, cioe ripete da 1 a 5 il comando meditazione

Altra cosa ancora, tintin++ fa largo uso delle variabili, quindi e' possibile scrivere un alias come z, cioe' se digito
Codice:
z dicoqualcosa

il dicoqualcosa riempirebbe la variabile %0 e il tutto corrisponderebbe ad un comando mud tipo
Codice:
gdico &W-->&P dicoqualcosa &W<--

cioe colorato rosa e racchiuso tra freccie bianche

Codice:

#config log plain
#format {time} {%T}
#format {logfile} {/home/allanon/tt/log/fra/sibilla-%d.txt} {$time};
#log append $logfile;
#var logging on

quasta sfilza di righe che ora non ricordo cosa vogliono dire, non fanno altro che occuparsi di scrivere un log del tipo sibilla-15-12-2006.txt
Ebbene si, ho scopiazzato queste righe da uno script trovato sul sito e ora non so cosa vuol dire: non bisogna essere l'arca della scienza per usare tintin++

Codice:

#var killmax 100
#act {%0 e' morto!!}
{
#var found 0;
#loop {100 $killmax}
{
#if {"$killname&0" == "%0"}
{
#math killcount&0 $killcount&0 + 1;
#var found 1
}
{
#if {$found == 0 && &0 == $killmax}
{
#var killname$killmax {%0};
#var killcount$killmax 1;
#math killmax $killmax + 1
}
}
}
}

#act {%0 e' morta!!}
{
#var found 0;
#loop {100 $killmax}
{
#if {"$killname&0" == "%0"}
{
#math killcount&0 $killcount&0 + 1;
#var found 1
}
{
#if {$found == 0 && &0 == $killmax}
{
#var killname$killmax {%0};
#var killcount$killmax 1;
#math killmax $killmax + 1
}
}
}
}

#alias {showkills}
{
#echo {%c%h} {"yellow" "KillList"};
#loop {100,$killmax}
{
#if {&0 < $killmax }
{
#echo {<128>%-5s<088> : %s %s %s %s %s %s} {"$killcount&0" "$killname&0"}
}
};
#echo {%c%h} {"yellow" "KillList"};
}




E' un po lunghetto,
vi spiego cosa fa: tiene in memoria il numero dei mostri che uccidete in questa sessione,
richiamabile con l'alias showkills
Codice:

################################################## #######"KillList"################################# ########################
"4" : "una fenice"
################################################## #######"KillList"################################# ########################



Altre cose in piu' di tintin++
l'altro giorno dopo un combattimento lyen mi chiedeva cosa avesse detto Tizio:
Codice:

#grep Tizio

fate attenzione al Case Sentitive, cioe alle maiuscole!

Quindi se volete tutta un sunto della chat,
#grep chiacc
idem per il gruppo ecc. ecc.

[perplessa]

per gli utenti linux

Pero' e' bello solo che quel che finisce, quindi adesso che sono sotto Feisty, su cui non mi pronunciero' oltre qui, e presumo lo sia pure tu (se hai ancora Edgy chiudi immediatamente questa pagina: non meriti il mio aiuto ne niente altro dalla vita!) l'installazione e' molto molto semplice:

1) apri console e scrivi
Codice:
sudo apt-get install tintin++


2) oppure apri il front-end grafico Synaptic e clicca su cerca, trova il tintin++ e marcalo per l'installazione Very Happy

cosi installerai la versione 1.96.3
che e' quella che "quasi" sto usando io.

Anche se leggendo ora dal sito..e' uscita la versione 1.97.1 che promette l'automapping e altro..

uhmmm

apri console
Codice:

mkdir ~/tt-1971
cd ~/tt-1971
wget http://heanet.dl.sourceforge.net/sou...1-linux.tar.gz
tar zxfv tintin-1.97.1-linux.tar.gz
./tt++


cosi facendo lo installerai all'interno della tua home sotto tt e lo farai anche partire Cool

[perplessa]

PS
il manuale spiega come realizzare altre macro con differenzi combinazioni di tasti

#help macro
Codice:
########################## MACRO

Command: #macro {key sequence} {commands}

Macros allows you to make tintin respond to function keys.

The key sequence send to the terminal when pressing a function key
differs for every OS and terminal. To find out what sequence is send
you can enable the CONVERT META config option.

Another option is pressing ctrl-v, which will enable CONVERT META for
the next key pressed.

Example: #macro {(press ctrl-v)(press F1)} {shout TinTin++ is the greatest!

The next time you press F1 the entered command should be executed.

Keypad: Not all terminals properly initialize the keypad key sequences.
If this is the case you can still use the keypad, but instead of the
arrow keys use ctrl b, f, p, and n.
#######################################

[perplessa]

questo invece e' una parte del file che uso io per malvokian

- logga ogni sessione
- macro per lo spostamento tramite numpad (funzioan solo con console pterm)
- trigger contro il disarma
- trigger per la raccolta mele da wild O_O
- autosave ogni 300 secondi con frase personalizzata

Codice:

#session equilibrium 82.104.216.203 4000
#split
#ticker {autosave} {save;, sbuffa aria dal naso taurino e ti guarda con occhi rosso sangue;ltd} {300}
#config {repeat enter} on
#message var off
#MACRO {\eOQ} {sacrifica corpo}
#MACRO {\e[17~} {gruppo}

/* pterm */
#macro {\eOt}o
#macro {\eOv}e
#macro {\eOr}s
#macro {\eOx}n
#macro {\eOy}ne
#macro {\eOw}no
#macro {\eOq}so
#macro {\eOs}se



#alias ri {supplica richiamo}

#tick {sputacchia}{sputa}{120}

#config log plain
#format {time} {%T}
#format {logfile} {/home/allanon/tt/log/malvokiah-%d.txt} {$time};
#log append $logfile;
#var logging on

#act {Una pera e' davanti a te} {pren tutto}
#act {Una mela rossa e' davanti ai tuoi piedi} {pren tutto}



#alias indib {form 'individua bene'}
#alias india {form 'individua allineamento'}
#alias indii {form 'individua invisibile'}
#alias indin {form 'individua nascosto'}
#alias indim {form 'individua magico'}

#alias deb {form 'debolezza'}
#alias leg {form 'causa leggere'}
#alias man {form 'mano di ombra'}
#alias sen {form 'sentenza'}
#alias sof {form 'sofferenza'}
#alias lama {form 'lama dell odio}

#alias arma {form 'armatura'}
#alias ombra {form 'scudo di ombra'}
#alias abisso {form 'abisso di ombra'}
#alias barriera {form 'barriera di spiriti'}
#alias patto {form 'patto di tenebra'}
#alias forz {form 'forza divina'}

#alias cura {form 'cura del male'}

#alias cibo {form 'crea cibo'}
#alias acqua {form 'crea acqua'}

#alias d {, sbuffando aria dal naso dopo ogni parola &Wdice in ardesyano '%0'}
#alias z {gdico &W-->&P %0 &W<--}

#alias ss {esa sud}
#alias nn {esa nord}
#alias ee {esa est}
#alias oo {esa ovest}
#alias nne {esa nordest}
#alias nno {esa nordovest}
#alias sse {esa sudest}
#alias sso {esa sudovest}
#alias aa {esa alto}
#alias bb {esa basso}




#act {ti DISARMA!} {pren portatri;ind portatri}

[perplessa]

ok queste erano le parole di allanozzolo.

adesso vi spiego come si deve fare per mac.

1)scaricate il programma e create una cartella dove mettete sia il programma sia 2 file di testo di cui uno sara' eseguibile.

2) create due file di testo
A) nel primo file io ho scritto e potete copiare cambiando opportunamente quello che volete e togliendo le parentesi:

#alias ri {supplica richiamo} (un esempio di alias)

#config log plain
#format {time} {%T}
#format {logfile} {/users/elena/desktop/mud/log/lyen-%d.txt} {$time};
#log append $logfile;
#var logging on (mi crea il log delle giocate suddiviso in giorni.. molto utile avercelo per chi ama conservarsi tutti i log)

#act {Una pera e' davanti a te} {pren tutto} (ogni volta che incontro una pera.. gnamme)
#act {Una mela rossa e' davanti ai tuoi piedi} {pren tutto}



#alias arma {form 'armatura'}
#alias cibo {form 'crea cibo'}
#alias acqua {form 'crea acqua'}

#alias z {gdico &W-->&P %0 &W<--} (il gdico colorato)

#act {ti DISARMA!} {pren bastone;ind bastone} (se ti disarmano)

#act {Inserisci il nome del tuo account o digita nuovo:} {nome account}
#act {Password:} {#delay {1}{password;l;nomepg;l}}(questo e' per il loggin automatico per un determinato pg)

***********
***********
***********

ecco salvate questo file di testo col nome che volete. Io lo chiamato lyen.txt

B) adesso create un altro file.txt che poi rendete eseguibile. Dentro dovete scrivere:

#!/bin/sh
BASENAME='/users/elena/desktop/mud' (ABBE DOVETE METTERE LA DIRECTORY DEL VOSTRO FILE MICA IL MIO)

# se cambia il file, modifica qui
$BASENAME/tt++ $BASENAME/lyen.txt

********
********

ok

memorizzato anche questo in .txt e messi entrambi i file nella stessa cartella di dove sta tin tin ++ allora cliccate sul secondo file che io ho chiamato lyenuzza.txt ma voi come volete e fate: apri con .. terminale.app. vi si apre tintin++ con il vostro bel pg pronto pronto al divertimento.

Ok lo so che non ho fatto capire nulla ma ci ho provato.

[allanozzolo]

Io lo stavo riscrivendo proprio perche' nn si capisce nulla!!!!

ci stavo mettendo le immagini, con tanto amore!!

niente va, mi hai rovinato la sorpresa, ora lo sistemi tu!!


PS

copia anche quello del kmuddy, che e' un client grafico, ed e' un progetto interessante

[perplessa]

no fai fai che non si capisce nulla davvero.. e io devo pure studiare....

[Mortigan]

Tra i suggerimenti vorrei aggiungerne uno pure io. Dedicato agli utenti linux/unix.
Se non vi piace il fonts di defaults di pterm, magari ha provato in più modi a cambiarlo con l'opzione -fn senza capire la sintassi (tra l'altro non documentata).

Un modo semplice è quello di installare PuTTy provare a impostare un fonts e copiare quello che appare, oppure salvare come default e aprire il file ~/.putty/sessions/Default Settings. Aggiungete la stringa dopo l'opzione -fn e si aprirà una sessione pterm con un carattere più gradevole o semplicemente più grande:

Per i pigri lascio anche la mia stringa di defaults:

pterm -fn -misc-fixed-medium-r-normal-*-*-170-*-*-c-*-iso8859-1

Ciao a tutti e buon divertimento.

PS: Vorrei ringraziare perplessa per avermi fatto scoprire tintin++

[Mortigan]

Statistiche con Showkills

Per chi come mè avesse problemi con lo script per le statistiche delle nostre vittime.
Ho modificato l'ononimo script che appare sul sito di tintin++.
Nulla di difficile alla linea 3 o 2 (se siete programmatori C che contano da 0), c'era un trigger più o meno così #act {%0 is DEAD!!}. Il problema inizialmente lo modificai in #act {%0 e' morto!!}, ma il problema che nell nostra lingua abbiamo il maschile e il femminile, quindi per non ripetere lo stesso trigger due volte ho sostituito l'ultima o in %1 così da funzionare sia per il maschile che per il femminile, e forse anche per gli assessuati
A mè funziona perfettamente anche se non uccido nessuno (capita di rado ).
Per i pigroni possono tranquillamente copiare il riquadro qui sotto e aggiungerlo al proprio script di tintin++.
Ciao e buon divertimento

#format kill_list %s

#act {%0 e' mort%1!!}
{
        #list kill_list fnd {%0} index;

        #if {$index}
        {
                #math kill_list[$index+1] $kill_list[$index+1] + 1
        }
        {
                #format index %L kill_list;

                #if {$index > 9750}
                {
                        #showme #kill counter: maximum size reached.
                }
                {
                        #list kill_list len index;

                        #var kill_list[$index+1] %0;
                        #var kill_list[$index+2] 1
                }
        }
}

#alias {showkills}
{
        #echo {%c%h} {{light yellow} { KILL LIST }};

        #list kill_list len index;

        #loop {1 $index}
        {
                #if {&0 % 2 == 1}
                {
                        #echo {<178>%+4s<068>: <128>%-50s<088>} {{$kill_list[&0+1]} {$kill_list[&0]}}
                }
        };
        #echo {%c%h} {{light yellow} { KILL LIST }}
}

[Mortigan]

Cambiare descrizione al volo

Ecco qua, con Orem ho spesso il problema ruolistico che non può dichiarare pubblicamente in una città buona o neutrale (due a caso Mallia e Knesya) il suo reale mestriere "il negromante".
Allo scopo di non essere appeso ad un albero con il suo stesso pugnale.
Sarebbe opportuno che in città o davanti a illustri diffensori del bene cambì atteggiamento (ovviamente non l'aspetto).
Quindi la descrizione passa da un atteggiamento quieto e sorridente a uno nervoso e imbronciato.
Quindi ho creato due alias per cambiare al volo la descrizione del pg.
Ecco lo script:

/* Per cambiare descrizione */
/* Lista variabili */
#variable {vedit} {Scrivi il tuo testo (/? = aiuto /s = salva /c = cancella /l = lista)}
/* Come potete vedere qui sotto sono state definite due varriabili: "vbuono" e "vcattivo" */
/* Esse contengono le descrizioni.  Dovendo  mettere  l'intera  descrizione  su  una  linea */
/* ptete andare a capo  con  la  sequenza  "\n"  (non  è  necessario  lasciare  uno  spazio*/
/* prima e dopo). */
#variable {vbuono} {Linea n.1 \n Linea n.2 \n Linea n.3}
#variable {vcattivo} {Linea n.1 \n Linea n.2 \n Linea n.3}
#alias {dbuono}
{

	, qui viene mostrato quello che gli altri possono leggere ; 
	#act $vedit {/c ; $vbuono ; /s} ; descrizione ; #delay {4} {#unact $vedit}
}

#alias {dcattivo}
{
	
	, qui viene mostrato quello che gli altri possono leggere ;
	#act $vedit {/c ; $vcattivo ; /s} ; descrizione ; #delay {5} {#unact $vedit} 
}

Ovviamente come io ho aggiunto il comando fai (","), potrete aggiungere tutte le
linee di codice che volete. A patto che le separiate da un ";". Come ad esempio rimuovere
dall'equipaggiamento armi o altri oggetti.
In ultimo ma non meno inportante potrete aggiungere tutti i cambi di descrizione che volete.
Spero che vi piacia e buon divertimento :-)!!!


Note: La descrizione in questo caso (ma non solo) intende solo quello che si può capire al primo sguardo, quindi in senso di rpg possiamo essere sorridenti e placati così come severi o arroganti. Personalmente non contemplo altri modi per definire una descrizione. Anche perchè la si legge con il comando "guarda", perciò guardando una persona non posso sapere con precisione tratti della sua vita o del suo passato, ma al massimo intuire come "mani sporche di sangue" e non particolari come "quella cicatrice che si fece da bambino"

[allanozzolo]

Ottimo lavoro!!

domandina: la statistica dei mostriciattoli uccisi ti funziona??
non so perche' ma mesi e mesi fa andava alla grande poi cambiando versione ha iniziato a dare loop infiniti

Mi sa che provero' la tua versione!

Una cosa simpatica da fare, se possibile sarebbe quella di salvare le statistiche su file e richiamarle ogni volta.

So che e' possibile scrivere su file tutta la configurazione attualmente usata, ma non so se sia possibile salvare selettivamente.

Sarebbe una gran gran bella cosa.

Difatti se non sbaglio/ricordo male e' possibile anche tenere una sorta di lista di tutte le identificazioni, qualora fosse possibile salvare tale elenco e richiamarlo ad ogni apertura, il risultato sarebbe spettacolare!!

In effetti credo sia anche possibile richiamare script esterni.... mmmmmm

Basta, ti ho dato troppi indizi!! mettiti al lavoro

[Mortigan]

Ottimo lavoro!!

Grazie 1000

domandina: la statistica dei mostriciattoli uccisi ti funziona??
non so perche' ma mesi e mesi fa andava alla grande poi cambiando versione ha iniziato a dare loop infiniti

Certo che mi funziona!
Anchio con quello del vecchio post avevo lo stesso problema (pensavo fosse un errore di trascrittura), poi ho dato un occhiata a quello del sito e ho notato che era differente.
Da li ho modificato solo il trigger, uso l'ultima versione di tintin++

Mi sa che provero' la tua versione!

Fammi sapere come va

Una cosa simpatica da fare, se possibile sarebbe quella di salvare le statistiche su file e richiamarle ogni volta.

So che e' possibile scrivere su file tutta la configurazione attualmente usata, ma non so se sia possibile salvare selettivamente.

Sarebbe una gran gran bella cosa.

Difatti se non sbaglio/ricordo male e' possibile anche tenere una sorta di lista di tutte le identificazioni, qualora fosse possibile salvare tale elenco e richiamarlo ad ogni apertura, il risultato sarebbe spettacolare!!

Ho letto uno scripettino simile sul forum di tintin++, mentre cazzeggiavo da un cliente :-P
Credo che sia nell'area script

In effetti credo sia anche possibile richiamare script esterni.... mmmmmm

Basta, ti ho dato troppi indizi!! mettiti al lavoro

Per gli script esterni è possibile chiamarli con il comando: #script (fatevi un tatuaggio perché è molto difficile ricordarselo :-D), la sintassi la potete vedere sulla documentazione online o con il comando '#help script', tra le altre cose è possibile scrivere script in python, ruby e php.
Ma se preferite un altro linguaggio (come l'Assemler :-D) potete usare il comando #run.
Se avessi avuto tempo vi avrei già lasciato un estensione di tintin fatta in python.
Ma è in fondo a una lista di cose da fare, quindi non vi prometto niente.
Ciao a tutti e grazie

[TehrionEQUIMUD]

grande morty
sempre detto che sei la soddisfazione di noi admin

continua cosi' grandissimo
byez

[Mortigan]

Script Eseguibile

Ecco un altro barbatrucco per rendere eseguibile lo script di tintin++.
Questa procedura è valida solo per le piattaforme UNIX (Linux, OS X, FreeBSD ecc).

Il trucco è semplice basta eseguire questi comandi:

$ which tt++
/usr/games/tt++

Come potete vedere il comando which riporta allo standard output il path dell'eseguibile di tintin++.
Anche se è probabile, non è detto che abbiate lo stesso risultato.

Dopo di che aprite con il vostro texteditor preferito e aggiungete alla prima linea la seguente riga:

#!/usr/games/tt++

Salvate e flaggate come eseguibile il file con un bel:

chmod +x nome_script

Fatto! Se tutto è andato bene potrete eseguire il vostro script con la seguente sintassi:

./nome_script

oppure spostarlo o linkarlo ad un path di ricerca degli eseguibili.

Ciao a tutti

[allanozzolo]

ghghghgh, per la serie, scazzi e mazzi

#ALIAS {dball}={#script {./database.py get_all}} @ {5}
#ALIAS {dbday}={#script {./database.py get_day}} @ {5}
#ALIAS {dbget}={#script {./database.py get_lastn %0}} @ {5}
#ACTION {%0 e' mort%1!!}={#script {./database.py "add" "%0"}} @ {5}

------------------

HP:264/264 T:92/92 A:93/93 F:97/97 A:94/94 Mov:360/360 Exp:608255 Oro:3973 Stato:> dball
################# get_all #################
21      : Un cittadino ubriaco
1       : un elementale di sabbia
26      : un goblin
1       : un puddu
1       : un toro infuriato
12      : Una cittadina ubriaca
###########################################


HP:264/264 T:92/92 A:93/93 F:97/97 A:94/94 Mov:360/360 Exp:608255 Oro:3973 Stato:> dbday
################# get_day #################
1       : un elementale di sabbia
4       : un goblin
1       : un puddu
###########################################


dbget 10
############## get_last 10   ##############
2008-06-25 18:32:04     : un goblin
2008-06-25 18:57:13     : un goblin
2008-06-25 18:57:39     : un goblin
2008-06-25 18:58:04     : un goblin
2008-06-25 18:58:30     : un goblin
2008-06-25 18:58:57     : un goblin
###########################################