Script utilissimo

[Simo63]

ciao scusate mi stò trovando in difficoltà a trasportare lingotti da casa alla banca per fillarli e metterli nel vendor ...dato che scornaminer non ha la funzione banca ...qualcuno potrebbe postare uno script che trasporti lingotti da una cassa dentro casa alla banca?
nn sò magari questo script potrebbe essere più generalizzato se tipo chiede il target dell'oggetto da trasportare in banca così se uno vuole trasportare legna targhetta la legna e porta quella in banca ,o altre risorse anche (dò solo un'idea non sò se è possibile farlo ) basterebbe cmq lo script per i linghi credo non sia utile solo a me...grazie mille anche per l'attenzione

[dArKoMeGa89]

uno di questi giorni se mi ricordo lo faccio

[Jimok91]

up x lo script delle feather away

[Simo63]

bè lo script per le feather away sarebbe bello solo che serve del tempo per farlo ....se ti metti a fare questo script saresti un mito...trasportare roba da casa a banca è un problema di molti ...grazie mille

[Sanzocoso]

bè lo script per le feather away sarebbe bello solo che serve del tempo per farlo ....se ti metti a fare questo script saresti un mito...trasportare roba da casa a banca è un problema di molti ...grazie mille

nessuno l'ha ancora fatto questo script? servirebbe tanto anche a me...

[MarioTidus2000]

imparate a scriptare e fatelo da soli, non è difficile u.u

[Assassin]

Io me ne ero fatto uno ma e' molto spartano.. se vi interessa :

MEGAUPLOAD - The leading online storage and file delivery service

Voi vi mettete davanti alla cassa dove ci sono i lingotti fate play e selezionate cassa e runebook.

Nel runebook come prima runa ci deve essere la runa per casa e successivamente quella per la banca.

all'inizio trovate questo codice :

  ; iron = 0
  ; dull copper = 2419
  ; shadow iron = 2406
  ; agapite = 2425
  ; copper = 2413
  ; bronzo = 2418
  ; gold = 2213
  ; verite = 2207
  ; valorite = 2219

  set %iron_col 2425

cambiate il valore di %iron_col con il colore del metallo che volete trasportare segnato nelle lista sopra e lui portera' in banca tutto il metallo di quel tipo.

poco piu sopra trovate :

set %MaxIronSale 4000

cambiate con il numero di lingotti massimo che puo portare il vostro pg.

[gramoz]

up x lo script delle feather away

Ma ragazzi, una domanda (visto che ancora io non l'ho testato), quello pubblicato da fengyr (http://forum.gamesnet.it/newreply.ph...te=1&p=5497508) non dovrebbe funzionare anche per le feathers se settato a dovere?

[gordoso]

non riesco a scaricarlo da megaupload.. non è che potresti postarlo sul foro? grazie mille

[Assassin]

  set %homeposx #charposx
  set %homeposy #charposy
  set %homeposz #charposz

  set %MaxIronSale 4000
  set %IronType ENK
  ; iron = 0
  ; dull copper = 2419
  ; shadow iron = 2406
  ; agapite = 2425
  ; copper = 2413
  ; bronzo = 2418
  ; gold = 2213
  ; verite = 2207
  ; valorite = 2219

  set %iron_col 0

  display ok seleziona la cassa dove prendere il metallo
  set #targcurs 1
  set %loop #true
  while %loop
  {
      if #targcurs = 1
            wait 5
      else
          set %loop #false
  }
  set %Cassa #ltargetid
  event macro 2 0 Cassa salvata

  display ok seleziona il runebook da utilizzare
  set #targcurs 1
  set %loop #true
  while %loop
  {
        if #targcurs = 1
           wait 5
        else
           set %loop #false
  }
  set %RuneBook #ltargetid
  event macro 2 0 runebook salvato

  set %continua #true

  while #true
  {
        gosub Rifornimento
        if #result
        {
           gosub s7UseRunebook %RuneBook 2 r
           set %loop #true
           while %loop
           {
            set #NEXTCPOSX 10
            set #NEXTCPOSY 30
            msg Bank $
            wait 10

            if #CONTTYPE = IKF
            {
               set %BancaID #CONTID
               set %loop #false

               findItem %IronType C_ , #backpackid
               if #findkind <> -1
               {
                  Exevent Drag #findid #findstack
                  wait 20
                  Exevent Dropc %BancaID
               }
            }
            else
            {
               event macro 2 0 Id banca non trovato, riprovo...
               wait 50
            }
          }
          gosub s7UseRunebook %RuneBook 1 r
          event PathFind %homeposx %homeposy %homeposz
          wait 3s
        }
        else
        {
            display ok Materiale spostato.
            halt
        }
  }


  sub Rifornimento
      set #lobjectid %Cassa
      event macro 17
      wait 15

  piloop:
        finditem %IronType c_ , %Cassa
        if #findkind = -1
        {
             ignoreitem reset
             return #false
        }
        if #findCol <> %iron_col
        {
             ignoreitem #findid
             goto piloop
         }
        ignoreitem reset
        wait 10
  piridrag:
      if #findstack < 4
      {
         return #false
      }
      set %fspi #findstack
      if %fspi > %MaxIronSale
      {
         set %fspi %MaxIronSale
      }
      Exevent Drag #findID %fspi
      gosub AntiBlock
      wait 10
      Exevent Dropc #BACKPACKID
      return #true
  return

[Assassin]

  ;----
  ;* @name s7UseRunebook
  ;* @author snicker7
  sub s7UseRunebook
    if %0 < 3 || _ , %2 , _ notin _1_2_3_4_5_6_7_8_9_10_11_12_13_14_15_16_default_
      return ERR_IncorrectParams
    namespace push
    namespace local _s7URB
    set !runebook %1
    set !index %2
    set !method %3
    set !fails 0
    if #contsize = 452_236
    {
      set !_cx #contposx + 20
      set !_cy #contposy + 20
      click !_cx !_cy r f dmc
      wait 5
    }
    for !_ 1 1
    {
      finditem OTF_JEF_KEF G_0
      if #findkind <> -1
        set !_ 0
    }
    for !orb 1 1
    {
      if !fails > 2 2
        namespace pop
        return ERR_ , #journal
      set !jStart #jindex + 1
      if !index <> default
      {
        gosub s7WaitForAction 12
        set #lobjectid !runebook
        event macro 17 0
        gosub s7WaitForVars contname = generic_gump contsize = 452_236 3
        if ! #result 2
          set !fails !fails + 1
          set !orb 0
        if #result
        {
          set !_cy #contposy + 196
          set !_cx #contposx + 105 + ( ( ( !index / 2 ) + ( !index % 2 ) ) * 35 )
          if !index > 8
            set !_cx !_cx + 30
          click !_cx !_cy f dmc
          wait 5
          set !_cx #contposx + 135
          set !_cy #contposy + 144
          if !method = G
            set !_cy !_cy + 20
          if !method = C
            set !_cy !_cy + 36
          if !method = S
            set !_cy !_cy - 76
          if ( !index % 2 ) = 0
            set !_cx !_cx + 160
          set !charpos #charposx , _ , #charposy
          set !timeout #scnt2
          click !_cx !_cy f dmc
        }
      }
      if !index = default
      {
        set #ltargetid !runebook
        set #ltargetkind 1
        if !method = c
          event macro 15 210
        if !method = r
          event macro 15 31
        if !method = g
          event macro 15 51
        if !method = s
        {
          finditem WTL C_ , #backpackid
          if #findkind = -1 2
            namespace pop
            return ERR_NoRecallScrolls
          if #findkind <> -1 3
            set #lobjectid #findid
            gosub s7WaitForAction 12
            event macro 17 0
        }
        for !_ 1 1
        {
          if #targcurs <> 1
            set !_ 0
          gosub s7ScanJournalFor !jStart fizzles more_reagents tithing_points insufficient_mana
          if #result 3
            set !_ 1
            set !orb 0
            wait 20
        }
        set !charpos #charposx , _ , #charposy
        set !timeout #scnt2
        event macro 22 0
      }
      if !orb = 1
      {
        for !success 1 1
        {
          if #charposx , _ , #charposy = !charpos && !method in _r_c_s_
            set !success 0
          if !method = g
          {
            finditem OTF_JEF_KEF G_0
            if #findkind = -1
              set !success 0
            if #findkind <> -1
            {
              set #lobjectid #findid
              gosub s7WaitForAction 12
              event macro 17 0
              for !_ 1 1
              {
                if #charposx , _ , #charposy = !charpos
                  set !_ 0
                if #contname = generic_gump && #contsize = 420_280
                {
                  set !_cx #contposx + 20
                  set !_cy #contposy + 260
                  click !_cx !_cy f dmc
                }
              }
            }
          }
          gosub s7ScanJournalFor !jStart fizzles location_is_blocked not_yet_recovered no_charges_left more_reagents tithing_points insufficient_mana not_marked
          if #result || !timeout + 60 < #scnt2
          {
            if no_charges in #journal
            {
              finditem WTL C_ , #backpackid
              if #findkind = -1
                set !fails 2
              if #findkind <> -1
              {
                set !scrolls #findid
                finditem !runebook
                set #findmod 0
                gosub s7WaitForAction 12
                event drag !runebook
                for !_ 1 1
                {
                  if #lliftedkind <> 1 2
                    wait 1
                    set !_ 0
                }
                str pos #contsize _
                set #strres #strres - 1
                str left #contsize #strres
                set !_cx #findx + #strres / 2
                str pos #contsize _
                str del #contsize 1 #strres
                set !_cy #findy + #strres / 2
                click !_cx !_cy p f dmc
                gosub s7MoveToCont !scrolls !runebook #backpackid 20_10
              }
            }
            set !fails !fails + 1
            set !success 1
            set !orb 0
          }
        }
        wait 20
      }
    }
  namespace pop
  return #true

  sub s7ScanJournalFor
    set !SJFje #jindex + 1
    for !SJFji %1 !SJFje
    {
      scanjournal !SJFji
      for !SJFpi 2 %0
      {
        if % . !SJFpi in #journal
          return #true
      }
    }
  return #false

  ;----
  ;* @name s7MoveToPos
  ;* @author snicker7
  sub s7MoveToPos
    if %0 < 4
      return #false
    namespace Push
    namespace Local _s7MvToPos
    set !_ID %1
    set !_x %2
    set !_y %3
    set !_tO %4
    set !_Amt #spc
    if %0 > 4
      set !_Amt %5
    set !_retry 0
    _s7MvToPos_SD:
    finditem !_ID
    if #findkind = -1 2
      namespace pop
      return #false
    gosub s7WaitForAction 13
    event drag #findid
    if #findstack > 1
    {
      set !_timeOut #scnt
      for !_ 1 1
      {
        if #contname <> stack_gump && #contname <> drag_gump
        {
          wait 1
          if !_timeOut + !_tO < #scnt
          {
            set !_retry !_retry + 1
            if !_retry > 2 2
              namespace pop
              return #false
            goto _s7MvToPos_SD
          }
          set !_ 0
        }
      }
      if !_Amt > #findstack
        set !_Amt #findstack
      msg !_Amt , $
    }
    set !_retry 0
    set !_timeOut #scnt
    for !_ 1 1
    {
      if #lliftedkind <> 1
      {
        wait 1
        if !_timeOut + !_tO < #scnt
        {
          set !_retry !_retry + 1
          if !_retry > 2 2
            namespace pop
            return #false
          goto _s7MvToPos_SD
        }
        set !_ 0
      }
    }
    set !_retry 0
    click !_x !_y p
    set !_timeout #scnt
    for !_ 1 1
    {
      if #lliftedkind = 1
      {
        wait 1
        if !_timeout + !_t0 < #scnt
        {
          set !_retry !_retry + 1
          if !_retry = 1
          {
            set !_x #clixres / 2
            set !_y ( #cliyres / 2 ) - 30
            click !_x !_y p
            set #result #false
            set !_timeout #scnt
          }
          if !_retry = 2 2
            display ok You have failed to drop an item to the correct position.$$The script is now halting to prevent a crash.
            halt
        }
        set !_ 0
      }
    }
    set #result #true
    namespace pop
  return #result

  ;----
  ;* @name s7MoveToCont
  ;* @author snicker7
  sub s7MoveToCont
    namespace Push
    namespace Local _s7MoveToCont
    set !_ID %1
    set !_DCont %2
    set !_MCont %3
    set !_FMod %4
    if 1_5 in #euover
    {
      set !_Amt 65535
      if %0 > 4
        set !_Amt abs %5
      finditem !_ID
      if #findkind = -1 2
        namespace pop
        return #false
      gosub s7WaitForAction 13
      exevent drag #findid !_Amt
      exevent dropc !_DCont
      namespace pop
      return #true
    }
    set !_Amt #spc
    if %0 > 4
      set !_Amt %5
    set #result #true
    set !_retry 0
    for !_ 1 1
    {
      finditem !_DCont C_ , !_MCont
      if #findkind = -1
      {
        set #lobjectid !_MCont
        gosub s7WaitForAction 13
        event macro 17 0
        gosub s7WaitForVars contid = !_MCont 3
        if ! #result
        {
          set !_retry !_retry + 1
          if !_retry > 2 2
            namespace pop
            return #false
        }
        set !_ 0
      }
    }
    set !_retry 0
    set #findmod !_Fmod
    for !_ 1 1
    {
      gosub s7MoveToPos !_ID #findx #findy 4 !_Amt
      if ! #result
      {
        set !_retry !_retry + 1
        if !_retry > 2 2
          namespace pop
          return #false
        set !_ 0
      }
    }
  namespace Pop
  return #true

  ;----
  ;* @name s7WaitForAction
  ;* @author snicker7
  sub s7WaitForAction
    _s7WaitForAction:
    if %_s7ActionTimer + %1 > #scnt2 2
      wait 1
      goto _s7WaitForAction
    set %_s7ActionTimer #scnt2
  return

  ;----
  ;* @name s7WaitForVars
  ;* @author snicker7, inspired by Quintok, and of course, Smertrios
  sub s7WaitForVars
    namespace Push
    namespace Local _s7WFVs
    set !C %0 / 3
    set !T #scnt + 5
    if ( %0 % 3 ) = 1
      set !T #scnt + % . %0
    for !i 1 !C
    {
      set !o 3 * !i - 2
      set !p !o + 1
      set !q !o + 2
      if ! ( # . % . !o % . !p % . !q )
        set !i 0
      if #scnt > !T 2
        namespace pop
        return #false
    }
    namespace Pop
  return #true

[gordoso]

grazie mille^^

[BlackBraveKnight]

Dovrei prendere degli iron ingot e portarli a casa, se inverto le rune non credo che funzioni lo stesso (in banca deve aprire il bankbox, a casa un chest, è diverso), o lo fa? Qualche suggerimento sulle modifiche da apportare? ^^

imparate a scriptare e fatelo da soli, non è difficile u.u

Uh, allora la sezione Script che cosa l'hanno messa a fare -in Dubbi e Domande, poi-? Certo, se poi volevi aumentare il numero dei tuoi post è un'altra cosa...

[djtano]

provo a farlo dp, qnd vado a casa... xo dovete vede se lo faccio bn

[Assassin]

Dovrei prendere degli iron ingot e portarli a casa, se inverto le rune non credo che funzioni lo stesso (in banca deve aprire il bankbox, a casa un chest, è diverso), o lo fa? Qualche suggerimento sulle modifiche da apportare? ^^




Uh, allora la sezione Script che cosa l'hanno messa a fare -in Dubbi e Domande, poi-? Certo, se poi volevi aumentare il numero dei tuoi post è un'altra cosa...

tra 4 giorni esco di jail e vedo di fartelo inverso se nessuno avra gia fatto la modifica